Structure.hs

module Zwirn.Core.Structure where

{-
    Structure.hs - functions manipulating the 'structure' of signals
    Copyright (C) 2025, Martin Gius

    This library is free software: you can redistribute it and/or modify
    it under the terms of the GNU General Public License as published by
    the Free Software Foundation, either version 3 of the License, or
    (at your option) any later version.

    This library is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this library.  If not, see <http://www.gnu.org/licenses/>.
-}

import Control.Applicative
import Control.Monad (join)
import Control.Monad.Identity
import Data.Bifunctor
import Data.Fixed (mod')
import Data.Functor (void)
import Music.Theory.Bjorklund (bjorklund, iseq)
import Zwirn.Core.Core
import Zwirn.Core.Modulate
import Zwirn.Core.Time
import Zwirn.Core.Tree
import Zwirn.Core.Types
import Prelude hiding (enumFromTo)

runFromTo :: (Ord a, Num a, Monad k, HasSilence k) => ZwirnT k st i a -> ZwirnT k st i a -> ZwirnT k st i a
runFromTo xz yz = join $ en <$> xz <*> yz
  where
    en x y = fastcat $ map pure $ enumerateFromTo x y

runFromThenTo :: (Ord a, Num a, Monad k, HasSilence k) => ZwirnT k st i a -> ZwirnT k st i a -> ZwirnT k st i a -> ZwirnT k st i a
runFromThenTo xz yz zz = join $ en <$> xz <*> yz <*> zz
  where
    en x y z = fastcat $ map pure $ enumerateFromThenTo x y z

slowrunFromTo :: (Ord a, Num a, Monad k, HasSilence k) => ZwirnT k st i a -> ZwirnT k st i a -> ZwirnT k st i a
slowrunFromTo xz yz = join $ en <$> xz <*> yz
  where
    en x y = slowcat $ map pure $ enumerateFromTo x y

slowrunFromThenTo :: (Ord a, Num a, Monad k, HasSilence k) => ZwirnT k st i a -> ZwirnT k st i a -> ZwirnT k st i a -> ZwirnT k st i a
slowrunFromThenTo xz yz zz = join $ en <$> xz <*> yz <*> zz
  where
    en x y z = slowcat $ map pure $ enumerateFromThenTo x y z

run :: (Monad k, HasSilence k) => ZwirnT k st i Int -> ZwirnT k st i Int
run n = runFromTo (pure 0) (fmap (\x -> x - 1) n)

slowrun :: (Monad k, HasSilence k) => ZwirnT k st i Int -> ZwirnT k st i Int
slowrun n = slowrunFromTo (pure 0) (fmap (\x -> x - 1) n)

struct :: (MultiMonad k) => ZwirnT k st i a -> ZwirnT k st i b -> ZwirnT k st i b
struct = withInner2 (liftA2Left f)
  where
    f (v1, st) (v2, _) = (Value (value v2) (time v1) (info v1), st)

segment :: (MultiMonad k, HasSilence k) => ZwirnT k st i Int -> ZwirnT k st i a -> ZwirnT k st i a
segment = struct . run

euclidOff :: (HasSilence k, Monad k) => ZwirnT k st i Int -> ZwirnT k st i Int -> ZwirnT k st i Int -> ZwirnT k st i a -> ZwirnT k st i a
euclidOff i1 i2 i3 x = euclidOff' <$> i1 <*> i2 <*> i3 <$$> x
  where
    euclidOff' a b off x = timecat $ map (\i -> (fromIntegral i :: Time, x)) ts
      where
        ts = rotate off $ iseq $ bjorklund (a, b)
        rotate n xs = take lxs . drop ((-n) `mod` lxs) . cycle $ xs where lxs = length xs

euclid :: (HasSilence k, Monad k) => ZwirnT k st i Int -> ZwirnT k st i Int -> ZwirnT k st i a -> ZwirnT k st i a
euclid x y = euclidOff x y (pure 0)

left :: (MultiMonad k) => (ZwirnT k st i a -> ZwirnT k st i b -> ZwirnT k st i c) -> ZwirnT k st i a -> ZwirnT k st i b -> ZwirnT k st i c
left f x y = struct x $ f x y

right :: (MultiMonad k) => (ZwirnT k st i a -> ZwirnT k st i b -> ZwirnT k st i c) -> ZwirnT k st i a -> ZwirnT k st i b -> ZwirnT k st i c
right f x y = struct y $ f x y