synthesizer-llvm-0.3: src/Synthesizer/LLVM/CausalParameterized/Controlled.hs

{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE FunctionalDependencies #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE UndecidableInstances #-}
{- |
This module provides a type class that automatically selects a filter
for a given parameter type.
We choose the dependency this way
because there may be different ways to specify the filter parameters
but there is only one implementation of the filter itself.
-}
module Synthesizer.LLVM.CausalParameterized.Controlled where

import qualified Synthesizer.LLVM.Filter.ComplexFirstOrderPacked as ComplexFiltPack
import qualified Synthesizer.LLVM.Filter.ComplexFirstOrder as ComplexFilt
import qualified Synthesizer.LLVM.Filter.Allpass as Allpass
import qualified Synthesizer.LLVM.Filter.FirstOrder as Filt1
import qualified Synthesizer.LLVM.Filter.SecondOrder as Filt2
import qualified Synthesizer.LLVM.Filter.SecondOrderCascade as Cascade
import qualified Synthesizer.LLVM.Filter.SecondOrderPacked as Filt2P
import qualified Synthesizer.LLVM.Filter.Moog as Moog
import qualified Synthesizer.LLVM.Filter.Universal as UniFilter

import qualified Synthesizer.LLVM.CausalParameterized.Process as CausalP
import qualified Synthesizer.LLVM.Parameterized.Signal as SigP
import qualified Synthesizer.LLVM.Parameter as Param

import qualified LLVM.Extra.Memory as Memory
import qualified LLVM.Extra.ScalarOrVector as SoV
import qualified LLVM.Extra.Vector as Vector
import qualified LLVM.Extra.Class as Class

import qualified LLVM.Core as LLVM
import LLVM.Core
   (Value, IsFloating, IsConst, IsSized, )

import qualified Synthesizer.LLVM.Frame.Stereo as Stereo

import qualified Data.TypeLevel.Num      as TypeNum
import qualified Data.TypeLevel.Num.Sets as TypeSet

import Foreign.Storable (Storable, )

-- import qualified Algebra.Field as Field
-- import qualified Algebra.Module as Module
import qualified Algebra.Ring as Ring
import qualified Algebra.Additive as Additive


{- |
A filter parameter type uniquely selects a filter function.
However it does not uniquely determine the input and output type,
since the same filter can run on mono and stereo signals.
-}
class C parameter a b | parameter a -> b, parameter b -> a where
   process :: CausalP.T p (parameter, a) b


processCtrlRate ::
   (C parameter a b,
    Memory.C parameter struct, IsSized struct ss,
    Memory.FirstClass r rm, IsSized r rs, IsSized rm rmsize,
    Ring.C r, IsFloating r, Storable r, IsConst r,
    Class.MakeValueTuple r (Value r),
    LLVM.CmpRet r Bool) =>
   Param.T p r ->
   (Param.T p r -> SigP.T p parameter) ->
   CausalP.T p a b
processCtrlRate reduct ctrlGen =
   CausalP.applyFst process
      (SigP.interpolateConstant reduct (ctrlGen reduct))


{-
Instances for the particular filters shall are defined here
in order to avoid orphan instances.
-}

instance
   (SoV.PseudoModule a v, SoV.IntegerConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    Memory.FirstClass v vm, IsSized v vs, IsSized vm vms) =>
      C (Filt1.Parameter (Value a))
        (Value v) (Filt1.Result (Value v)) where
   process = Filt1.causalP

instance
   (SoV.PseudoModule a v, SoV.IntegerConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    Memory.FirstClass v vm, IsSized v vs, IsSized vm vms) =>
      C (Filt2.Parameter (Value a))
        (Value v) (Value v) where
   process = Filt2.causalP

instance
   (Vector.Arithmetic a, SoV.RationalConstant a,
    Memory.C (Value (Filt2P.State a)) am, IsSized am size {-,
    Memory.FirstClass a am, IsSized (Vector TypeNum.D4 a) as,
    IsSized am ams, LLVM.IsPrimitive am -}) =>
      C (Filt2P.Parameter a)
        (Value a) (Value a) where
   process = Filt2P.causalP

instance
   (SoV.PseudoModule a v, SoV.IntegerConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    Memory.FirstClass v vm, IsSized v vs, IsSized vm vms,
    TypeSet.Nat n,
    TypeNum.Mul n LLVM.UnknownSize paramSize, TypeSet.Pos paramSize) =>
      C (Cascade.ParameterValue n a)
        (Value v) (Value v) where
   process = Cascade.causalP


instance
   (SoV.PseudoModule a v, SoV.RationalConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    Memory.FirstClass v vm, IsSized v vs, IsSized vm vms) =>
      C (Allpass.Parameter (Value a))
        (Value v) (Value v) where
   process = Allpass.causalP

instance
   (SoV.PseudoModule a v, SoV.RationalConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    Memory.FirstClass v vm, IsSized v vs, IsSized vm vms,
    TypeNum.Nat n) =>
      C (Allpass.CascadeParameter n (Value a))
        (Value v) (Value v) where
   process = Allpass.cascadeP


instance
   (SoV.PseudoModule a v, SoV.IntegerConstant a,
    Additive.C v, IsConst v,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    Memory.FirstClass v vm, IsSized v vs, IsSized vm vms,
    Class.MakeValueTuple a (Value a),
    Class.MakeValueTuple v (Value v),
    Storable v,
    TypeSet.Nat n) =>
      C (Moog.Parameter n (Value a))
        (Value v) (Value v) where
   process = Moog.causalP


instance
   (SoV.PseudoModule a v, SoV.RationalConstant a,
    Memory.FirstClass a am, IsSized a as, IsSized am ams,
    Memory.FirstClass v vm, IsSized v vs, IsSized vm vms) =>
      C (UniFilter.Parameter (Value a))
        (Value v) (UniFilter.Result (Value v)) where
   process = UniFilter.causalP

instance
   (IsFloating a, SoV.RationalConstant a,
    Memory.FirstClass a am, IsSized a sa, IsSized am ams) =>
      C (ComplexFilt.Parameter (Value a))
        (Stereo.T (Value a)) (Stereo.T (Value a)) where
   process = ComplexFilt.causalP

instance
   (Vector.Arithmetic a, IsConst a,
    Memory.C (Value (Filt2P.State a)) am, IsSized am size) =>
{-
   (Memory.FirstClass a am, Vector.Arithmetic a, LLVM.IsPrimitive am,
    IsSized am ams,
    IsSized (Vector TypeNum.D4 a) as) =>
-}
      C (ComplexFiltPack.Parameter a)
        (Stereo.T (Value a)) (Stereo.T (Value a)) where
   process = ComplexFiltPack.causalP