packages feed

mischief-0.1.1.0: examples/rat-picker/Material.hs

module Material where

import Mischief.Materials
import Mischief.Materials.Sprite (SpriteMaterial)
import Mischief.Materials.Sprite qualified as Sprite
import Mischief.Materials.Time (TimeMaterial, getTime)
import Prelude (otherwise)
import Prelude qualified

data RatMaterial

newtype Bindings f = Bindings (Uniform f (RatColor f))
  deriving stock (Generic)
  deriving anyclass (Bindable)

newtype RatColor f = RatColor (Field f Int)
  deriving stock (Generic)
  deriving anyclass (Bufferable)

instance Component (RatColor CPU)

instance Default (RatColor CPU) where
  def = RatColor 0

minColor :: Prelude.Int
minColor = 0

maxColor :: Prelude.Int
maxColor = 4

colorDown :: RatColor CPU -> RatColor CPU
colorDown (RatColor 0) = RatColor maxColor
colorDown (RatColor x) = RatColor (x Prelude.- 1)

colorUp :: RatColor CPU -> RatColor CPU
colorUp (RatColor x)
  | x Prelude.== maxColor = RatColor minColor
  | otherwise = RatColor (x Prelude.+ 1)

instance Material RatMaterial where
  type B RatMaterial = Bindings
  type VI RatMaterial = Sprite.VertexInput
  type VO RatMaterial = Sprite.VertexOutput

  type Extends RatMaterial = '[SpriteMaterial, TimeMaterial]

  vertex = liftExt . vertex @SpriteMaterial
  fragment vo = do
    a <- liftExt $ Sprite.sampleSprite vo.uv
    select
      (all $ a.rgb == vec3 1 1 1)
      (pickColor vo.uv)
      (pure a)

  fetch =
    FetchBindings
      (const $ pure ())
      (\sprite -> [q|sprite. (Buffer RatColor)|])
      (const Bindings)

pickColor :: Vec2 Float -> Shader RatMaterial (Vec4 Float)
pickColor uv = do
  Bindings (RatColor c) <- bindings

  Sprite.Bindings {sprite = Sprite.SpriteData {size}} <- extension @SpriteMaterial
  uv <- var $ (floor (size * uv) ^+ 0.5) / size

  pick
    [ (c == 0, color0 uv),
      (c == 1, color1 uv),
      (c == 2, color2 uv),
      (c == 3, color3 uv),
      (c == 4, color4 uv)
    ]
    (color0 uv)

color0 :: Vec2 Float -> Shader RatMaterial (Vec4 Float)
color0 _ = pure $ vec4 82 25 181 256 ^/ 256

color1 :: Vec2 Float -> Shader RatMaterial (Vec4 Float)
color1 uv = pure $ mix (vec4 1 0 0 1) (vec4 0 1 1 1) uv.x

color2 :: Vec2 Float -> Shader RatMaterial (Vec4 Float)
color2 uv = do
  time <- liftExt getTime
  pure $ mix (vec4 0 0.5 1 1) (vec4 1 0 0.1 1) (uv.x / uv.y + sin time * 0.5)

color3 :: Vec2 Float -> Shader RatMaterial (Vec4 Float)
color3 uv = do
  time <- liftExt getTime
  i :: Int <- var $ cast (floor (uv.y * 10) + time) % 6
  color :: Vec3 Float <-
    pick
      [ (i == 0, pure $ vec3 228 3 3),
        (i == 1, pure $ vec3 255 140 0),
        (i == 2, pure $ vec3 255 237 0),
        (i == 3, pure $ vec3 0 128 38),
        (i == 4, pure $ vec3 0 76 255)
      ]
      (pure $ vec3 115 41 130)
  pure $ color ^/ 256 +: 1

color4 :: Vec2 Float -> Shader RatMaterial (Vec4 Float)
color4 uv = do
  time <- liftExt getTime
  i :: Int <- var $ cast (floor (uv.x / uv.y * 10) + time * 2) % 5
  color :: Vec3 Float <-
    pick
      [ (i == 0, pure $ vec3 91 207 250),
        (i == 1, pure $ vec3 245 171 185),
        (i == 2, pure $ vec3 255 255 255),
        (i == 3, pure $ vec3 245 171 185)
      ]
      (pure $ vec3 91 207 250)
  pure $ color ^/ 256 +: 1