packages feed

mischief-0.1.1.0: examples/rat-picker/Main.hs

module Main where

import Control.Monad
import Material (RatColor, RatMaterial, colorDown, colorUp)
import Mischief.Animation
import Mischief.Assets
import Mischief.ECS
import Mischief.Input
import Mischief.Input.Keys qualified as Keys
import Mischief.Materials.Sprite (SpriteMaterial)
import Mischief.Math
import Mischief.Math.Transform qualified as Transform
import Mischief.Render
import Mischief.Render.Camera (CameraBackground (..), CameraZoom (..))

main :: IO ()
main = do
  app <- newApp
  setAssetSource "assets/" app
  addPlugin @RatPickerPlugin app
  runApp app

data RatPickerPlugin

instance Plugin RatPickerPlugin where
  init = do
    schedule @Startup $ systems setup

    schedule @RenderUpdate $
      systems
        ( renderMaterial @SpriteMaterial def {defaultSampler = sampler @PixelSampler},
          renderMaterial @RatMaterial def {defaultSampler = sampler @PixelSampler}
        )
    schedule @RenderPrepare $ systems (maintainBuffer @RatColor)

    schedule @Update $ systems (handleInput, animateArrows)

  deps = [dep @RenderPlugin, dep @InputPlugin, dep @AnimationPlugin]

data Rat = Rat

instance Component Rat where
  required = require @(RatColor CPU)

setup :: System ()
setup = do
  window <- spawn Window
  spawn_ (Camera, CameraZoom 15, CameraBackground $ 5 / 256, Rel OutputTo window)

  fur <- load @Image "ui/fur.png"
  size <- load @Image "ui/size.png"

  spawn_ (Rat, Animator RatAnimator, WithMaterial @RatMaterial)

  spawn_ (Sprite size, WithMaterial @SpriteMaterial, def {translation = V3 48 0 0})
  spawn_ (UpArrow, Animator ArrowAnimator, WithMaterial @SpriteMaterial, def {translation = V3 48 25 0})
  spawn_ (DownArrow, Animator ArrowAnimator, WithMaterial @SpriteMaterial, Transform.rotateZ pi def {translation = V3 48 (-25) 0})

  spawn_ (Sprite fur, WithMaterial @SpriteMaterial, def {translation = V3 0 (-26) 0})
  spawn_ (RightArrow, Animator ArrowAnimator, WithMaterial @SpriteMaterial, Transform.rotateZ (-(pi / 2)) def {translation = V3 16 (-26) 0})
  spawn_ (LeftArrow, Animator ArrowAnimator, WithMaterial @SpriteMaterial, Transform.rotateZ (pi / 2) def {translation = V3 (-16) (-26) 0})

data UpArrow = UpArrow deriving (Component)

data DownArrow = DownArrow deriving (Component)

data LeftArrow = LeftArrow deriving (Component)

data RightArrow = RightArrow deriving (Component)

data ArrowAnimator = ArrowAnimator

animateArrows :: System ()
animateArrows = do
  Just keys <- res @Keys

  single [q|E / With LeftArrow|] >>= input (const $ IsPressed $ Keys.pressed keys Keys.Left) . unwrap
  single [q|E / With RightArrow|] >>= input (const $ IsPressed $ Keys.pressed keys Keys.Right) . unwrap
  single [q|E / With UpArrow|] >>= input (const $ IsPressed $ Keys.pressed keys Keys.Up) . unwrap
  single [q|E / With DownArrow|] >>= input (const $ IsPressed $ Keys.pressed keys Keys.Down) . unwrap

instance AnimatorTag ArrowAnimator where
  data State ArrowAnimator = Pressed | NotPressed
  data Input ArrowAnimator = IsPressed Bool deriving (Generic, Default)
  data Shift ArrowAnimator = Shift

  animation Pressed = selAnim "ui/arrow-animations.kdl" "pressed"
  animation NotPressed = selAnim "ui/arrow-animations.kdl" "not_pressed"

  transition NotPressed (IsPressed True) _ _ = Just Pressed
  transition Pressed (IsPressed False) _ _ = Just NotPressed
  transition _ _ _ _ = Nothing

  start = NotPressed

handleInput :: System ()
handleInput = do
  Just (rat, color) <- single [q|E, (RatColor CPU) / With Rat|]
  Just keys <- res @Keys

  when (Keys.justPressed keys Keys.Up) $ shift ShiftUp rat
  when (Keys.justPressed keys Keys.Down) $ shift ShiftDown rat

  when (Keys.justPressed keys Keys.Left) $ insert (colorDown color) rat
  when (Keys.justPressed keys Keys.Right) $ insert (colorUp color) rat

data RatAnimator = RatAnimator

instance AnimatorTag RatAnimator where
  data State RatAnimator = Rat1 | Rat2 | Rat3
  data Input RatAnimator = Input deriving (Generic, Default)
  data Shift RatAnimator = ShiftUp | ShiftDown

  animation Rat1 = selAnim "rats/rat-animations.kdl" "rat1"
  animation Rat2 = selAnim "rats/rat-animations.kdl" "rat2"
  animation Rat3 = selAnim "rats/rat-animations.kdl" "rat3"

  transition Rat1 _ (Just ShiftUp) _ = Just Rat2
  transition Rat2 _ (Just ShiftUp) _ = Just Rat3
  transition Rat3 _ (Just ShiftDown) _ = Just Rat2
  transition Rat2 _ (Just ShiftDown) _ = Just Rat1
  transition _ _ _ _ = Nothing

  start = Rat1