hpg-0.7: hpg.hs

{-|
  Copyright (c) 2017 Fritjof Bornebusch <fritjof@alokat.org>
 
  Permission to use, copy, modify, and distribute this software for any
  purpose with or without fee is hereby granted, provided that the above
  copyright notice and this permission notice appear in all copies.
 
  THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
-}

{-# LANGUAGE CPP #-}

module Main ( main ) where

import Data.Word               ( Word16 )
import System.Console.GetOpt   ( ArgDescr(ReqArg, NoArg), ArgOrder(RequireOrder),
                                 getOpt, OptDescr(Option) )
import System.Environment      ( getArgs )
import System.Exit             ( exitFailure, exitSuccess )
import System.IO               ( hPutStr, hPutStrLn, stderr, stdout )

#ifdef openbsd_HOST_OS
import System.OpenBSD.Process  ( pledge )
#else
import OpenBSD.Compat          ( pledge )
#endif 

import System.Random           ( randomRIO )

default ( Word16 )

upperCaseLettersList :: [Char]
upperCaseLettersList = ['A'..'Z']

lowerCaseLettersList :: [Char]
lowerCaseLettersList = ['a'..'z']

numbersList :: [Char]
numbersList = ['0'..'9']

specialCharactersList :: [Char]
specialCharactersList = ['!'..'/'] ++ [':'..'@'] ++ ['['..'_'] ++ ['{'..'~']

data Options = Options { optLowerCaseFlag         :: Bool
                       , optNoNewLineFlag         :: Bool
                       , optNumbersFlag           :: Bool
                       , optSpecialCharactersFlag :: Bool
                       , optUpperCaseFlag         :: Bool
                       , optLengthValue           :: Word16
                        }

startOptions :: Options
startOptions = Options  { optLowerCaseFlag         = False
                        , optNoNewLineFlag         = False
                        , optNumbersFlag           = False 
                        , optSpecialCharactersFlag = False
                        , optUpperCaseFlag         = False
                        , optLengthValue           = 16
                        }

options :: [ OptDescr (Options -> IO Options) ]
options =
    [
      Option "l" []
        (NoArg
            (\opt -> return opt { optLowerCaseFlag = True }))
        "lower case letters"
     
     , Option "N" []
         (NoArg
             (\opt -> return opt { optNoNewLineFlag = True}))
         "no newline"
      
    , Option "n" []
        (NoArg
            (\opt -> return opt { optNumbersFlag = True }))
        "numbers"
 
    , Option "s" [] 
        (NoArg
            (\opt -> return opt { optSpecialCharactersFlag = True }))
        "special characters"

    ,  Option "u" [] 
          (NoArg  
              (\opt -> return opt { optUpperCaseFlag = True }))
          "upper case letters"
 
    , Option "x" []
        (ReqArg
            (\arg opt -> return opt { optLengthValue = do
                                          let value = read arg :: Integer
                                          case isWord16 value of
                                              True -> read arg
                                              _    -> 0
                                    })
            "length")
        "password length"
    ]

isWord16 :: Integer -> Bool
isWord16 n
    | n < toInteger(minBound::Word16) = False
    | n > toInteger(maxBound::Word16) = False
    | otherwise = True

exitWithMessage :: String -> IO ()
exitWithMessage msg = do
    hPutStrLn stderr msg
    exitFailure

parse :: [String] -> IO ([Options -> IO Options], [String])
parse args =
    case getOpt RequireOrder options args of
        (actions, nonOptions,[]) -> return (actions, nonOptions)
        (_,_,errors)              -> do
            hPutStrLn stderr (concat errors ++ header)
            exitFailure

    where header = "usage: hpg [-N]\n" ++
                   "           [-lnsu]\n" ++ 
                   "           [-x length]"

randomList :: Word16 -> [Char] -> IO([Int])
randomList 0 _ = return []
randomList n list = do
    let l = length list
    r <- randomRIO (0, l-1)
    rs <- randomList (n-1) list
    return (r:rs)

createPassword :: Word16 -> [Bool] -> IO [Char]
createPassword lengthValue flags = do
    let l = createList [lowerCaseLettersList,
                        numbersList,
                        specialCharactersList,
                        upperCaseLettersList] flags

    rl <- randomList lengthValue l
    return [l !! i | i <- rl]

addToList :: [Char] -> ([Char], Bool) -> [Char] 
addToList list (l, True) = list ++ l
addToList list (_, False) = list

createList :: [[Char]] -> [Bool] -> [Char]
createList characters [False, False, False, False] = do
    -- default values are lower case, numbers and
    -- upper case letters
    createList characters [True, True, False, True]

createList characters flags = do
    let z = zip characters flags
    foldl (\x y -> addToList x y) [] z

main :: IO ()
main = do
    pledge (Just "stdio") Nothing

    (actions, _nonOptions) <- getArgs >>= parse
    opts <- foldl (>>=) (return startOptions) actions
    let Options { optLowerCaseFlag          = lowerCase
                , optNoNewLineFlag          = noNewLine
                , optNumbersFlag            = numbers
                , optSpecialCharactersFlag  = specialCharacters
                , optUpperCaseFlag          = upperCase
                , optLengthValue            = lengthValue } = opts

    if lengthValue == 0
        then exitWithMessage "invalid password length"
        else do
            pwd <- createPassword lengthValue [lowerCase,
                                               numbers,
                                               specialCharacters,
                                               upperCase]
            
            hPutStr stdout pwd
            case noNewLine of
                False -> hPutStr stdout "\n"
                _     -> return ()

    exitSuccess