hoare-0.2.0.0: lib/Control/Concurrent/TCSlot.hs
-- | A /closeable/, single-element STM queue.
--
-- Identical to @TBCQueue@ but has a max length of 1.
-- Helpful when you want to minimize latency,
-- and has simpler ops since values are just held in a @TVar (Maybe a)@.
module Control.Concurrent.TCSlot(
TCSlot,
newTCSlot,
newTCSlotIO,
readTCSlot,
writeTCSlot,
overwriteTCSlot,
closeTCSlot,
isOpenTCSlot,
isClosedTCSlot,
isEmptyTCSlot,
isFullTCSlot,
) where
import Control.Concurrent.Channel.Overwrite
import Control.Concurrent.STM
import Control.Monad
import Data.Maybe (isNothing)
data TCSlot a = TCSlot {
slot :: TVar (Maybe a),
open :: TVar Bool
}
newTCSlot :: STM (TCSlot a)
newTCSlot = TCSlot <$> newTVar Nothing <*> newTVar True
newTCSlotIO :: IO (TCSlot a)
newTCSlotIO = atomically newTCSlot
readTCSlot :: TCSlot a -> STM (Maybe a)
readTCSlot c = readTVar c.slot >>= \case
Just v -> do
writeTVar c.slot Nothing
pure $ Just v
Nothing -> do
stillOpen <- readTVar c.open
if stillOpen
then retry
else pure Nothing
writeTCSlot :: TCSlot a -> a -> STM Bool
writeTCSlot c !v = do
stillOpen <- readTVar c.open
when stillOpen $ do
check . isNothing =<< readTVar c.slot
writeTVar c.slot $ Just v
pure stillOpen
overwriteTCSlot :: TCSlot a -> a -> STM (OverwriteResult a)
overwriteTCSlot c !v = do
stillOpen <- readTVar c.open
if stillOpen
then readTVar c.slot >>= \case
Just o -> do
writeTVar c.slot $ Just v
pure $ Overwrote o
Nothing -> do
writeTVar c.slot $ Just v
pure Wrote
else pure Closed
closeTCSlot :: TCSlot a -> STM ()
closeTCSlot c = writeTVar c.open False
isOpenTCSlot :: TCSlot a -> STM Bool
isOpenTCSlot c = readTVar c.open
isClosedTCSlot :: TCSlot a -> STM Bool
isClosedTCSlot = fmap not . isOpenTCSlot
isEmptyTCSlot :: TCSlot a -> STM Bool
isEmptyTCSlot = fmap not . isFullTCSlot
isFullTCSlot :: TCSlot a -> STM Bool
isFullTCSlot c = readTVar c.slot >>= \case
Just _ -> pure True
Nothing -> pure False