Par.hs

--
-- Copyright (c) 2009-2011, ERICSSON AB
-- All rights reserved.
-- 
-- Redistribution and use in source and binary forms, with or without
-- modification, are permitted provided that the following conditions are met:
-- 
--     * Redistributions of source code must retain the above copyright notice, 
--       this list of conditions and the following disclaimer.
--     * Redistributions in binary form must reproduce the above copyright
--       notice, this list of conditions and the following disclaimer in the
--       documentation and/or other materials provided with the distribution.
--     * Neither the name of the ERICSSON AB nor the names of its contributors
--       may be used to endorse or promote products derived from this software
--       without specific prior written permission.
-- 
-- THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
-- AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
-- IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE 
-- DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
-- FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
-- DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
-- SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
-- CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
-- OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
-- OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
--

{-# LANGUAGE UndecidableInstances #-}

module Feldspar.Compiler.Imperative.FromCore.Par where

import Language.Syntactic
import Language.Syntactic.Constructs.Monad
import Language.Syntactic.Constructs.Binding

import Feldspar.Core.Types
import Feldspar.Core.Interpretation
import Feldspar.Core.Constructs.Par

import Feldspar.Compiler.Imperative.Frontend hiding (Variable)
import Feldspar.Compiler.Imperative.FromCore.Interpretation

instance ( Compile dom dom
         , Lambda TypeCtx :<: dom
         , ParFeature :<: dom
         )
      => Compile (MONAD Par) dom
  where
    compileProgSym Bind _ loc (ma :* (lam :$ body) :* Nil)
        | Just (_, Lambda v)  <- prjDecorCtx typeCtx lam
        , Just (info, ParNew) <- prjDecor ma
        -- TODO add helper function :: Info (Par a) -> Info a
        = do
            let var = mkVar (compileTypeRep (infoType info) (infoSize info)) v
            withDecl var $ compileProg loc body

    compileProgSym Bind _ loc (ma :* (lam :$ body) :* Nil)
        | Just (_, Lambda v) <- prjDecorCtx typeCtx lam
        = do
            e <- compileExpr ma
            withAlias v e $ compileProg loc body

    compileProgSym Then _ loc (ma :* mb :* Nil) = do
        compileExpr ma
        compileProg loc mb

    compileProgSym Return info loc (a :* Nil)
        | ParType UnitType <- infoType info = return ()
        | otherwise                         = compileProg loc a

    compileProgSym When _ loc (c :* action :* Nil) = do
        c' <- compileExpr c
        (_, body) <- confiscateProg $ compileProg loc action
        tellProg [If c' (Seq body) Skip]

instance ( Compile dom dom
         , Variable TypeCtx :<: dom
         )
      => Compile ParFeature dom
  where
    compileExprSym ParGet _ (r :* Nil) = do
        releaseProgs
        compileExpr r

    compileExprSym a info args = compileProgFresh a info args

    compileProgSym ParRun _ loc (p :* Nil) = compileProg loc p

    compileProgSym ParGet _ loc (r :* Nil) = do
        releaseProgs
        compileProg loc r

    compileProgSym ParPut _ loc (r :* a :* Nil)
        | Just (info, Variable v) <- prjDecorCtx typeCtx r
        = do
            let var = mkVar (compileTypeRep (infoType info) (infoSize info)) v
            compileProg var a

    compileProgSym ParFork _ loc (p :* Nil) = do
        suspendProg $ compileProg loc p

    compileProgSym ParYield _ loc Nil = return ()