Injection12.hs

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE DefaultSignatures #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FunctionalDependencies #-}
{-# OPTIONS_GHC -Wall #-}

-- | The twelfth injection of a sum type, as a prism. The sum-type dual of 'Control.Lens.Field12'.
module Data.Lens.Injection.Injection12 (
  Injection12 (..),
) where

import Control.Lens (Prism)
import Data.Lens.Injection.Generic (GInjection, injection)
import Data.Proxy (Proxy (..))
import GHC.Generics (Generic, Rep)

{- $setup
>>> :set -XDeriveGeneric -XMultiParamTypeClasses -XFlexibleInstances
>>> import Control.Lens((^?), (#))
>>> import GHC.Generics(Generic)
-}

{- | Access the twelfth constructor of a sum type.

Where 'Control.Lens._12' is the twelfth projection out of a product, '_I12' is the twelfth
injection into a sum.

The default implementation is the prism to the twelfth constructor of a
'Generic' type, @'injection' (Proxy :: Proxy 11)@.

>>> data T = C1 | C2 | C3 | C4 | C5 | C6 | C7 | C8 | C9 | C10 | C11 | C12 Int | C13 deriving (Show, Generic)
>>> instance Injection12 T T Int Int
>>> C12 1 ^? _I12
Just 1

>>> C13 ^? _I12
Nothing

>>> _I12 # 1 :: T
C12 1
-}
class Injection12 s t a b | s -> a, t -> b, s b -> t, t a -> s where
  _I12 :: Prism s t a b
  default _I12 :: (Generic s, Generic t, GInjection 11 (Rep s) (Rep t) a b) => Prism s t a b
  _I12 =
    injection (Proxy :: Proxy 11)
  {-# INLINE _I12 #-}