Injection11.hs

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE DefaultSignatures #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FunctionalDependencies #-}
{-# OPTIONS_GHC -Wall #-}

-- | The eleventh injection of a sum type, as a prism. The sum-type dual of 'Control.Lens.Field11'.
module Data.Lens.Injection.Injection11 (
  Injection11 (..),
) where

import Control.Lens (Prism)
import Data.Lens.Injection.Generic (GInjection, injection)
import Data.Proxy (Proxy (..))
import GHC.Generics (Generic, Rep)

{- $setup
>>> :set -XDeriveGeneric -XMultiParamTypeClasses -XFlexibleInstances
>>> import Control.Lens((^?), (#))
>>> import GHC.Generics(Generic)
-}

{- | Access the eleventh constructor of a sum type.

Where 'Control.Lens._11' is the eleventh projection out of a product, '_I11' is the eleventh
injection into a sum.

The default implementation is the prism to the eleventh constructor of a
'Generic' type, @'injection' (Proxy :: Proxy 10)@.

>>> data T = C1 | C2 | C3 | C4 | C5 | C6 | C7 | C8 | C9 | C10 | C11 Int | C12 deriving (Show, Generic)
>>> instance Injection11 T T Int Int
>>> C11 1 ^? _I11
Just 1

>>> C12 ^? _I11
Nothing

>>> _I11 # 1 :: T
C11 1
-}
class Injection11 s t a b | s -> a, t -> b, s b -> t, t a -> s where
  _I11 :: Prism s t a b
  default _I11 :: (Generic s, Generic t, GInjection 10 (Rep s) (Rep t) a b) => Prism s t a b
  _I11 =
    injection (Proxy :: Proxy 10)
  {-# INLINE _I11 #-}