edge-0.9.1.0: Projectile/BulletSII.hs

{-|
Module      : Projectile.BulletSII
Description : Bullet projectile
Copyright   : (c) Christopher Howard, 2016
License     : GPL-3
Maintainer  : ch.howard@zoho.com
-}

module Projectile.BulletSII ( BulletSII(..)
                            , new
                            , prj
                            , speed
                            ) where

import Prelude ((+), max, (-), (||), Maybe(..), Bool(..), ($), cos, sin, (.), (<), otherwise, (*), Double)
import Graphics.Gloss.Data.Picture ( Picture(Circle, Color) )
import Graphics.Gloss.Data.Color ( yellow, red, green )
import Data.WrapAround ( WP, WM, distance )

import Combat
import Animation
import Updating
import qualified Moving as M
    ( Moving(..), Locatable(..), Colliding(..), newLocation )
import Common
import Math

speed = velocityC

velocityC = 600.0

rangeC = 1000.0

damE = 1

data BulletSII =
  BulletSII { velocity :: Velocity
            , center :: WP
            , rangeLeft :: Double
            , wrapMap :: WM
            , idealNewCenter :: Maybe WP
            , impacted :: Bool
            , clock :: Time
            }

new a b c (d, e) =
  BulletSII { velocity = (x + d, y + e)
            , center = c
            , rangeLeft = rangeC
            , wrapMap = a
            , idealNewCenter = Nothing
            , impacted = False
            , clock = 0.0
            }
  where (x, y) = appPair ((* velocityC) . ($ b)) (cos, sin)

instance Animation BulletSII where

  image s t = (Color (c r) . Circle) 2.0
    where c x | x < 0.10 = green
              | otherwise = yellow
          r = remF (clock s) 0.2

instance M.Colliding BulletSII where

  collisionRadius _ = 2.0

instance M.Moving BulletSII where

  velocity = velocity

instance M.Locatable BulletSII where

  center = center

instance SimpleTransient BulletSII where

  expired = zeroOrLess . rangeLeft

instance InternallyUpdating BulletSII where

  preUpdate s t = s { clock = clock s + t }

  postUpdate s t = s { center = a, rangeLeft = r }
    where a = M.newLocation (wrapMap s) (center s) (velocity s) t
          r = max 0 (rangeLeft s - Data.WrapAround.distance (wrapMap s) (center s) a)

instance Damaging BulletSII where

  damageEnergy _ = damE

instance Transient BulletSII where

  expired' s = if impacted s || zeroOrLess (rangeLeft s) then Just [] else Nothing

instance Damageable BulletSII where

  inflictDamage s d = if moreThanZero d then s { impacted = True } else s

-- | Func abstracting construction of 'BulletSII' projectile
prj :: (M.Moving a)
    => a -- ^ object receiving projectile
    -> (a -> WM) -- ^ func which retrieves WM from object
    -> Angle -- ^ firing angle
    -> Projectile
prj a f b = Projectile (new (f a) b (M.center a) (M.velocity a))