coincident-root-loci-0.3: mathematica/equiv_motivic_chern.src

(* ===== EQUIVARIANT MOTIVIC CHERN CLASSES OF COINCIDENT ROOT LOCI ==== *)

<< Combinatorica`

(* === NORMALIZATION in K(P^n) === *)

(* Weights of Sym^n C^2 *)
Clear[L, X, Y]
WT[n_, i_] := X^(n - i)*Y^i

(* the relation in K (P^n). Convention: 
L is the tautological line bundle, 
   c_ 1(X) = -alpha, c_ 1(Y) = -beta *)

KREL[n_] := Product[1 - L*WT[n, i], {i, 0, n}]

(* normal form of L^(n+1) *)
Clear[Lpow$nplus1]
Lpow$nplus1[n_] := 
 Lpow$nplus1[n] = 
  Expand[L^(n + 1) - (-1)^(n + 1) KREL[n]/(X*Y)^Binomial[n + 1, 2]]

(* (unefficiently) normalize a polynomial in L *) 
Clear[KnormalizeSlow]
KnormalizeSlow[n_, Z0_] := Module[{Z = Expand[Z0], m},
  m = Exponent[Z, L];
  If[m <= n, Z, 
   KnormalizeSlow[n, Z /. {L^m -> L^(m - n - 1)*Lpow$nplus1[n]}]]
  ]

(* Table of normal forms of L^p *)
Clear[LPowXY]
LPowXY[n_, k_] := LPowXY[n, k] = Expand[KnormalizeSlow[n, L^k]]

(* More efficient normalization in K^(P^n) 
usage: KnormalizeVarXY[dim,L,expr] *)
Clear[KnormalizeVarXY]
KnormalizeVarXY[n_, uuu_, Z0_] := Module[
  {m, Z},
  Z = Expand[Z0];
  m = Exponent[Z, uuu];
  Expand[Sum[Coefficient[Z, uuu, k]*(LPowXY[n, k] /. {L -> uuu}), {k, 0, m}]]
  ] 

(* === PUSHFORWARD ALONG PSI (THE MULTIPLICATION MAP) === *)

(* formulas for (psi_{n,1})_! (L1^p*L2^q) *)
Clear[PSI$N1f]
PSI$N1f[n_, 0, 1] := L*(X^(n + 1) - Y^(n + 1))/(X - Y)
PSI$N1f[n_, p_, 0] := 
 L^p*(X^(p + 1) - Y^(p + 1))/(X - Y) + 
  L^(p + 1) (X^(n + 1)*Y^(p + 1) - Y^(n + 1) X^(p + 1))/(X - Y)
PSI$N1f[n_, p_, q_] := If[p >= q,
  L^q*PSI$N1f[n, p - q, 0],
  L^p*PSI$N1f[n, 0, q - p]
  ]

Clear[PSI$N1]
PSI$N1[n_, p_, q_] := PSI$N1[n, p, q] = Expand[Factor[PSI$N1f[n, p, q]]]

Clear[newPsiBang2]
newPsiBang2[{n_, 1}, {var1_, var2_}, outvar_, ZZ_] := Module[
  {Z},
  Z = Expand[ZZ];
  Expand[Sum[
    Coefficient[Coefficient[Z, var1, i], var2, 
      j]*(PSI$N1[n, i, j] /. {L -> outvar}), {i, 0, n}, {j, 0, 1}]]
  ]

(* find elements in K(P^m x P^1) such that their pushforward to K(P^(m+1)) is \
{1,L,L^2,...L^(m+1)} *)
findBasis$M1[m_] := findBasis$M1[m] =
  Module[{vars, A, B, list, i, j, k, eqs, sols, sol},
   vars = Table[Subscript[a, i], {i, 0, m + 1}];
   A = Sum[Subscript[a, i]*L1^i, {i, 0, m}] +
     Subscript[a, m + 1]*L1^m*L2;
   B = newPsiBang2[{m, 1}, {L1, L2}, L, A];
   list = Table[Null, {i, 0, m + 1}];
   For[k = 0, k <= m + 1, k++,
    eqs = Table[Coefficient[B, L, i] == If[k == i, 1, 0], {i, 0, m + 1}];
    sols = Solve[eqs, vars];
    sol = sols[[1]];
    list[[k + 1]] = A /. sol;
    ];
   list
   ]


Clear[PSI$NM, S, T]
PSI$NM[n_, 0, p_, 0] := L^p
PSI$NM[0, m_, 0, q_] := L^q
PSI$NM[n_, 1, p_, q_] := PSI$NM[n, 1, p, q] = PSI$N1[n, p, q]
PSI$NM[n_, mplus1_, p_, q_] := PSI$NM[n, mplus1, p, q] = Module[
   {m = mplus1 - 1, basis, A, B, C},
   basis = findBasis$M1[m];
   A = basis[[q + 1]] /. {L1 -> L2, L2 -> T};
   B = newPsiBang2[{n, m}, {L1, L2}, S, L1^p*A];
   C = newPsiBang2[{n + m, 1}, {S, T}, L, B];
   Expand[Factor[C]]
   ]

newPsiBang2[{n_, m_}, {var1_, var2_}, outvar_, ZZ_] := Module[
  {Z, deg1, deg2},
  Z = Expand[ZZ];
  deg1 = Exponent[Z, var1];
  deg2 = Exponent[Z, var2];
  Expand[Sum[
    Coefficient[Coefficient[Z, var1, i], var2, 
      j]*(PSI$NM[n, m, i, j] /. {L -> outvar}), {i, 0, deg1}, {j, 0, deg2}]]
  ]

newPsiBangMany[{n_}, {uuu_}, www_, Z_] := Z /. {uuu -> www}
newPsiBangMany[ns_, uuus_, www_, Z_] := Module[{ttt, vvvs, ms},
  If[Length[uuus] == 1, Z /. {uuus[[1]] -> www},
   If[Length[uuus] == 2, newPsiBang2[ns, uuus, www, Z],
    ms = Join[{ns[[1]] + ns[[2]]}, Drop[ns, 2]];
    vvvs = Join[{ttt}, Drop[uuus, 2]];
    newPsiBangMany[ms, vvvs, www, 
     newPsiBang2[Take[ns, 2], Take[uuus, 2], ttt, Z]]]]]

(* === PUSHFORwARD ALONG THE DIAGONAL MAP === *)

notk[n_, k_] := Select[Range[0, n], # != k &]

(* class of the diagonal in K(P^n x P^n) *)
Clear[DELTA$CLASS$2]
DELTA$CLASS$2[n_] := DELTA$CLASS$2[n] =
  Factor[Sum[ 
    Product[ (1 - 
        L1*WT[n, i]) (1 - L2*WT[n, i])/(1 - WT[n, i]/WT[n, k])  , {i, 
      notk[n, k]}] , {k, 0, n}]]

newDeltaBang2[n_, invar_, {var1_, var2_}, ZZ_] := Module[
  {Z = Expand[ZZ], m, A},
  m = Exponent[Z, invar];
  A = Expand[(DELTA$CLASS$2[n] /. {L1 -> var1, L2 -> var2})*
     Sum[var1^p*Coefficient[Z, invar, p], {p, 0, m}]];
  KnormalizeVarXY[n, var1, A]
  ]

(* usage: deltaBangMany[dim,L,{L1,L2,L3},X] *)

newDeltaBangMany[n_, uuu_, vvvs_, Z_] := Module[{ttt},
  If[Length[vvvs] == 1, Z /. {uuu -> vvvs[[1]]},
   If[Length[vvvs] == 2, newDeltaBang2[n, uuu, vvvs, Z],
    newDeltaBangMany[n, ttt, Drop[vvvs, 1], 
     newDeltaBang2[n, uuu, {vvvs[[1]], ttt}, Z]]]]]

 
(* PUSHFORWARD ALONG THE POWER MAP *)

Clear[OMEGA$ND]
OMEGA$ND[n_, d_, p_] := OMEGA$ND[n, d, p] = Module[{vars, ns, A, B},
   vars = Table[Subscript[TMP$X, i], {i, 1, d}];
   ns = Table[n, {i, 1, d}];
   A = newDeltaBangMany[n, L, vars, L^p];
   B = newPsiBangMany[ns, vars, L, Expand[A]];
   Expand[B]
   ]

newOmegaBang[n_, 0, var1_, var2_, ZZ_] := Coefficient[ZZ, var1, 0]
newOmegaBang[n_, 1, var1_, var2_, ZZ_] := ZZ /. {var1 -> var2}
newOmegaBang[n_, d_, var1_, var2_, ZZ_] := Module[
  {Z = Expand[ZZ], m, A},
  m = Exponent[Z, var1];
  A = Sum[(OMEGA$ND[n, d, p] /. {L -> var2})*Coefficient[Z, var1, p], {p, 0, 
     m}];
  Expand[A]
  ]

(* P^n1 x P^n2 x P^n3 -> P^(d1*n1) x P^(d2*n2) x P^(d3*n3) -> P^(d1*n1 + \
d2*n2 + d3*n3 *) 
newOmegaBangLam[ns_, ds_, uuus_, www_, Z0_] := Module[
  {Z = Expand[Z0],
   m = Length[ns],
   vars, W, nds, ttt, i},
  vars = Table[Subscript[ttt, i], {i, 1, m}];
  nds = Table[ ns[[i]]*ds[[i]], {i, 1, m}];
  W = Z;
  For[i = 1, i <= m, i++, 
   W = newOmegaBang[ns[[i]], ds[[i]], uuus[[i]], vars[[i]], W]];
  newPsiBangMany[nds, vars, www, W]
  ]

 
(*only works for lists of equal length!!*)
Zip[as_, bs_] := MapThread[{#1, #2} &, {as, bs}]
Zip3[as_, bs_, cs_] := MapThread[{#1, #2, #3} &, {as, bs, cs}]

Fst[pair_] := pair[[1]]
Snd[pair_] := pair[[2]]

extendListWithZeros[L_, n_] := Join[L, Table[0, {i, 1, n - Length[L]}]]

EmptyPartQ[part_] := Length[part] == 0

DualPart[{}] := {}
DualPart[lam_] := 
 With[{m = lam[[1]]}, Table[Length[Select[lam, # >= i &]], {i, 1, m}]]
 
toExpoForm[{}] := {} 
toExpoForm[part_] := 
 Module[{k = Max[part]}, Table[Length[Select[part, # == j &]], {j, 1, k}]]

posVectorQ[as_] := Map[# >= 0 &, as] /. {List -> And};
kdeTriples[p_, ns_] := Module[
  {m = Length[ns],
   posQ, oneK, A},
  oneK[k_] := 
   Table[{k, ns - es, es}, {es, Combinatorica`Compositions[p - k, m]}];
  A = Table [oneK[k], {k, 0, p - 1}];
  A = Select[Flatten[A, 1], posVectorQ[Snd[#]] &];
  A]


(* motivic Chern class of P^n *)
Clear[mcPn];
mcPn[n_] := mcPn[n] =
  Module[{rel, tmp}, rel = Product[1 - L*X^(n - i)*Y^i, {i, 0, n}];
   tmp = Product[1 + t*L*X^(n - i)*Y^i, {i, 0, n}];
   Factor[(tmp - (-t)^(n + 1) rel)/(1 + t)]]

Clear[L, S]

LL[i_] := Subscript[L, i];
SS[i_] := Subscript[S, i];
LLs[n_] := Table[LL[i], {i, 1, n}]
SSs[n_] := Table[SS[i], {i, 1, n}]

Clear[mcXLam, mcDisj1, mcDisj, mcDisjSorted]

mcXLam[{}] := mcXLam[{}] = 1
mcXLam[{1}] := mcXLam[{1}] = mcPn[1]

mcDisj1[0] := mcDisj1[0] = 1
mcDisj1[1] := mcDisj1[1] = mcPn[1]

mcDisj[{}] := mcDisj[{}] = 1

mcDisjSorted[{}] := mcDisjSorted[{}] = 1

(* equivariant motivic chern class of D(n)=X(1^n) *)

mcDisj1[n_] := mcDisj1[n] = Module[
   {parts = Select[Combinatorica`Partitions[n], Length[#] < n &]},
   Expand[mcPn[n] - Sum[mcXLam[p], {p, parts}]]
   ]

(* equivariant motivic chern class of X_lambda *)

mcXLam[lambda_] := mcXLam[lambda] = Module[
   {es = toExpoForm[lambda], m, m1, ns, pairs, Z},
   m = Length[es];
   ns = Range[m];
   pairs = Zip[ns, es];   (* i^e_ *)
   
   pairs = Select[pairs, Snd[#] > 0 &]; (* !!! *)
   m1 = Length[pairs];
   ns = Map[Fst, pairs];
   es = Map[Snd, pairs];
   Z = mcDisj[es];
   (* Print["xlam1 - ",pairs];
   Print["xlam2 - ",es," | ",ns," | ",uus[m1]," | ",X]; *)
   
   Expand[newOmegaBangLam[es, ns, LLs[m1], L, Z]]
   ]

(* equivariant motivic chern class of D(d1,d2,...) *)

mcDisj[{n_}] := mcDisj[{n}] = mcDisj1[n] /. {L -> LL[1]}
mcDisj[ns0_] := mcDisj[ns0] = Module[
   {m = Length[ns0],
    nis0, nis1, ns1, idxs, X, ttt},
   nis0 = Zip[ns0, Range[m]];
   nis1 = SortBy[nis0, -Fst[#] &];
   idxs = Map[Snd, nis1];
   ns1 = Select[Map[Fst, nis1], # > 0 &];
   (* Print["nis1 - ",nis0," | ",nis1];
   Print["nis2 - ",ns1]; *)
   X = mcDisjSorted[ns1];
   X = X /. Table[LL[i] -> Subscript[ttt, i], {i, 1, m}];
   X /. Table[Subscript[ttt, i] -> LL[idxs[[i]]], {i, 1, m}]
   ]

(* a single term corresponding to a triple (k,ds,es) *)
Clear[singleKDE]
singleKDE[{k_, ds_, es_}] := ssingleKDE[{k, ds, es}] = Module[
   {A, B,
    m, vars, dims,
    pp, qq, rr, ss,
    pps, qqs, rrs, sss
    },
   m = Length[ds];
   pp[i_] := Subscript[pp$p, i];
   qq[i_] := Subscript[qq$q, i];
   rr[i_] := Subscript[rr$r, i];
   ss[i_] := Subscript[ss$s, i];
   pps = Table[pp[i], {i, 1, m}];
   qqs = Table[qq[i], {i, 1, m}];
   rrs = Table[rr[i], {i, 1, m}];
   sss = Table[ss[i], {i, 1, m}];
   vars = Join[{zzz}, pps, qqs];
   dims = Join[{k}, ds, es];
   A = mcDisj[dims] /. Table[LL[i] -> vars[[i]], {i, 1, 2 m + 1}];
   B = A;
   For[i = 1, i <= m, i++, 
    B = Expand[newDeltaBang2[es[[i]], qq[i], {rr[i], ss[i]}, B]]];
   For[i = 1, i <= m, i++, 
    B = Expand[newPsiBang2[{ds[[i]], es[[i]]}, {pp[i], ss[i]}, LL[i], B]]];
   B = newPsiBangMany[Join[{k}, es], Join[{zzz}, rrs], z, B];
   B
   ]

(* equiv mc of D(d1,d2,...), but we require d1>=d2>=d3>=...>=dn>0 *)

mcDisjSorted[{n_}] := mcDisjSorted[{n}] = mcDisj1[n] /. {L -> LL[1]}
mcDisjSorted[pns_] := mcDisjSorted[pns] = Module[
   {p = pns[[1]],
    ns = Drop[pns, 1],
    A, B, rest,
    KDE
    },
   KDE = kdeTriples[p, ns];
   (* Print["sorted1 - ",p," | ",ns];
   Print["sorted2 - ",KDE]; *)
   A = (mcDisj1[p] /. {L -> z})*mcDisj[ns];
   rest = Sum[singleKDE[kde], {kde, KDE}];
   B = Expand[A - rest];
   B = B /. Table[LL[i] -> LL[i + 1], {i, 1, Length[ns]}];
   B = B /. {z -> LL[1]}
   ]


(* export the classes of X(lambda) for |lambda|<=n *)

ExportMC[n_] := Module[
  {h, i, p, parts, k, m, s, j, A},
  h = OpenWrite["equivariant_mc_classes.txt"];
  For[i = 1, i <= n, i++,
    Print["\nn = ", i];
    WriteString[h, "\n(* =================== *)"];
    WriteString[h, "\n(* ----   n = " <> ToString[i] <> "   ---- *)\n\n"];
    parts = Partitions[i];
    m = Length[parts];
    For[j = 1, j <= m, j++,
     p = parts[[j]];
     Print["part = ", p];
     A = Expand[mcXLam[p]];
     (* Print[A]; *)
     
     s = ToString[A, FormatType -> InputForm, PageWidth -> Infinity, 
       TotalWidth -> Infinity];
     s = StringJoin["mc[", ToString[p], "] = ", s, " ;\n\n"];
     (* Print[s]; *)
     WriteString[h, s];
     ]
    ]
   Close[h];
  ]


mcXLam[{1, 1, 1}]

t - t^3 - L t X^3 + L t^3 X^3 - L X^2 Y - 2 L t X^2 Y + L t^3 X^2 Y + 
 L^2 t X^5 Y - L^2 t^3 X^5 Y - L X Y^2 - 2 L t X Y^2 + L t^3 X Y^2 + 
 L^2 X^4 Y^2 + L^2 t X^4 Y^2 - L^2 t^2 X^4 Y^2 - L^2 t^3 X^4 Y^2 - L t Y^3 + 
 L t^3 Y^3 + L^2 X^3 Y^3 + 2 L^2 t X^3 Y^3 - L^2 t^2 X^3 Y^3 - 
 2 L^2 t^3 X^3 Y^3 + L^3 t^2 X^6 Y^3 + L^3 t^3 X^6 Y^3 + L^2 X^2 Y^4 + 
 L^2 t X^2 Y^4 - L^2 t^2 X^2 Y^4 - L^2 t^3 X^2 Y^4 + L^3 t X^5 Y^4 + 
 2 L^3 t^2 X^5 Y^4 + L^3 t^3 X^5 Y^4 + L^2 t X Y^5 - L^2 t^3 X Y^5 + 
 L^3 t X^4 Y^5 + 2 L^3 t^2 X^4 Y^5 + L^3 t^3 X^4 Y^5 + L^3 t^2 X^3 Y^6 + 
 L^3 t^3 X^3 Y^6

mcXLam[{1, 1, 1, 1, 1}]

t^3 - t^5 - L t^3 X^5 + L t^5 X^5 - L t^3 X^4 Y + L t^5 X^4 Y + 
 L^2 t^3 X^9 Y - L^2 t^5 X^9 Y + L t X^3 Y^2 + L t^2 X^3 Y^2 - L t^3 X^3 Y^2 +
  L t^5 X^3 Y^2 + L^2 t^3 X^8 Y^2 - L^2 t^5 X^8 Y^2 + L t X^2 Y^3 + 
 L t^2 X^2 Y^3 - L t^3 X^2 Y^3 + L t^5 X^2 Y^3 - L^2 t X^7 Y^3 + 
 3 L^2 t^3 X^7 Y^3 - 2 L^2 t^5 X^7 Y^3 - L^3 t^3 X^12 Y^3 + L^3 t^5 X^12 Y^3 -
  L t^3 X Y^4 + L t^5 X Y^4 + L^2 t^2 X^6 Y^4 + 3 L^2 t^3 X^6 Y^4 - 
 2 L^2 t^5 X^6 Y^4 - L^3 t X^11 Y^4 - 2 L^3 t^2 X^11 Y^4 - 
 2 L^3 t^3 X^11 Y^4 + L^3 t^5 X^11 Y^4 - L t^3 Y^5 + L t^5 Y^5 + L^2 X^5 Y^5 +
  L^2 t^2 X^5 Y^5 + 5 L^2 t^3 X^5 Y^5 - 3 L^2 t^5 X^5 Y^5 - L^3 X^10 Y^5 - 
 2 L^3 t X^10 Y^5 - 4 L^3 t^2 X^10 Y^5 - 5 L^3 t^3 X^10 Y^5 + 
 2 L^3 t^5 X^10 Y^5 + L^2 t^2 X^4 Y^6 + 3 L^2 t^3 X^4 Y^6 - 
 2 L^2 t^5 X^4 Y^6 - L^3 X^9 Y^6 - 3 L^3 t X^9 Y^6 - 6 L^3 t^2 X^9 Y^6 - 
 7 L^3 t^3 X^9 Y^6 + 3 L^3 t^5 X^9 Y^6 + L^4 t^3 X^14 Y^6 - L^4 t^5 X^14 Y^6 -
  L^2 t X^3 Y^7 + 3 L^2 t^3 X^3 Y^7 - 2 L^2 t^5 X^3 Y^7 - L^3 X^8 Y^7 - 
 3 L^3 t X^8 Y^7 - 7 L^3 t^2 X^8 Y^7 - 8 L^3 t^3 X^8 Y^7 + 3 L^3 t^5 X^8 Y^7 +
  L^4 t X^13 Y^7 + 2 L^4 t^2 X^13 Y^7 + L^4 t^3 X^13 Y^7 - L^4 t^4 X^13 Y^7 - 
 L^4 t^5 X^13 Y^7 + L^2 t^3 X^2 Y^8 - L^2 t^5 X^2 Y^8 - L^3 X^7 Y^8 - 
 3 L^3 t X^7 Y^8 - 7 L^3 t^2 X^7 Y^8 - 8 L^3 t^3 X^7 Y^8 + 3 L^3 t^5 X^7 Y^8 +
  L^4 X^12 Y^8 + 2 L^4 t X^12 Y^8 + 4 L^4 t^2 X^12 Y^8 + 4 L^4 t^3 X^12 Y^8 - 
 L^4 t^4 X^12 Y^8 - 2 L^4 t^5 X^12 Y^8 + L^2 t^3 X Y^9 - L^2 t^5 X Y^9 - 
 L^3 X^6 Y^9 - 3 L^3 t X^6 Y^9 - 6 L^3 t^2 X^6 Y^9 - 7 L^3 t^3 X^6 Y^9 + 
 3 L^3 t^5 X^6 Y^9 + L^4 X^11 Y^9 + 5 L^4 t X^11 Y^9 + 8 L^4 t^2 X^11 Y^9 + 
 5 L^4 t^3 X^11 Y^9 - L^4 t^4 X^11 Y^9 - 2 L^4 t^5 X^11 Y^9 - L^3 X^5 Y^10 - 
 2 L^3 t X^5 Y^10 - 4 L^3 t^2 X^5 Y^10 - 5 L^3 t^3 X^5 Y^10 + 
 2 L^3 t^5 X^5 Y^10 + 2 L^4 X^10 Y^10 + 5 L^4 t X^10 Y^10 + 
 9 L^4 t^2 X^10 Y^10 + 8 L^4 t^3 X^10 Y^10 - L^4 t^4 X^10 Y^10 - 
 3 L^4 t^5 X^10 Y^10 + L^5 t^4 X^15 Y^10 + L^5 t^5 X^15 Y^10 - 
 L^3 t X^4 Y^11 - 2 L^3 t^2 X^4 Y^11 - 2 L^3 t^3 X^4 Y^11 + L^3 t^5 X^4 Y^11 +
  L^4 X^9 Y^11 + 5 L^4 t X^9 Y^11 + 8 L^4 t^2 X^9 Y^11 + 5 L^4 t^3 X^9 Y^11 - 
 L^4 t^4 X^9 Y^11 - 2 L^4 t^5 X^9 Y^11 + L^5 t^2 X^14 Y^11 + 
 2 L^5 t^3 X^14 Y^11 + 2 L^5 t^4 X^14 Y^11 + L^5 t^5 X^14 Y^11 - 
 L^3 t^3 X^3 Y^12 + L^3 t^5 X^3 Y^12 + L^4 X^8 Y^12 + 2 L^4 t X^8 Y^12 + 
 4 L^4 t^2 X^8 Y^12 + 4 L^4 t^3 X^8 Y^12 - L^4 t^4 X^8 Y^12 - 
 2 L^4 t^5 X^8 Y^12 + L^5 t X^13 Y^12 + 2 L^5 t^2 X^13 Y^12 + 
 3 L^5 t^3 X^13 Y^12 + 3 L^5 t^4 X^13 Y^12 + L^5 t^5 X^13 Y^12 + 
 L^4 t X^7 Y^13 + 2 L^4 t^2 X^7 Y^13 + L^4 t^3 X^7 Y^13 - L^4 t^4 X^7 Y^13 - 
 L^4 t^5 X^7 Y^13 + L^5 t X^12 Y^13 + 2 L^5 t^2 X^12 Y^13 + 
 3 L^5 t^3 X^12 Y^13 + 3 L^5 t^4 X^12 Y^13 + L^5 t^5 X^12 Y^13 + 
 L^4 t^3 X^6 Y^14 - L^4 t^5 X^6 Y^14 + L^5 t^2 X^11 Y^14 + 
 2 L^5 t^3 X^11 Y^14 + 2 L^5 t^4 X^11 Y^14 + L^5 t^5 X^11 Y^14 + 
 L^5 t^4 X^10 Y^15 + L^5 t^5 X^10 Y^15

mcXLam[{2, 2, 1, 1}]

-t - t^2 + t^3 + t^4 + L t X^6 + L t^2 X^6 - L t^3 X^6 - L t^4 X^6 + 
 L X^5 Y + 2 L t X^5 Y + L t^2 X^5 Y - L t^3 X^5 Y - L t^4 X^5 Y - 
 L^2 t X^11 Y - L^2 t^2 X^11 Y + L^2 t^3 X^11 Y + L^2 t^4 X^11 Y + 
 2 L t X^4 Y^2 + 2 L t^2 X^4 Y^2 - L t^3 X^4 Y^2 - L t^4 X^4 Y^2 - 
 L^2 X^10 Y^2 - 3 L^2 t X^10 Y^2 - 2 L^2 t^2 X^10 Y^2 + L^2 t^3 X^10 Y^2 + 
 L^2 t^4 X^10 Y^2 + L t X^3 Y^3 + L t^2 X^3 Y^3 - L t^3 X^3 Y^3 - 
 L t^4 X^3 Y^3 - 2 L^2 X^9 Y^3 - 7 L^2 t X^9 Y^3 - 6 L^2 t^2 X^9 Y^3 + 
 L^2 t^3 X^9 Y^3 + 2 L^2 t^4 X^9 Y^3 + L^3 t X^15 Y^3 + L^3 t^2 X^15 Y^3 - 
 L^3 t^3 X^15 Y^3 - L^3 t^4 X^15 Y^3 + 2 L t X^2 Y^4 + 2 L t^2 X^2 Y^4 - 
 L t^3 X^2 Y^4 - L t^4 X^2 Y^4 - 3 L^2 X^8 Y^4 - 11 L^2 t X^8 Y^4 - 
 10 L^2 t^2 X^8 Y^4 + 2 L^2 t^4 X^8 Y^4 + L^3 X^14 Y^4 + 4 L^3 t X^14 Y^4 + 
 3 L^3 t^2 X^14 Y^4 - L^3 t^3 X^14 Y^4 - L^3 t^4 X^14 Y^4 + L X Y^5 + 
 2 L t X Y^5 + L t^2 X Y^5 - L t^3 X Y^5 - L t^4 X Y^5 - 5 L^2 X^7 Y^5 - 
 15 L^2 t X^7 Y^5 - 13 L^2 t^2 X^7 Y^5 + 3 L^2 t^4 X^7 Y^5 + 3 L^3 X^13 Y^5 + 
 11 L^3 t X^13 Y^5 + 11 L^3 t^2 X^13 Y^5 + L^3 t^3 X^13 Y^5 - 
 2 L^3 t^4 X^13 Y^5 + L t Y^6 + L t^2 Y^6 - L t^3 Y^6 - L t^4 Y^6 - 
 5 L^2 X^6 Y^6 - 16 L^2 t X^6 Y^6 - 14 L^2 t^2 X^6 Y^6 + 3 L^2 t^4 X^6 Y^6 + 
 7 L^3 X^12 Y^6 + 21 L^3 t X^12 Y^6 + 19 L^3 t^2 X^12 Y^6 + 
 3 L^3 t^3 X^12 Y^6 - 2 L^3 t^4 X^12 Y^6 - L^4 t X^18 Y^6 - L^4 t^2 X^18 Y^6 +
  L^4 t^3 X^18 Y^6 + L^4 t^4 X^18 Y^6 - 5 L^2 X^5 Y^7 - 15 L^2 t X^5 Y^7 - 
 13 L^2 t^2 X^5 Y^7 + 3 L^2 t^4 X^5 Y^7 + 9 L^3 X^11 Y^7 + 
 30 L^3 t X^11 Y^7 + 30 L^3 t^2 X^11 Y^7 + 6 L^3 t^3 X^11 Y^7 - 
 3 L^3 t^4 X^11 Y^7 - L^4 X^17 Y^7 - 4 L^4 t X^17 Y^7 - 3 L^4 t^2 X^17 Y^7 + 
 L^4 t^3 X^17 Y^7 + L^4 t^4 X^17 Y^7 - 3 L^2 X^4 Y^8 - 11 L^2 t X^4 Y^8 - 
 10 L^2 t^2 X^4 Y^8 + 2 L^2 t^4 X^4 Y^8 + 13 L^3 X^10 Y^8 + 
 38 L^3 t X^10 Y^8 + 36 L^3 t^2 X^10 Y^8 + 9 L^3 t^3 X^10 Y^8 - 
 2 L^3 t^4 X^10 Y^8 - 3 L^4 X^16 Y^8 - 10 L^4 t X^16 Y^8 - 
 9 L^4 t^2 X^16 Y^8 + 2 L^4 t^4 X^16 Y^8 - 2 L^2 X^3 Y^9 - 7 L^2 t X^3 Y^9 - 
 6 L^2 t^2 X^3 Y^9 + L^2 t^3 X^3 Y^9 + 2 L^2 t^4 X^3 Y^9 + 13 L^3 X^9 Y^9 + 
 42 L^3 t X^9 Y^9 + 42 L^3 t^2 X^9 Y^9 + 10 L^3 t^3 X^9 Y^9 - 
 3 L^3 t^4 X^9 Y^9 - 6 L^4 X^15 Y^9 - 18 L^4 t X^15 Y^9 - 
 16 L^4 t^2 X^15 Y^9 - 2 L^4 t^3 X^15 Y^9 + 2 L^4 t^4 X^15 Y^9 - 
 L^2 X^2 Y^10 - 3 L^2 t X^2 Y^10 - 2 L^2 t^2 X^2 Y^10 + L^2 t^3 X^2 Y^10 + 
 L^2 t^4 X^2 Y^10 + 13 L^3 X^8 Y^10 + 38 L^3 t X^8 Y^10 + 
 36 L^3 t^2 X^8 Y^10 + 9 L^3 t^3 X^8 Y^10 - 2 L^3 t^4 X^8 Y^10 - 
 9 L^4 X^14 Y^10 - 27 L^4 t X^14 Y^10 - 24 L^4 t^2 X^14 Y^10 - 
 3 L^4 t^3 X^14 Y^10 + 3 L^4 t^4 X^14 Y^10 - L^5 t^2 X^20 Y^10 - 
 2 L^5 t^3 X^20 Y^10 - L^5 t^4 X^20 Y^10 - L^2 t X Y^11 - L^2 t^2 X Y^11 + 
 L^2 t^3 X Y^11 + L^2 t^4 X Y^11 + 9 L^3 X^7 Y^11 + 30 L^3 t X^7 Y^11 + 
 30 L^3 t^2 X^7 Y^11 + 6 L^3 t^3 X^7 Y^11 - 3 L^3 t^4 X^7 Y^11 - 
 11 L^4 X^13 Y^11 - 31 L^4 t X^13 Y^11 - 27 L^4 t^2 X^13 Y^11 - 
 4 L^4 t^3 X^13 Y^11 + 3 L^4 t^4 X^13 Y^11 - 2 L^5 t X^19 Y^11 - 
 6 L^5 t^2 X^19 Y^11 - 6 L^5 t^3 X^19 Y^11 - 2 L^5 t^4 X^19 Y^11 + 
 7 L^3 X^6 Y^12 + 21 L^3 t X^6 Y^12 + 19 L^3 t^2 X^6 Y^12 + 
 3 L^3 t^3 X^6 Y^12 - 2 L^3 t^4 X^6 Y^12 - 11 L^4 X^12 Y^12 - 
 33 L^4 t X^12 Y^12 - 29 L^4 t^2 X^12 Y^12 - 3 L^4 t^3 X^12 Y^12 + 
 4 L^4 t^4 X^12 Y^12 - L^5 X^18 Y^12 - 4 L^5 t X^18 Y^12 - 
 9 L^5 t^2 X^18 Y^12 - 10 L^5 t^3 X^18 Y^12 - 4 L^5 t^4 X^18 Y^12 + 
 3 L^3 X^5 Y^13 + 11 L^3 t X^5 Y^13 + 11 L^3 t^2 X^5 Y^13 + 
 L^3 t^3 X^5 Y^13 - 2 L^3 t^4 X^5 Y^13 - 11 L^4 X^11 Y^13 - 
 31 L^4 t X^11 Y^13 - 27 L^4 t^2 X^11 Y^13 - 4 L^4 t^3 X^11 Y^13 + 
 3 L^4 t^4 X^11 Y^13 - 3 L^5 t X^17 Y^13 - 11 L^5 t^2 X^17 Y^13 - 
 12 L^5 t^3 X^17 Y^13 - 4 L^5 t^4 X^17 Y^13 + L^3 X^4 Y^14 + 
 4 L^3 t X^4 Y^14 + 3 L^3 t^2 X^4 Y^14 - L^3 t^3 X^4 Y^14 - 
 L^3 t^4 X^4 Y^14 - 9 L^4 X^10 Y^14 - 27 L^4 t X^10 Y^14 - 
 24 L^4 t^2 X^10 Y^14 - 3 L^4 t^3 X^10 Y^14 + 3 L^4 t^4 X^10 Y^14 + 
 L^5 X^16 Y^14 - 7 L^5 t^2 X^16 Y^14 - 11 L^5 t^3 X^16 Y^14 - 
 5 L^5 t^4 X^16 Y^14 + L^3 t X^3 Y^15 + L^3 t^2 X^3 Y^15 - L^3 t^3 X^3 Y^15 - 
 L^3 t^4 X^3 Y^15 - 6 L^4 X^9 Y^15 - 18 L^4 t X^9 Y^15 - 
 16 L^4 t^2 X^9 Y^15 - 2 L^4 t^3 X^9 Y^15 + 2 L^4 t^4 X^9 Y^15 + 
 3 L^5 X^15 Y^15 + 3 L^5 t X^15 Y^15 - 7 L^5 t^2 X^15 Y^15 - 
 11 L^5 t^3 X^15 Y^15 - 4 L^5 t^4 X^15 Y^15 + L^6 t X^21 Y^15 + 
 3 L^6 t^2 X^21 Y^15 + 3 L^6 t^3 X^21 Y^15 + L^6 t^4 X^21 Y^15 - 
 3 L^4 X^8 Y^16 - 10 L^4 t X^8 Y^16 - 9 L^4 t^2 X^8 Y^16 + 
 2 L^4 t^4 X^8 Y^16 + L^5 X^14 Y^16 - 7 L^5 t^2 X^14 Y^16 - 
 11 L^5 t^3 X^14 Y^16 - 5 L^5 t^4 X^14 Y^16 + L^6 X^20 Y^16 + 
 7 L^6 t X^20 Y^16 + 12 L^6 t^2 X^20 Y^16 + 8 L^6 t^3 X^20 Y^16 + 
 2 L^6 t^4 X^20 Y^16 - L^4 X^7 Y^17 - 4 L^4 t X^7 Y^17 - 3 L^4 t^2 X^7 Y^17 + 
 L^4 t^3 X^7 Y^17 + L^4 t^4 X^7 Y^17 - 3 L^5 t X^13 Y^17 - 
 11 L^5 t^2 X^13 Y^17 - 12 L^5 t^3 X^13 Y^17 - 4 L^5 t^4 X^13 Y^17 + 
 4 L^6 X^19 Y^17 + 13 L^6 t X^19 Y^17 + 19 L^6 t^2 X^19 Y^17 + 
 14 L^6 t^3 X^19 Y^17 + 4 L^6 t^4 X^19 Y^17 - L^4 t X^6 Y^18 - 
 L^4 t^2 X^6 Y^18 + L^4 t^3 X^6 Y^18 + L^4 t^4 X^6 Y^18 - L^5 X^12 Y^18 - 
 4 L^5 t X^12 Y^18 - 9 L^5 t^2 X^12 Y^18 - 10 L^5 t^3 X^12 Y^18 - 
 4 L^5 t^4 X^12 Y^18 + 4 L^6 X^18 Y^18 + 16 L^6 t X^18 Y^18 + 
 24 L^6 t^2 X^18 Y^18 + 16 L^6 t^3 X^18 Y^18 + 4 L^6 t^4 X^18 Y^18 - 
 2 L^5 t X^11 Y^19 - 6 L^5 t^2 X^11 Y^19 - 6 L^5 t^3 X^11 Y^19 - 
 2 L^5 t^4 X^11 Y^19 + 4 L^6 X^17 Y^19 + 13 L^6 t X^17 Y^19 + 
 19 L^6 t^2 X^17 Y^19 + 14 L^6 t^3 X^17 Y^19 + 4 L^6 t^4 X^17 Y^19 - 
 L^5 t^2 X^10 Y^20 - 2 L^5 t^3 X^10 Y^20 - L^5 t^4 X^10 Y^20 + 
 L^6 X^16 Y^20 + 7 L^6 t X^16 Y^20 + 12 L^6 t^2 X^16 Y^20 + 
 8 L^6 t^3 X^16 Y^20 + 2 L^6 t^4 X^16 Y^20 + L^6 t X^15 Y^21 + 
 3 L^6 t^2 X^15 Y^21 + 3 L^6 t^3 X^15 Y^21 + L^6 t^4 X^15 Y^21