CSP.hs

-- Communicating Haskell Processes.
-- Copyright (c) 2008, University of Kent.
-- All rights reserved.
-- 
-- Redistribution and use in source and binary forms, with or without
-- modification, are permitted provided that the following conditions are
-- met:
--
--  * Redistributions of source code must retain the above copyright
--    notice, this list of conditions and the following disclaimer.
--  * Redistributions in binary form must reproduce the above copyright
--    notice, this list of conditions and the following disclaimer in the
--    documentation and/or other materials provided with the distribution.
--  * Neither the name of the University of Kent nor the names of its
--    contributors may be used to endorse or promote products derived from
--    this software without specific prior written permission.
--
-- THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
-- IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
-- THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
-- PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
-- CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
-- EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
-- PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
-- PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
-- LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
-- NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
-- SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

-- | This module contains support for CSP-style tracing.  A CSP trace is simply
-- a flat list of events in the order in which they occurred.
module Control.Concurrent.CHP.Traces.CSP (CSPTrace(..), runCHP_CSPTrace, runCHP_CSPTraceAndPrint) where

import Control.Concurrent.STM
import Control.Monad.State
import qualified Data.Map as Map
import Text.PrettyPrint.HughesPJ

import Control.Concurrent.CHP.Base
import Control.Concurrent.CHP.Traces.Base

-- | A classic CSP trace.  It is simply the channel labels, and a list of recorded
-- events in sequence -- the head of the list is the first (oldest) event.
newtype CSPTrace = CSPTrace (ChannelLabels, [RecordedEvent])

instance Show CSPTrace where
  show = renderStyle (Style OneLineMode 1 1) . prettyPrint

instance Trace CSPTrace where
  emptyTrace = CSPTrace (Map.empty, [])
  runCHPAndTrace p = do tv <- atomically $ newTVar []
                        runCHPProgramWith' (CSPTraceRev tv) toPublic p

  prettyPrint (CSPTrace (labels, events))
    = char '<' <+> (sep $ punctuate (char ',') $ map (text . nameCSP labels') events) <+> char '>'
    where
      labels' = ensureAllNamed labels events      

toPublic :: ChannelLabels -> SubTraceStore -> IO CSPTrace
toPublic l (CSPTraceRev tv)
  = do list <- atomically $ readTVar tv
       return $ CSPTrace (l, concatMap (\(n,es) -> concat $ replicate n $ reverse es) $ reverse list)
toPublic _ _ = error "Error in CSP trace -- tracing type got switched"

nameCSP :: ChannelLabels -> RecordedEvent -> String
nameCSP m = flip evalState m . nameEvent


runCHP_CSPTrace :: CHP a -> IO (Maybe a, CSPTrace)
runCHP_CSPTrace = runCHPAndTrace

runCHP_CSPTraceAndPrint :: CHP a -> IO ()
runCHP_CSPTraceAndPrint p = do (_, tr) <- runCHP_CSPTrace p
                               putStrLn $ show $ tr