Foundation.hs

{-# LANGUAGE InstanceSigs #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE RankNTypes #-}
{-# LANGUAGE TemplateHaskell #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE ViewPatterns #-}
{-# LANGUAGE NoImplicitPrelude #-}
{-# OPTIONS_GHC -Wno-missing-deriving-strategies #-}
{-# OPTIONS_GHC -Wno-partial-fields #-}

module BtcLsp.Yesod.Foundation where

import qualified BtcLsp.Class.Env as Class
import BtcLsp.Yesod.Data.BootstrapColor
import qualified BtcLsp.Yesod.Data.Language
import BtcLsp.Yesod.Import.NoFoundation
import BtcLsp.Yesod.TH (mkMessageNoFallback)
import Control.Monad.Logger (LogSource)
import qualified Data.CaseInsensitive as CI
import qualified Data.Kind as Kind
import Data.List.NonEmpty (NonEmpty ((:|)))
import qualified Data.Text.Encoding as TE
import Database.Persist.Sql (ConnectionPool, runSqlPool)
import Text.Hamlet (hamletFile)
import Text.Jasmine (minifym)
import Yesod.Auth.Dummy
import qualified Yesod.Auth.Message as Auth
import Yesod.Core.Types (Logger)
import qualified Yesod.Core.Unsafe as Unsafe
import Yesod.Default.Util (addStaticContentExternal)

-- | NOTE : this type aliases are there only because of
-- poor support of advanced Haskell in yesodroutes and i18n
-- files through Yesod TH.
--
-- !!! DO NOT USE DIRECTLY IN SOURCE CODE !!!
type Uuid'SwapIntoLnTable = Uuid 'SwapIntoLnTable

type Money'Lsp'OnChain'Gain = Money 'Lsp 'OnChain 'Gain

type Money'Usr'OnChain'Fund = Money 'Usr 'OnChain 'Fund

-- | The foundation datatype for your application. This can be a good place to
-- keep settings and values requiring initialization before your application
-- starts running, such as database connections. Every handler will have
-- access to the data present here.
data App = forall m.
  (Class.Env m) =>
  App
  { appSettings :: AppSettings,
    -- | Settings for static file serving.
    appStatic :: Static,
    -- | Database connection pool.
    appConnPool :: ~ConnectionPool,
    appHttpManager :: Manager,
    appLogger :: Logger,
    appMRunner :: UnliftIO m
  }

mkMessageNoFallback "App" "messages" $ "en" :| ["ru"]

data MenuItem = MenuItem
  { menuItemLabel :: AppMessage,
    menuItemRoute :: Route App,
    menuItemAccessCallback :: Bool,
    menuItemActiveCallback :: Bool,
    menuItemNoReferrer :: Bool
  }

data MenuTypes
  = NavbarLeft MenuItem
  | NavbarRight MenuItem

-- This is where we define all of the routes in our application. For a full
-- explanation of the syntax, please see:
-- http://www.yesodweb.com/book/routing-and-handlers
--
-- Note that this is really half the story; in Application.hs, mkYesodDispatch
-- generates the rest of the code. Please see the following documentation
-- for an explanation for this split:
-- http://www.yesodweb.com/book/scaffolding-and-the-site-template#scaffolding-and-the-site-template_foundation_and_application_modules
--
-- This function also generates the following type synonyms:
-- type Handler = HandlerFor App
-- type Widget = WidgetFor App ()
mkYesodData "App" $(parseRoutesFile "config/routes.yesodroutes")

-- | A convenient synonym for creating forms.
type Form x = Html -> MForm (HandlerFor App) (FormResult x, Widget)

-- | A convenient synonym for database access functions.
type DB a =
  forall (m :: Kind.Type -> Kind.Type).
  (MonadUnliftIO m) =>
  ReaderT SqlBackend m a

-- Please see the documentation for the Yesod typeclass. There are a number
-- of settings which can be configured by overriding methods here.
instance Yesod App where
  -- Controls the base of generated URLs. For more information on modifying,
  -- see: https://github.com/yesodweb/yesod/wiki/Overriding-approot
  approot :: Approot App
  approot = ApprootRequest $ \app req ->
    case appRoot $ appSettings app of
      Nothing -> getApprootText guessApproot app req
      Just root -> root

  -- Store session data on the client in encrypted cookies,
  -- default session idle timeout is 120 minutes
  makeSessionBackend :: App -> IO (Maybe SessionBackend)
  makeSessionBackend _ =
    Just
      <$> defaultClientSessionBackend
        120 -- timeout in minutes
        "config/client_session_key.aes"

  -- Yesod Middleware allows you to run code before and after each handler function.
  -- The defaultYesodMiddleware adds the response header "Vary: Accept, Accept-Language" and performs authorization checks.
  -- Some users may also want to add the defaultCsrfMiddleware, which:
  --   a) Sets a cookie with a CSRF token in it.
  --   b) Validates that incoming write requests include that token in either a header or POST parameter.
  -- To add it, chain it together with the defaultMiddleware: yesodMiddleware = defaultYesodMiddleware . defaultCsrfMiddleware
  -- For details, see the CSRF documentation in the Yesod.Core.Handler module of the yesod-core package.
  -- yesodMiddleware ::
  --   ( ToTypedContent res
  --   ) =>
  --   Handler res ->
  --   Handler res
  -- yesodMiddleware =
  --   defaultYesodMiddleware

  defaultLayout :: Widget -> Handler Html
  defaultLayout =
    newLayout Nothing

  -- The page to be redirected to when authentication is required.
  authRoute ::
    App ->
    Maybe (Route App)
  authRoute _ = Just $ AuthR LoginR

  isAuthorized ::
    -- The route the user is visiting.
    Route App ->
    -- Whether or not this is a "write" request.
    Bool ->
    Handler AuthResult
  -- Routes not requiring authentication.
  isAuthorized (AuthR _) _ = return Authorized
  isAuthorized HomeR _ = return Authorized
  isAuthorized FaviconR _ = return Authorized
  isAuthorized RobotsR _ = return Authorized
  isAuthorized (StaticR _) _ = return Authorized
  isAuthorized (LanguageR _) _ = return Authorized
  isAuthorized OpenChanR {} _ = pure Authorized
  isAuthorized SwapIntoLnCreateR {} _ = pure Authorized
  isAuthorized SwapIntoLnSelectR {} _ = pure Authorized
  isAuthorized AboutR _ = pure Authorized
  isAuthorized SwapUpdatesR {} _ = pure Authorized

  -- This function creates static content files in the static folder
  -- and names them based on a hash of their content. This allows
  -- expiration dates to be set far in the future without worry of
  -- users receiving stale content.
  addStaticContent ::
    -- The file extension
    Text ->
    -- The MIME content type
    Text ->
    -- The contents of the file
    LByteString ->
    Handler (Maybe (Either Text (Route App, [(Text, Text)])))
  addStaticContent ext mime content = do
    master <- getYesod
    let staticDir = appStaticDir $ appSettings master
    addStaticContentExternal
      minifym
      genFileName
      staticDir
      (StaticR . flip StaticRoute [])
      ext
      mime
      content
    where
      -- Generate a unique filename based on the content itself
      genFileName lbs = "autogen-" ++ base64md5 lbs

  -- What messages should be logged. The following includes all messages when
  -- in development, and warnings and errors in production.
  shouldLogIO :: App -> LogSource -> LogLevel -> IO Bool
  shouldLogIO app _source level =
    return $
      appShouldLogAll (appSettings app)
        || level == LevelWarn
        || level == LevelError

  makeLogger :: App -> IO Logger
  makeLogger = return . appLogger

-- Define breadcrumbs.
instance YesodBreadcrumbs App where
  -- Takes the route that the user is currently on, and returns a tuple
  -- of the 'Text' that you want the label to display, and a previous
  -- breadcrumb route.
  breadcrumb ::
    -- The route the user is visiting currently.
    Route App ->
    Handler (Text, Maybe (Route App))
  breadcrumb r = do
    render <- getMessageRender
    pure (render $ getMsg r, getParent r)
    where
      getMsg :: Route App -> AppMessage
      getMsg = \case
        StaticR _ -> MsgNothing
        FaviconR -> MsgNothing
        RobotsR -> MsgNothing
        LanguageR {} -> MsgNothing
        AuthR {} -> MsgNothing
        HomeR -> MsgHomeRLinkShort
        OpenChanR -> MsgOpenChanRLinkShort
        SwapIntoLnCreateR -> MsgSwapIntoLnCreateRLinkShort
        SwapIntoLnSelectR x -> MsgSwapIntoLnSelectRLinkShort x
        AboutR -> MsgAboutRLinkShort
        SwapUpdatesR _ _ -> MsgNothing
      getParent :: Route App -> Maybe (Route App)
      getParent = \case
        StaticR {} -> Nothing
        FaviconR -> Nothing
        RobotsR -> Nothing
        LanguageR {} -> Nothing
        HomeR -> Nothing
        AuthR {} -> Just HomeR
        OpenChanR -> Just HomeR
        SwapIntoLnCreateR -> Just HomeR
        SwapIntoLnSelectR {} -> Just SwapIntoLnCreateR
        AboutR -> Just HomeR
        SwapUpdatesR _ _ -> Nothing

-- How to run database actions.
instance YesodPersist App where
  type YesodPersistBackend App = SqlBackend
  runDB :: SqlPersistT Handler a -> Handler a
  runDB action = do
    master <- getYesod
    runSqlPool action $ appConnPool master

instance YesodPersistRunner App where
  getDBRunner :: Handler (DBRunner App, Handler ())
  getDBRunner = defaultGetDBRunner appConnPool

instance YesodAuth App where
  type AuthId App = UserId

  -- Where to send a user after successful login
  loginDest :: App -> Route App
  loginDest _ = HomeR

  -- Where to send a user after logout
  logoutDest :: App -> Route App
  logoutDest _ = HomeR

  -- Override the above two destinations when a Referer: header is present
  redirectToReferer :: App -> Bool
  redirectToReferer _ = True

  authenticate ::
    ( MonadHandler m,
      HandlerSite m ~ App
    ) =>
    Creds App ->
    m (AuthenticationResult App)
  authenticate _ =
    liftHandler $
      pure $ UserError Auth.AuthError

  -- You can add other plugins like Google Email, email or OAuth here
  authPlugins :: App -> [AuthPlugin App]
  authPlugins app =
    extraAuthPlugins
    where
      -- Enable authDummy login if enabled.
      extraAuthPlugins = [authDummy | appAuthDummyLogin $ appSettings app]

-- | Access function to determine if a user is logged in.
isAuthenticated :: Handler AuthResult
isAuthenticated = do
  muid <- maybeAuthId
  return $ case muid of
    Nothing -> Unauthorized "You must login to access this page"
    Just _ -> Authorized

instance YesodAuthPersist App

-- This instance is required to use forms. You can modify renderMessage to
-- achieve customized and internationalized form validation messages.
instance RenderMessage App FormMessage where
  renderMessage :: App -> [Lang] -> FormMessage -> Text
  renderMessage _ _ = defaultFormMessage

-- Useful when writing code that is re-usable outside of the Handler context.
-- An example is background jobs that send email.
-- This can also be useful for writing code that works across multiple Yesod applications.
instance HasHttpManager App where
  getHttpManager :: App -> Manager
  getHttpManager = appHttpManager

unsafeHandler :: App -> Handler a -> IO a
unsafeHandler = Unsafe.fakeHandlerGetLogger appLogger

data PanelConfig = PanelConfig
  { panelConfigColor :: BootstrapColor,
    panelConfigMsgShort :: AppMessage,
    panelConfigMsgLong :: AppMessage
  }

newLayout :: Maybe PanelConfig -> Widget -> Handler Html
newLayout mpcfg widget = do
  master <- getYesod
  mmsg <- getMessage
  mcurrentRoute <- getCurrentRoute

  -- Get the breadcrumbs, as defined in the YesodBreadcrumbs instance.
  (title, parents) <- breadcrumbs

  -- Define the menu items of the header.
  let menuItems =
        [ NavbarLeft $
            MenuItem
              { menuItemLabel = MsgHomeRLinkShort,
                menuItemRoute = HomeR,
                menuItemAccessCallback = True,
                menuItemActiveCallback = mcurrentRoute == Just HomeR,
                menuItemNoReferrer = False
              },
          NavbarLeft $
            MenuItem
              { menuItemLabel = MsgOpenChanRLinkShort,
                menuItemRoute = OpenChanR,
                menuItemAccessCallback = True,
                menuItemActiveCallback = mcurrentRoute == Just OpenChanR,
                menuItemNoReferrer = False
              },
          NavbarLeft $
            MenuItem
              { menuItemLabel = MsgSwapIntoLnCreateRLinkShort,
                menuItemRoute = SwapIntoLnCreateR,
                menuItemAccessCallback = True,
                menuItemActiveCallback =
                  maybe
                    False
                    ( \case
                        SwapIntoLnCreateR -> True
                        SwapIntoLnSelectR {} -> True
                        _ -> False
                    )
                    mcurrentRoute,
                menuItemNoReferrer = False
              },
          NavbarLeft $
            MenuItem
              { menuItemLabel = MsgAboutRLinkShort,
                menuItemRoute = AboutR,
                menuItemAccessCallback = True,
                menuItemActiveCallback = mcurrentRoute == Just AboutR,
                menuItemNoReferrer = False
              }
        ]

  let navbarLeftMenuItems = [x | NavbarLeft x <- menuItems]
  let navbarRightMenuItems = [x | NavbarRight x <- menuItems]

  let navbarLeftFilteredMenuItems = [x | x <- navbarLeftMenuItems, menuItemAccessCallback x]
  let navbarRightFilteredMenuItems = [x | x <- navbarRightMenuItems, menuItemAccessCallback x]

  -- We break up the default layout into two components:
  -- default-layout is the contents of the body tag, and
  -- default-layout-wrapper is the entire page. Since the final
  -- value passed to hamletToRepHtml cannot be a widget, this allows
  -- you to use normal widget features in default-layout.

  mLang <- lookupSession "_LANG"
  let disclaimerTos = $(widgetFile "disclaimer_tos")
  pc <- widgetToPageContent $ do
    addStylesheet $ StaticR css_bootstrap_css
    addStylesheet $ StaticR css_app_css
    --  generated from @Settings/StaticFiles.hs@
    $(widgetFile "default-layout")

  withUrlRenderer $(hamletFile "templates/default-layout-wrapper.hamlet")

panelLayout ::
  BootstrapColor ->
  AppMessage ->
  AppMessage ->
  Widget ->
  Handler Html
panelLayout color msgShort msgLong =
  newLayout . Just $
    PanelConfig
      { panelConfigColor = color,
        panelConfigMsgShort = msgShort,
        panelConfigMsgLong = msgLong
      }

-- Note: Some functionality previously present in the scaffolding has been
-- moved to documentation in the Wiki. Following are some hopefully helpful
-- links:
--
--
-- https://github.com/yesodweb/yesod/wiki/Sending-email
-- https://github.com/yesodweb/yesod/wiki/Serve-static-files-from-a-separate-domain
-- https://github.com/yesodweb/yesod/wiki/i18n-messages-in-the-scaffolding