diff --git a/LICENSE b/LICENSE
new file mode 100644
--- /dev/null
+++ b/LICENSE
@@ -0,0 +1,30 @@
+Copyright (c)2012, Jeremy Shaw
+
+All rights reserved.
+
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are met:
+
+    * Redistributions of source code must retain the above copyright
+      notice, this list of conditions and the following disclaimer.
+
+    * Redistributions in binary form must reproduce the above
+      copyright notice, this list of conditions and the following
+      disclaimer in the documentation and/or other materials provided
+      with the distribution.
+
+    * Neither the name of Jeremy Shaw nor the names of other
+      contributors may be used to endorse or promote products derived
+      from this software without specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+"AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
diff --git a/Setup.hs b/Setup.hs
new file mode 100644
--- /dev/null
+++ b/Setup.hs
@@ -0,0 +1,2 @@
+import Distribution.Simple
+main = defaultMain
diff --git a/Text/Reform/Blaze/Common.hs b/Text/Reform/Blaze/Common.hs
new file mode 100644
--- /dev/null
+++ b/Text/Reform/Blaze/Common.hs
@@ -0,0 +1,326 @@
+{-# LANGUAGE OverloadedStrings, ScopedTypeVariables, TypeFamilies #-}
+module Text.Reform.Blaze.Common where
+
+import Data.Monoid (mconcat, mempty, (<>))
+import Text.Reform.Backend
+import Text.Reform.Core
+import Text.Reform.Generalized as G
+import Text.Reform.Result (FormId, Result(Ok), unitRange)
+import Text.Blaze.Html (Html, (!), toValue)
+import qualified Text.Blaze.Html5  as H
+import Text.Blaze.Html5.Attributes (type_, name, value)
+import qualified Text.Blaze.Html5.Attributes as A
+
+instance H.ToValue FormId where
+    toValue fid = toValue (show fid)
+
+inputText :: (Monad m, FormError error, H.ToValue text) =>
+             (input -> Either error text)
+          -> text
+          -> Form m input error Html () text
+inputText getInput initialValue = G.input getInput inputField initialValue
+    where
+      inputField i a = H.input ! type_ "text" ! A.id (toValue i) ! name (toValue i) ! value (toValue a)
+
+inputPassword :: (Monad m, FormError error, H.ToValue text) =>
+             (input -> Either error text)
+          -> text
+          -> Form m input error Html () text
+inputPassword getInput initialValue = G.input getInput inputField initialValue
+    where
+      inputField i a = H.input ! type_ "password" ! A.id (toValue i) ! name (toValue i) ! value (toValue a)
+
+inputSubmit :: (Monad m, FormError error, H.ToValue text) =>
+             (input -> Either error text)
+          -> text
+          -> Form m input error Html () (Maybe text)
+inputSubmit getInput initialValue = G.inputMaybe getInput inputField initialValue
+    where
+      inputField i a = H.input ! type_ "submit" ! A.id (toValue i) ! name (toValue i) ! value (toValue a)
+
+inputReset :: (Monad m, FormError error, H.ToValue text) =>
+              text
+           -> Form m input error Html () ()
+inputReset lbl = G.inputNoData inputField lbl
+    where
+      inputField i a = H.input ! type_ "submit" ! A.id (toValue i) ! name (toValue i) ! value (toValue a)
+
+inputHidden :: (Monad m, FormError error, H.ToValue text) =>
+             (input -> Either error text)
+          -> text
+          -> Form m input error Html () text
+inputHidden getInput initialValue = G.input getInput inputField initialValue
+    where
+      inputField i a = H.input ! type_ "hidden" ! A.id (toValue i) ! name (toValue i) ! value (toValue a)
+
+inputButton :: (Monad m, FormError error, H.ToValue text) =>
+             text
+          -> Form m input error Html () ()
+inputButton label = G.inputNoData inputField label
+    where
+      inputField i a = H.input ! type_ "button" ! A.id (toValue i) ! name (toValue i) ! value (toValue a)
+
+
+textarea :: (Monad m, FormError error, H.ToMarkup text) =>
+            (input -> Either error text)
+         -> Int    -- ^ cols
+         -> Int    -- ^ rows
+         -> text   -- ^ initial text
+         -> Form m input error Html () text
+textarea getInput cols rows initialValue = G.input getInput textareaView initialValue
+    where
+      textareaView i txt =
+          H.textarea ! A.rows (toValue rows)
+                     ! A.cols (toValue cols)
+                     ! A.id   (toValue i)
+                     ! A.name (toValue i) $
+               H.toHtml txt
+
+
+-- | Create an @\<input type=\"file\"\>@ element
+--
+-- This control may succeed even if the user does not actually select a file to upload. In that case the uploaded name will likely be \"\" and the file contents will be empty as well.
+inputFile :: (Monad m, FormError error, FormInput input, ErrorInputType error ~ input) =>
+             Form m input error Html () (FileType input)
+inputFile = G.inputFile fileView
+    where
+      fileView i = H.input ! type_ "file" ! A.id (toValue i) ! name (toValue i)
+
+
+-- | Create a @\<button type=\"submit\"\>@ element
+buttonSubmit :: (Monad m, FormError error, H.ToValue text, H.ToMarkup children) =>
+                (input -> Either error text)
+             -> text
+             -> children
+             -> Form m input error Html () (Maybe text)
+buttonSubmit getInput text c = G.inputMaybe getInput inputField text
+    where
+      inputField i a = H.button ! type_ "submit" ! A.id (toValue i) ! name (toValue i) ! value (toValue a) $ H.toHtml c
+
+-- | create a  @\<button type=\"reset\"\>\<\/button\>@ element
+--
+-- This element does not add any data to the form data set.
+buttonReset :: (Monad m, FormError error, H.ToMarkup children) =>
+               children
+             -> Form m input error Html () ()
+buttonReset c = G.inputNoData inputField Nothing
+    where
+      inputField i a = H.button ! type_ "reset" ! A.id (toValue i) ! name (toValue i) $ H.toHtml c
+
+-- | create a  @\<button type=\"button\"\>\<\/button\>@ element
+--
+-- This element does not add any data to the form data set.
+button :: (Monad m, FormError error, H.ToMarkup children) =>
+          children
+       -> Form m input error Html () ()
+button c = G.inputNoData inputField Nothing
+    where
+      inputField i a = H.button ! type_ "button" ! A.id (toValue i) ! name (toValue i) $ H.toHtml c
+
+
+-- | create a @\<label\>@ element.
+--
+-- Use this with <++ or ++> to ensure that the @for@ attribute references the correct @id@.
+--
+-- > label "some input field: " ++> inputText ""
+label :: (Monad m, H.ToMarkup children) =>
+         children
+      -> Form m input error Html () ()
+label c = G.label mkLabel
+    where
+      mkLabel i = H.label ! A.for (toValue i) $ H.toHtml c
+
+
+
+-- | Create a single @\<input type=\"checkbox\"\>@ element
+--
+-- returns a 'Bool' indicating if it was checked or not.
+--
+-- see also 'inputCheckboxes'
+-- FIXME: Should this built on something in Generalized?
+inputCheckbox :: forall x error input m. (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+                   Bool  -- ^ initially checked
+                -> Form m input error Html () Bool
+inputCheckbox initiallyChecked =
+    Form $
+      do i <- getFormId
+         v <- getFormInput' i
+         case v of
+           Default   -> mkCheckbox i initiallyChecked
+           Missing   -> mkCheckbox i False -- checkboxes only appear in the submitted data when checked
+           (Found input) ->
+               case getInputString input of
+                 (Right _) -> mkCheckbox i True
+                 (Left  (e :: error) ) -> mkCheckbox i False
+    where
+      mkCheckbox i checked =
+          let checkbox  = H.input ! type_ "checkbox" ! A.id (toValue i) ! name (toValue i) ! value (toValue i)
+              checkbox' = if checked then checkbox ! A.checked "checked" else checkbox
+          in
+          return ( View $ const $  checkbox'
+                 , return $ Ok (Proved { proofs   = ()
+                                       , pos      = unitRange i
+                                       , unProved = if checked then True else False
+                                       })
+                 )
+
+-- | Create a group of @\<input type=\"checkbox\"\>@ elements
+--
+inputCheckboxes :: (Functor m, Monad m, FormError error, ErrorInputType error ~ input, FormInput input, H.ToMarkup lbl) =>
+                  [(a, lbl)]  -- ^ value, label, initially checked
+                -> (a -> Bool) -- ^ function which indicates if a value should be checked initially
+                -> Form m input error Html () [a]
+inputCheckboxes choices isChecked =
+    G.inputMulti choices mkCheckboxes isChecked
+    where
+      mkCheckboxes nm choices' = mconcat $ concatMap (mkCheckbox nm) choices'
+      mkCheckbox nm (i, val, lbl, checked) =
+          [ ((if checked then (! A.checked "checked") else id) $
+                     H.input ! type_ "checkbox" ! A.id (toValue i) ! name (toValue nm) ! value (toValue val))
+                  ,  H.label ! A.for (toValue i) $ H.toHtml lbl
+                  ]
+
+-- | Create a group of @\<input type=\"radio\"\>@ elements
+inputRadio :: (Functor m, Monad m, FormError error, ErrorInputType error ~ input, FormInput input, H.ToMarkup lbl) =>
+              [(a, lbl)]  -- ^ value, label, initially checked
+           -> (a -> Bool) -- ^ isDefault
+           -> Form m input error Html () a
+inputRadio choices isDefault =
+    G.inputChoice isDefault choices mkRadios
+    where
+      mkRadios nm choices' = mconcat $ concatMap (mkRadio nm) choices'
+      mkRadio nm (i, val, lbl, checked) =
+          [ ((if checked then (! A.checked "checked") else id) $
+             H.input ! type_ "radio" ! A.id (toValue i) ! name (toValue nm) ! value (toValue val))
+          ,  H.label ! A.for (toValue i) $ H.toHtml lbl
+          ,  H.br
+          ]
+
+-- | create @\<select\>\<\/select\>@ element plus its @\<option\>\<\/option\>@ children.
+--
+-- see also: 'selectMultiple'
+select :: (Functor m, Monad m, FormError error, ErrorInputType error ~ input, FormInput input, H.ToMarkup lbl) =>
+              [(a, lbl)]  -- ^ value, label
+           -> (a -> Bool) -- ^ isDefault, must match *exactly one* element in the list of choices
+           -> Form m input error Html () a
+select choices isDefault  =
+    G.inputChoice isDefault choices mkSelect
+    where
+      mkSelect nm choices' =
+          H.select ! name (toValue nm) $
+           mconcat $ map mkOption choices'
+
+      mkOption (_, val, lbl, selected) =
+          (if selected then (! A.selected "selected") else id)
+             H.option ! value (toValue val) $ H.toHtml lbl
+
+-- | create @\<select multiple=\"multiple\"\>\<\/select\>@ element plus its @\<option\>\<\/option\>@ children.
+--
+-- This creates a @\<select\>@ element which allows more than one item to be selected.
+selectMultiple :: (Functor m, Monad m, FormError error, ErrorInputType error ~ input, FormInput input, H.ToMarkup lbl) =>
+                  [(a, lbl)]  -- ^ value, label, initially checked
+               -> (a -> Bool)  -- ^ isSelected initially
+               -> Form m input error Html () [a]
+selectMultiple choices isSelected =
+    G.inputMulti choices mkSelect isSelected
+    where
+      mkSelect nm choices' =
+          H.select ! name (toValue nm) ! A.multiple "multiple" $
+           mconcat $ map mkOption choices'
+
+      mkOption (_, val, lbl, selected) =
+        (if selected then (! A.selected "selected") else id)
+             H.option ! value (toValue val) $ H.toHtml lbl
+
+{-
+inputMultiSelectOptGroup :: (Functor m, XMLGenerator x, EmbedAsChild x groupLbl, EmbedAsChild x lbl, EmbedAsAttr x (Attr String FormId), FormError error, ErrorInputType error ~ input, FormInput input, Monad m) =>
+                   [(groupLbl, [(a, lbl, Bool)])]  -- ^ value, label, initially checked
+                -> Form m input error Html () [a]
+inputMultiSelectOptGroup choices =
+    G.inputMulti choices mkSelect
+    where
+      mkSelect nm choices' =
+          [<select name=nm multiple="multiple">
+            <% mapM mkOptGroup choices' %>
+           </select>
+          ]
+      mkOptGroup (grpLabel, options) =
+          <optgroup label=grpLabel>
+           <% mapM mkOption options %>
+          </optgroup>
+      mkOption (_, val, lbl, selected) =
+          <option value=val (if selected then ["selected" := "selected"] else [])>
+           <% lbl %>
+          </option>
+-}
+
+-- | create a @\<ul\>@ which contains all the errors related to the 'Form'.
+--
+-- The @<\ul\>@ will have the attribute @class=\"reform-error-list\"@.
+errorList :: (Monad m, H.ToMarkup error) =>
+             Form m input error Html () ()
+errorList = G.errors mkErrors
+    where
+      mkErrors []   = mempty
+      mkErrors errs =
+          H.ul ! A.class_ "reform-error-list" $
+             mconcat $ map mkError errs
+      mkError e     = H.li $ H.toHtml e
+
+-- | create a @\<ul\>@ which contains all the errors related to the 'Form'.
+--
+-- Includes errors from child forms.
+--
+-- The @<\ul\>@ will have the attribute @class=\"reform-error-list\"@.
+childErrorList :: (Monad m, H.ToMarkup error) =>
+             Form m input error Html () ()
+childErrorList = G.childErrors mkErrors
+    where
+      mkErrors []   = mempty
+      mkErrors errs =
+          H.ul ! A.class_ "reform-error-list" $
+             mconcat $ map mkError errs
+      mkError e     = H.li $ H.toHtml e
+
+
+-- | create a @\<br\>@ tag.
+br :: (Monad m) => Form m input error Html () ()
+br = view H.br
+
+-- | wrap a @\<fieldset class=\"reform\"\>@ around a 'Form'
+--
+fieldset :: (Monad m, Functor m) =>
+            Form m input error Html proof a
+         -> Form m input error Html proof a
+fieldset frm = mapView (H.fieldset ! A.class_ "reform") frm
+
+-- | wrap an @\<ol class=\"reform\"\>@ around a 'Form'
+ol :: (Monad m, Functor m) =>
+      Form m input error Html proof a
+   -> Form m input error Html proof a
+ol frm = mapView (H.ol ! A.class_ "reform") frm
+
+-- | wrap a @\<ul class=\"reform\"\>@ around a 'Form'
+ul :: (Monad m, Functor m) =>
+      Form m input error Html proof a
+   -> Form m input error Html proof a
+ul frm = mapView (H.ul ! A.class_ "reform") frm
+
+-- | wrap a @\<li class=\"reform\"\>@ around a 'Form'
+li :: (Monad m, Functor m) =>
+      Form m input error Html proof a
+   -> Form m input error Html proof a
+li frm = mapView (H.li ! A.class_ "reform") frm
+
+-- | create @\<form action=action method=\"POST\" enctype=\"multipart/form-data\"\>@
+form :: (H.ToValue action) =>
+        action                  -- ^ action url
+     -> [(String, String)]       -- ^ hidden fields to add to form
+     -> Html -- ^ children
+     -> Html
+form action hidden children =
+    H.form ! A.action (toValue action) ! A.method "POST" ! A.enctype "multipart/form-data" $
+         ((mconcat $ map mkHidden hidden) <> children)
+      where
+        mkHidden (nm, val) =
+            H.input ! type_ "hidden" ! name (toValue nm) ! value (toValue val)
diff --git a/Text/Reform/Blaze/String.hs b/Text/Reform/Blaze/String.hs
new file mode 100644
--- /dev/null
+++ b/Text/Reform/Blaze/String.hs
@@ -0,0 +1,107 @@
+{-# LANGUAGE FlexibleContexts, FlexibleInstances, MultiParamTypeClasses, ScopedTypeVariables, TypeFamilies, UndecidableInstances, ViewPatterns #-}
+{- |
+This module provides functions creating Reform using blaze-html markup.
+
+This module assumes that you wish for text based controls such as 'inputText' and 'textarea' to using 'String' values. If you prefer 'Data.Text.Text' see "Text.Reform.Blaze.Text".
+
+-}
+module Text.Reform.Blaze.String
+    ( -- * \<input\> element
+      inputText
+    , inputPassword
+    , inputSubmit
+    , inputReset
+    , inputHidden
+    , inputButton
+    , C.inputCheckbox
+    , C.inputCheckboxes
+    , C.inputRadio
+    , C.inputFile
+      -- * \<textarea\> element
+    , textarea
+      -- * \<button\> element
+    , buttonSubmit
+    , C.buttonReset
+    , C.button
+      -- * \<select\> element
+    , C.select
+    , C.selectMultiple
+      -- * \<label\> element
+    , C.label
+      -- * errors
+    , C.errorList
+    , C.childErrorList
+      -- * layout functions
+    , C.br
+    , C.fieldset
+    , C.ol
+    , C.ul
+    , C.li
+    , C.form
+    ) where
+
+import Text.Blaze.Html (Html, ToMarkup)
+import Text.Reform
+import qualified Text.Reform.Blaze.Common as C
+
+-- | Create an @\<input type=\"text\"\>@ element
+inputText :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+               String -- ^ initial value
+            -> Form m input error Html () String
+inputText initialValue = C.inputText getInputString initialValue
+
+-- | Create an @\<input type=\"password\"\>@ element
+inputPassword :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+                 Form m input error Html () String
+inputPassword = C.inputPassword getInputString ""
+
+-- | Create an @\<input type=\"submit\"\>@ element
+--
+-- returns:
+--
+--   [@Just@ /value/] if this button was used to submit the form.
+--
+--   [@Nothing@]    if this button was not used to submit the form.
+inputSubmit :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+               String -- ^ @value@ attribute. Used for button label, and value if button is submitted.
+            -> Form m input error Html () (Maybe String)
+inputSubmit initialValue = C.inputSubmit getInputString initialValue
+
+-- | Create an @\<input type=\"reset\"\>@ element
+--
+-- This element does not add any data to the form data set.
+inputReset :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+              String -- ^ value attribute. Used only to label the button.
+           -> Form m input error Html () ()
+inputReset = C.inputReset
+
+-- | Create an @\<input type=\"hidden\"\>@ element
+inputHidden :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+               String -- ^ value to store in the hidden element
+            -> Form m input error Html () String
+inputHidden initialValue = C.inputHidden getInputString initialValue
+
+-- | Create an @\<input type=\"button\"\>@ element
+--
+-- The element is a push button with a text label. The button does nothing by default, but actions can be added using javascript. This element does not add any data to the form data set.
+--
+-- see also: 'C.button'
+inputButton :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+               String -- ^ value attribute. Used to label the button.
+            -> Form m input error Html () ()
+inputButton label = C.inputButton label
+
+-- | Create a \<textarea\>\<\/textarea\> element
+textarea :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+            Int    -- ^ cols
+         -> Int    -- ^ rows
+         -> String -- ^ initial contents
+         -> Form m input error Html () String
+textarea rows cols initialValue = C.textarea getInputString rows cols initialValue
+
+-- | create a  @\<button type=\"submit\"\>\<\/button\>@ element
+buttonSubmit :: ( Monad m, FormError error, FormInput input, ErrorInputType error ~ input, ToMarkup children) =>
+                String -- ^ value attribute. Returned if this button submits the form.
+             -> children -- ^ children to embed in the \<button\>
+             -> Form m input error Html () (Maybe String)
+buttonSubmit = C.buttonSubmit getInputString
diff --git a/Text/Reform/Blaze/Text.hs b/Text/Reform/Blaze/Text.hs
new file mode 100644
--- /dev/null
+++ b/Text/Reform/Blaze/Text.hs
@@ -0,0 +1,108 @@
+{-# LANGUAGE FlexibleContexts, FlexibleInstances, MultiParamTypeClasses, ScopedTypeVariables, TypeFamilies, UndecidableInstances, ViewPatterns #-}
+{- |
+This module provides functions creating Reform using blaze-html markup.
+
+This module assumes that you wish for text based controls such as 'inputText' and 'textarea' to using 'Text' values. If you prefer 'String' see "Text.Reform.Blaze.String".
+
+-}
+module Text.Reform.Blaze.Text
+    ( -- * \<input\> element
+      inputText
+    , inputPassword
+    , inputSubmit
+    , inputReset
+    , inputHidden
+    , inputButton
+    , C.inputCheckbox
+    , C.inputCheckboxes
+    , C.inputRadio
+    , C.inputFile
+      -- * \<textarea\> element
+    , textarea
+      -- * \<button\> element
+    , buttonSubmit
+    , C.buttonReset
+    , C.button
+      -- * \<select\> element
+    , C.select
+    , C.selectMultiple
+      -- * \<label\> element
+    , C.label
+      -- * errors
+    , C.errorList
+    , C.childErrorList
+      -- * layout functions
+    , C.br
+    , C.fieldset
+    , C.ol
+    , C.ul
+    , C.li
+    , C.form
+    ) where
+
+import Data.Text (Text, empty)
+import Text.Blaze.Html (Html, ToMarkup)
+import Text.Reform
+import qualified Text.Reform.Blaze.Common as C
+
+-- | Create an @\<input type=\"text\"\>@ element
+inputText :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+               Text -- ^ initial value
+            -> Form m input error Html () Text
+inputText initialValue = C.inputText getInputText initialValue
+
+-- | Create an @\<input type=\"password\"\>@ element
+inputPassword :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+                 Form m input error Html () Text
+inputPassword = C.inputPassword getInputText empty
+
+-- | Create an @\<input type=\"submit\"\>@ element
+--
+-- returns:
+--
+--   [@Just@ /value/] if this button was used to submit the form.
+--
+--   [@Nothing@]    if this button was not used to submit the form.
+inputSubmit :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+               Text -- ^ @value@ attribute. Used for button label, and value if button is submitted.
+            -> Form m input error Html () (Maybe Text)
+inputSubmit initialValue = C.inputSubmit getInputText initialValue
+
+-- | Create an @\<input type=\"reset\"\>@ element
+--
+-- This element does not add any data to the form data set.
+inputReset :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+              Text -- ^ value attribute. Used only to label the button.
+           -> Form m input error Html () ()
+inputReset = C.inputReset
+
+-- | Create an @\<input type=\"hidden\"\>@ element
+inputHidden :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+               Text -- ^ value to store in the hidden element
+            -> Form m input error Html () Text
+inputHidden initialValue = C.inputHidden getInputText initialValue
+
+-- | Create an @\<input type=\"button\"\>@ element
+--
+-- The element is a push button with a text label. The button does nothing by default, but actions can be added using javascript. This element does not add any data to the form data set.
+--
+-- see also: 'C.button'
+inputButton :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+               Text -- ^ value attribute. Used to label the button.
+            -> Form m input error Html () ()
+inputButton label = C.inputButton label
+
+-- | Create a \<textarea\>\<\/textarea\> element
+textarea :: (Monad m, FormInput input, FormError error, ErrorInputType error ~ input) =>
+            Int    -- ^ cols
+         -> Int    -- ^ rows
+         -> Text -- ^ initial contents
+         -> Form m input error Html () Text
+textarea rows cols initialValue = C.textarea getInputText rows cols initialValue
+
+-- | create a  @\<button type=\"submit\"\>\<\/button\>@ element
+buttonSubmit :: ( Monad m, FormError error, FormInput input, ErrorInputType error ~ input, ToMarkup children) =>
+                Text -- ^ value attribute. Returned if this button submits the form.
+             -> children -- ^ children to embed in the \<button\>
+             -> Form m input error Html () (Maybe Text)
+buttonSubmit = C.buttonSubmit getInputText
diff --git a/reform-blaze.cabal b/reform-blaze.cabal
new file mode 100644
--- /dev/null
+++ b/reform-blaze.cabal
@@ -0,0 +1,29 @@
+Name:                reform-blaze
+Version:             0.1
+Synopsis:            Add support for using blaze-html with Reform
+Description:         Reform is a library for building and validating forms using applicative functors. This package add support for using reform with blaze-html.
+Homepage:            http://www.happstack.com/
+License:             BSD3
+License-file:        LICENSE
+Author:              Jeremy Shaw
+Maintainer:          jeremy@n-heptane.com
+Copyright:           2012 Jeremy Shaw, SeeReason Partners LLC
+Category:            Web
+Build-type:          Simple
+Cabal-version:       >=1.6
+
+source-repository head
+    type:     darcs
+    subdir:   reform-blaze
+    location: http://patch-tag.com/r/stepcut/reform
+
+Library
+  Exposed-modules:   Text.Reform.Blaze.Common
+                     Text.Reform.Blaze.String
+                     Text.Reform.Blaze.Text
+
+  Build-depends:     base         >4 && <5,
+                     blaze-markup == 0.5.*,
+                     blaze-html   == 0.5.*,
+                     reform       == 0.1.*,
+                     text         == 0.11.*