diff --git a/ChangeLog.md b/ChangeLog.md
new file mode 100644
--- /dev/null
+++ b/ChangeLog.md
@@ -0,0 +1,5 @@
+# Changelog for polysemy-extra
+
+## v0.1.0.0
+
+* Add several `Input`, `Output` and `KVStore` functions that I use..
diff --git a/LICENSE b/LICENSE
new file mode 100644
--- /dev/null
+++ b/LICENSE
@@ -0,0 +1,30 @@
+Copyright Daniel Firth (c) 2020
+
+All rights reserved.
+
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are met:
+
+    * Redistributions of source code must retain the above copyright
+      notice, this list of conditions and the following disclaimer.
+
+    * Redistributions in binary form must reproduce the above
+      copyright notice, this list of conditions and the following
+      disclaimer in the documentation and/or other materials provided
+      with the distribution.
+
+    * Neither the name of Author name here nor the names of other
+      contributors may be used to endorse or promote products derived
+      from this software without specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+"AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
diff --git a/README.md b/README.md
new file mode 100644
--- /dev/null
+++ b/README.md
@@ -0,0 +1,5 @@
+# polysemy-extra
+
+This package provides some extra polysemy functions that I use for
+transforming `Input`, `Output` and `KVStore`. Maybe this will make
+its way into the main library.
diff --git a/polysemy-extra.cabal b/polysemy-extra.cabal
new file mode 100644
--- /dev/null
+++ b/polysemy-extra.cabal
@@ -0,0 +1,37 @@
+cabal-version: 1.12
+
+-- This file has been generated from package.yaml by hpack version 0.34.2.
+--
+-- see: https://github.com/sol/hpack
+
+name:           polysemy-extra
+version:        0.1.0.0
+synopsis:       Run a KVStore as a filesystem in polysemy.
+category:       Polysemy
+author:         Daniel Firth
+maintainer:     dan.firth@homotopic.tech
+copyright:      2020 Daniel Firth
+license:        MIT
+license-file:   LICENSE
+build-type:     Simple
+extra-source-files:
+    README.md
+    ChangeLog.md
+
+source-repository head
+  type: git
+  location: https://gitlab.com/homotopic-tech/polysemy-extra
+
+library
+  exposed-modules:
+      Polysemy.Extra
+  other-modules:
+      Paths_polysemy_extra
+  hs-source-dirs:
+      src
+  build-depends:
+      base >=4.7 && <5
+    , containers
+    , polysemy
+    , polysemy-zoo
+  default-language: Haskell2010
diff --git a/src/Polysemy/Extra.hs b/src/Polysemy/Extra.hs
new file mode 100644
--- /dev/null
+++ b/src/Polysemy/Extra.hs
@@ -0,0 +1,86 @@
+{-# LANGUAGE BlockArguments #-}
+{-# LANGUAGE DataKinds      #-}
+{-# LANGUAGE ExplicitForAll #-}
+{-# LANGUAGE GADTs          #-}
+{-# LANGUAGE LambdaCase     #-}
+{-# LANGUAGE PolyKinds      #-}
+{-# LANGUAGE ScopedTypeVariables #-}
+{-# LANGUAGE TypeApplications #-}
+{-# LANGUAGE TypeOperators  #-}
+module Polysemy.Extra where
+
+import Data.Map as Map
+import Polysemy
+import Polysemy.KVStore
+import Polysemy.Input
+import Polysemy.Output
+
+-- | Run a KVStore in terms of another KVStore by way of pure key and value
+-- transformations.
+runKVStoreAsKVStore :: forall k v k' v' r a.
+                       (k  -> k')
+                    -> (v  -> v')
+                    -> (v' -> v )
+                    -> Sem (KVStore k v ': r) a
+                    -> Sem (KVStore k' v' ': r) a
+runKVStoreAsKVStore f g h = reinterpret \case
+  LookupKV k   -> fmap h <$> lookupKV @k' @v' (f k)
+  UpdateKV k x -> updateKV @k' @v' (f k) (fmap g x)
+
+-- | Run a KVStore in terms of another KVStore by way of transforming the
+-- keys and values with Sem functions.
+runKVStoreAsKVStoreSem :: forall k v k' v' r a.
+                          Members '[KVStore k' v'] r
+                       => (k  -> Sem r k')
+                       -> (v  -> Sem r v')
+                       -> (v' -> Sem r v )
+                       -> Sem (KVStore k v ': r) a
+                       -> Sem r a
+runKVStoreAsKVStoreSem f g h = interpret \case
+  LookupKV k   -> f k >>= lookupKV @k' @v' >>= sequence . fmap h
+  UpdateKV k x -> do
+    z  <- f k
+    z' <- sequence . fmap g $ x
+    updateKV @k' @v' z z'
+
+-- | Run an `Output (Map k v)` as a `KVStore` by writing the values to
+-- the keys.
+runOutputMapAsKVStore :: Members '[ KVStore k v ] r
+                      => Sem (Output (Map k v) ': r) a
+                      -> Sem r a
+runOutputMapAsKVStore = interpret \case
+  Output xs -> mapM_ (uncurry writeKV) (Map.toList xs)
+
+-- | Map an Output forwards 
+mapOutput :: Members '[ Output o' ] r
+          => (o -> o')
+          -> Sem (Output o ': r) a
+          -> Sem r a
+mapOutput f = interpret \case
+  Output o -> output (f o)
+
+-- | Map an Output forwards through a monadic function.
+mapOutputSem :: Members '[ Output o' ] r
+             => (o -> Sem r o')
+             -> Sem (Output o ': r) a
+             -> Sem r a
+mapOutputSem f = interpret \case
+  Output o -> f o >>= output
+
+-- | Map an `Input` contravariantly.
+contramapInput :: forall i i' r a.
+            Members '[ Input i' ] r
+         => (i' -> i)
+         -> Sem (Input i ': r) a
+         -> Sem r a
+contramapInput f = interpret \case
+  Input -> f <$> input @i'
+
+-- | Map an `Input` contravariantly through a monadic function.
+contramapInputSem :: forall i i' r a.
+                     Members '[ Input i' ] r
+                  => (i' -> Sem r i)
+                  -> Sem (Input i ': r) a
+                  -> Sem r a
+contramapInputSem f = interpret \case
+  Input -> f =<< input @i'