"
+ , Text.dropEnd
+ 1
+ (Text.unlines (map (foldMap emphasizeChunkHtml) lines'))
+ , ""
+ , ""
+ ]
+
+emphasizeRangeLatex ::
+ (String, [String], [(String, String)]) -> EmphasizedLines -> Block
+emphasizeRangeLatex (_, classes, _) lines' =
+ RawBlock (Format "latex") (Text.unpack (encloseInVerbatim emphasized))
+ where
+ languageAttr =
+ case classes of
+ [lang] -> ",language=" <> Text.pack lang
+ _ -> ""
+ encloseInTextIt t
+ | Text.null t = t
+ | otherwise = "£\\CodeEmphasis{" <> t <> "}£"
+ emphasizeNonSpace t
+ | Text.null t = t
+ | otherwise =
+ let (nonSpace, rest) = Text.break isSpace t
+ (spaces, rest') = Text.span isSpace rest
+ in mconcat [encloseInTextIt nonSpace, spaces, emphasizeNonSpace rest']
+ emphasizeChunk chunk =
+ case chunk of
+ Literal t -> t
+ Emphasized t -> emphasizeNonSpace t
+ emphasized = Text.unlines (map (foldMap emphasizeChunk) lines')
+ encloseInVerbatim t =
+ mconcat
+ [ "\\begin{lstlisting}[escapechar=£"
+ , languageAttr
+ , "]\n"
+ , t
+ , "\\end{lstlisting}\n"
+ ]
+
+type Emphasizer
+ = (String, [String], [(String, String)]) -> EmphasizedLines -> Block
+
+asEmphasizer :: Format -> Maybe Emphasizer
+asEmphasizer f
+ | f `elem` ["html", "html5"] = Just emphasizeRangeHtml
+ | f == "markdown_github" = Just emphasizeRangeMarkdown
+ | f == "latex" = Just emphasizeRangeLatex
+ | f == "beamer" = Just emphasizeRangeLatex
+ | otherwise = Nothing
+
+lookupRanges :: HM.HashMap String String -> Maybe Text.Text
+lookupRanges attrs = Text.pack <$> HM.lookup "emphasize" attrs
+
+-- | A Pandoc filter that emphasizes code blocks.
+emphasizeCode :: Maybe Format -> Block -> IO Block
+emphasizeCode (Just (asEmphasizer -> Just emphasizer)) cb@(CodeBlock (id', classes, attrs) contents) =
+ case lookupRanges attrs' >>= (runParser . parseRanges) of
+ Just (Right ranges) ->
+ let lines' = emphasizeRanges (splitRanges ranges) (Text.pack contents)
+ in return
+ (emphasizer
+ (id', classes, HM.toList (HM.delete "emphasize" attrs'))
+ lines')
+ Just (Left err) -> printAndFail err
+ Nothing -> return cb
+ where
+ attrs' = HM.fromList attrs
+emphasizeCode _ x = return x
diff --git a/src/Text/Pandoc/Filter/EmphasizeCode/Chunking.hs b/src/Text/Pandoc/Filter/EmphasizeCode/Chunking.hs
new file mode 100644
--- /dev/null
+++ b/src/Text/Pandoc/Filter/EmphasizeCode/Chunking.hs
@@ -0,0 +1,63 @@
+{-# LANGUAGE CPP #-}
+{-# LANGUAGE OverloadedStrings #-}
+
+module Text.Pandoc.Filter.EmphasizeCode.Chunking
+ ( LineChunk(..)
+ , EmphasizedLine
+ , EmphasizedLines
+ , emphasizeRanges
+ ) where
+
+import Data.HashMap.Strict (HashMap)
+import qualified Data.HashMap.Strict as HashMap
+import Data.List (foldl')
+import Data.Text (Text)
+import qualified Data.Text as Text
+
+import Text.Pandoc.Filter.EmphasizeCode.Position
+import Text.Pandoc.Filter.EmphasizeCode.Range
+
+data LineChunk
+ = Literal Text
+ | Emphasized Text
+ deriving (Show, Eq)
+
+chunkText :: LineChunk -> Text
+chunkText (Literal t) = t
+chunkText (Emphasized t) = t
+
+type EmphasizedLine = [LineChunk]
+
+type EmphasizedLines = [EmphasizedLine]
+
+emphasizeRanges :: HashMap Line [LineRange] -> Text -> EmphasizedLines
+emphasizeRanges ranges contents = zipWith chunkLine (Text.lines contents) [1 ..]
+ where
+ chunkLine line' lineNr =
+ let (rest, _, chunks) =
+ foldl'
+ chunkRange
+ (line', 0, [])
+ (HashMap.lookupDefault [] lineNr ranges)
+ in filter (not . Text.null . chunkText) (chunks ++ [Literal rest])
+ chunkRange ::
+ (Text, Column, EmphasizedLine)
+ -> LineRange
+ -> (Text, Column, EmphasizedLine)
+ chunkRange (lineText, offset, chunks) r =
+ case Text.splitAt startIndex lineText of
+ (before, rest) ->
+ case lineRangeEnd r of
+ Just end ->
+ let endIndex = fromIntegral (end - offset) - Text.length before
+ (emph, rest') = Text.splitAt endIndex rest
+ newOffset =
+ offset +
+ fromIntegral (Text.length lineText - Text.length rest')
+ in (rest', newOffset, chunks ++ [Literal before, Emphasized emph])
+ Nothing ->
+ ( ""
+ , offset + fromIntegral (Text.length lineText)
+ , chunks ++ [Literal before, Emphasized rest])
+ where
+ startIndex = fromIntegral (lineRangeStart r - 1 - offset)
diff --git a/src/Text/Pandoc/Filter/EmphasizeCode/Parser.hs b/src/Text/Pandoc/Filter/EmphasizeCode/Parser.hs
new file mode 100644
--- /dev/null
+++ b/src/Text/Pandoc/Filter/EmphasizeCode/Parser.hs
@@ -0,0 +1,74 @@
+{-# LANGUAGE CPP #-}
+{-# LANGUAGE FlexibleContexts #-}
+{-# LANGUAGE NamedFieldPuns #-}
+{-# LANGUAGE OverloadedStrings #-}
+
+module Text.Pandoc.Filter.EmphasizeCode.Parser
+ ( Parser
+ , ParseError(..)
+ , parseRanges
+ , runParser
+ ) where
+
+import Control.Monad.Except
+import Data.Text (Text)
+import qualified Data.Text as Text
+import Text.Read (readMaybe)
+
+import Text.Pandoc.Filter.EmphasizeCode.Position
+import Text.Pandoc.Filter.EmphasizeCode.Range
+
+type Parser a = ExceptT ParseError Maybe a
+
+data ParseError
+ = InvalidRange Position
+ Position
+ | InvalidRanges RangesError
+ | InvalidRangeFormat Text
+ | InvalidPosition Line
+ Column
+ | InvalidPositionFormat Text
+ | InvalidLineNumber Text
+ | InvalidColumnNumber Text
+ deriving (Show, Eq)
+
+parseMaybe :: Read a => Text -> (Text -> ParseError) -> Parser a
+parseMaybe t mkError =
+ case readMaybe (Text.unpack t) of
+ Just x -> pure x
+ Nothing -> throwError (mkError t)
+
+split2 :: MonadError e m => Text -> Text -> (Text -> e) -> m (Text, Text)
+split2 sep t err =
+ case Text.splitOn sep t of
+ [before, after] -> return (before, after)
+ _ -> throwError (err t)
+
+parsePosition :: Text -> Parser Position
+parsePosition t = do
+ (line, col) <- split2 ":" t InvalidPositionFormat
+ line' <- Line <$> parseMaybe line InvalidLineNumber
+ col' <- Column <$> parseMaybe col InvalidColumnNumber
+ case mkPosition line' col' of
+ Just position -> pure position
+ Nothing -> throwError (InvalidPosition line' col')
+
+parseRange :: Text -> Parser Range
+parseRange t = do
+ (startStr, endStr) <- split2 "-" t InvalidRangeFormat
+ start <- parsePosition startStr
+ end <- parsePosition endStr
+ case mkRange start end of
+ Just range -> pure range
+ Nothing -> throwError (InvalidRange start end)
+
+parseRanges :: Text -> Parser Ranges
+parseRanges t = do
+ let strs = filter (not . Text.null) (map Text.strip (Text.splitOn "," t))
+ rs <- mapM parseRange strs
+ case mkRanges rs of
+ Left err -> throwError (InvalidRanges err)
+ Right ranges -> pure ranges
+
+runParser :: Parser a -> Maybe (Either ParseError a)
+runParser = runExceptT
diff --git a/src/Text/Pandoc/Filter/EmphasizeCode/Position.hs b/src/Text/Pandoc/Filter/EmphasizeCode/Position.hs
new file mode 100644
--- /dev/null
+++ b/src/Text/Pandoc/Filter/EmphasizeCode/Position.hs
@@ -0,0 +1,42 @@
+{-# LANGUAGE GeneralizedNewtypeDeriving #-}
+
+-- | A position that cannot be constructed with incorrect bounds.
+module Text.Pandoc.Filter.EmphasizeCode.Position
+ ( Line(..)
+ , Column(..)
+ , Position
+ , line
+ , column
+ , mkPosition
+ , positionToTuple
+ ) where
+
+import Data.Hashable
+
+newtype Line =
+ Line Word
+ deriving (Show, Eq, Ord, Num, Enum, Real, Integral, Hashable)
+
+newtype Column =
+ Column Word
+ deriving (Show, Eq, Ord, Num, Enum, Real, Integral, Hashable)
+
+data Position = Position
+ { line :: Line
+ , column :: Column
+ } deriving (Eq, Show)
+
+instance Ord Position where
+ Position r1 c1 `compare` Position r2 c2
+ | r1 < r2 = LT
+ | r1 == r2 && c1 == c2 = EQ
+ | r1 == r2 && c1 < c2 = LT
+ | otherwise = GT
+
+mkPosition :: Line -> Column -> Maybe Position
+mkPosition r c
+ | r > 0 && c > 0 = Just (Position r c)
+ | otherwise = Nothing
+
+positionToTuple :: Position -> (Line, Column)
+positionToTuple (Position l c) = (l, c)
diff --git a/src/Text/Pandoc/Filter/EmphasizeCode/Pretty.hs b/src/Text/Pandoc/Filter/EmphasizeCode/Pretty.hs
new file mode 100644
--- /dev/null
+++ b/src/Text/Pandoc/Filter/EmphasizeCode/Pretty.hs
@@ -0,0 +1,47 @@
+{-# LANGUAGE CPP #-}
+{-# LANGUAGE OverloadedStrings #-}
+
+module Text.Pandoc.Filter.EmphasizeCode.Pretty where
+#if MIN_VERSION_base(4,8,0)
+import Data.Semigroup ((<>))
+#else
+import Control.Applicative
+import Data.Monoid
+#endif
+import Data.Text (Text)
+import qualified Data.Text as Text
+
+import Text.Pandoc.Filter.EmphasizeCode.Parser
+import Text.Pandoc.Filter.EmphasizeCode.Position
+import Text.Pandoc.Filter.EmphasizeCode.Range
+
+printLine :: Line -> Text
+printLine (Line n) = Text.pack (show n)
+
+printColumn :: Column -> Text
+printColumn (Column n) = Text.pack (show n)
+
+printPosition :: Position -> Text
+printPosition p = printLine (line p) <> ":" <> printColumn (column p)
+
+printRange :: Range -> Text
+printRange r = printPosition (rangeStart r) <> "-" <> printPosition (rangeEnd r)
+
+printRangesError :: RangesError -> Text
+printRangesError err =
+ case err of
+ EmptyRanges -> "At least one range is required"
+ Overlap r1 r2 -> printRange r1 <> " overlaps with " <> printRange r2
+
+printParseError :: ParseError -> Text
+printParseError err =
+ case err of
+ InvalidRange start end ->
+ "Invalid range: " <> printPosition start <> " to " <> printPosition end
+ InvalidRanges rangesErr -> printRangesError rangesErr
+ InvalidRangeFormat t -> "Invalid range: " <> t
+ InvalidPosition line' column' ->
+ "Invalid position: " <> printLine line' <> " to " <> printColumn column'
+ InvalidPositionFormat t -> "Invalid position: " <> t
+ InvalidLineNumber n -> "Invalid line number: " <> n
+ InvalidColumnNumber n -> "Invalid column number: " <> n
diff --git a/src/Text/Pandoc/Filter/EmphasizeCode/Range.hs b/src/Text/Pandoc/Filter/EmphasizeCode/Range.hs
new file mode 100644
--- /dev/null
+++ b/src/Text/Pandoc/Filter/EmphasizeCode/Range.hs
@@ -0,0 +1,119 @@
+{-# LANGUAGE CPP #-}
+
+-- | Ranges that cannot be constructed with incorrect bounds.
+module Text.Pandoc.Filter.EmphasizeCode.Range
+ ( Range
+ , rangeStart
+ , rangeEnd
+ , mkRange
+ , rangeToTuple
+ , rangeToTuples
+ , lineIntersectsWithRange
+ , Ranges
+ , rangesToList
+ , RangesError(..)
+ , mkRanges
+ , LineRange
+ , lineRangeLine
+ , lineRangeStart
+ , lineRangeEnd
+ , mkLineRange
+ , splitRanges
+ ) where
+#if MIN_VERSION_base(4,8,0)
+import Data.Semigroup ((<>))
+#else
+import Control.Applicative
+import Data.Monoid
+#endif
+import Control.Monad (foldM_, when)
+import Data.HashMap.Strict (HashMap)
+import qualified Data.HashMap.Strict as HashMap
+import Data.List (sortOn)
+
+import Text.Pandoc.Filter.EmphasizeCode.Position
+
+data Range = Range
+ { rangeStart :: Position
+ , rangeEnd :: Position
+ } deriving (Eq, Show)
+
+mkRange :: Position -> Position -> Maybe Range
+mkRange s e
+ | s < e = Just (Range s e)
+ | otherwise = Nothing
+
+rangeToTuple :: Range -> (Position, Position)
+rangeToTuple (Range p1 p2) = (p1, p2)
+
+rangeToTuples :: Range -> ((Line, Column), (Line, Column))
+rangeToTuples r =
+ let (p1, p2) = rangeToTuple r
+ in (positionToTuple p1, positionToTuple p2)
+
+rangesAreDisjoint :: Range -> Range -> Bool
+rangesAreDisjoint (Range s1 e1) (Range s2 e2) =
+ (s1 < s2 && e1 < e2) || (s2 < s1 && e2 < e1)
+
+rangeIntersects :: Range -> Range -> Bool
+rangeIntersects r1 r2 = not (rangesAreDisjoint r1 r2)
+
+lineIntersectsWithRange :: Line -> Range -> Bool
+lineIntersectsWithRange l (Range start end) = line start <= l && line end >= l
+
+newtype Ranges =
+ Ranges [Range]
+ deriving (Eq, Show)
+
+rangesToList :: Ranges -> [Range]
+rangesToList (Ranges rs) = rs
+
+data RangesError
+ = EmptyRanges
+ | Overlap Range
+ Range
+ deriving (Show, Eq)
+
+mkRanges :: [Range] -> Either RangesError Ranges
+mkRanges [] = Left EmptyRanges
+mkRanges ranges = do
+ let sorted = sortOn rangeStart ranges
+ foldM_ checkOverlap Nothing sorted
+ pure (Ranges sorted)
+ where
+ checkOverlap (Just last') this = do
+ when (last' `rangeIntersects` this) $ Left (Overlap last' this)
+ return (Just this)
+ checkOverlap Nothing this = return (Just this)
+
+data LineRange = LineRange
+ { lineRangeLine :: Line
+ , lineRangeStart :: Column
+ , lineRangeEnd :: Maybe Column
+ } deriving (Eq, Show)
+
+mkLineRange :: Line -> Column -> Maybe Column -> Maybe LineRange
+mkLineRange line' start (Just end)
+ | line' > 0 && start < end = Just (LineRange line' start (Just end))
+mkLineRange line' start Nothing
+ | line' > 0 = Just (LineRange line' start Nothing)
+mkLineRange _ _ _ = Nothing
+
+rangeToLineRanges :: Range -> [LineRange]
+rangeToLineRanges r@Range {rangeStart = p1, rangeEnd = p2}
+ | line p1 == line p2 = [LineRange (line p1) (column p1) (Just (column p2))]
+ | line p2 > line p1 =
+ let startLine = LineRange (line p1) (column p1) Nothing
+ endLine = LineRange (line p2) 1 (Just (column p2))
+ middleLines =
+ [LineRange n 1 Nothing | n <- [succ (line p1) .. pred (line p2)]]
+ in startLine : middleLines ++ [endLine]
+ | otherwise = error ("'Range' has invalid positions: " ++ show r)
+
+splitRanges :: Ranges -> HashMap Line [LineRange]
+splitRanges ranges =
+ HashMap.fromListWith
+ (flip (<>))
+ [ (lineRangeLine lr, [lr])
+ | lr <- concatMap rangeToLineRanges (rangesToList ranges)
+ ]
diff --git a/test/Main.hs b/test/Main.hs
new file mode 100644
--- /dev/null
+++ b/test/Main.hs
@@ -0,0 +1,1 @@
+{-# OPTIONS_GHC -F -pgmF tasty-discover #-}
diff --git a/test/Text/Pandoc/Filter/EmphasizeCode/ChunkingTest.hs b/test/Text/Pandoc/Filter/EmphasizeCode/ChunkingTest.hs
new file mode 100644
--- /dev/null
+++ b/test/Text/Pandoc/Filter/EmphasizeCode/ChunkingTest.hs
@@ -0,0 +1,32 @@
+{-# LANGUAGE OverloadedStrings #-}
+{-# OPTIONS_GHC -fno-warn-missing-signatures #-}
+
+module Text.Pandoc.Filter.EmphasizeCode.ChunkingTest where
+
+import Test.Tasty.Hspec
+
+import Text.Pandoc.Filter.EmphasizeCode.Chunking
+import Text.Pandoc.Filter.EmphasizeCode.Range
+import Text.Pandoc.Filter.EmphasizeCode.Testing.Ranges
+
+spec_emphasizeRanges = do
+ it "emphasizes a single line range" $ do
+ rs <- splitRanges <$> mkRanges' [((1, 1), (1, 7))]
+ emphasizeRanges rs "hello world" `shouldBe`
+ [[Emphasized "hello w", Literal "orld"]]
+ it "emphasizes multiple line ranges on a single line" $ do
+ rs <- splitRanges <$> mkRanges' [((1, 1), (1, 3)), ((1, 5), (1, 8))]
+ emphasizeRanges rs "hello world" `shouldBe`
+ [[Emphasized "hel", Literal "l", Emphasized "o wo", Literal "rld"]]
+ it "emphasizes multiple line ranges on multiple lines" $ do
+ rs <-
+ splitRanges <$>
+ mkRanges' [((1, 1), (1, 5)), ((1, 7), (2, 3)), ((4, 5), (4, 10))]
+ emphasizeRanges rs "hello world\nhej världen\nhallo welt\nhei verden" `shouldBe`
+ [ [Emphasized "hello", Literal " ", Emphasized "world"]
+ , [Emphasized "hej", Literal " världen"]
+ , [Literal "hallo welt"]
+ , [Literal "hei ", Emphasized "verden"]
+ ]
+
+{-# ANN module ("HLint: ignore Use camelCase" :: String) #-}
diff --git a/test/Text/Pandoc/Filter/EmphasizeCode/RangeTest.hs b/test/Text/Pandoc/Filter/EmphasizeCode/RangeTest.hs
new file mode 100644
--- /dev/null
+++ b/test/Text/Pandoc/Filter/EmphasizeCode/RangeTest.hs
@@ -0,0 +1,51 @@
+{-# OPTIONS_GHC -fno-warn-missing-signatures #-}
+
+module Text.Pandoc.Filter.EmphasizeCode.RangeTest where
+
+import qualified Data.HashMap.Strict as HashMap
+import Data.Maybe (mapMaybe)
+import Test.Tasty.Hspec
+
+import Text.Pandoc.Filter.EmphasizeCode.Position
+import Text.Pandoc.Filter.EmphasizeCode.Range
+import Text.Pandoc.Filter.EmphasizeCode.Testing.Ranges
+
+makeLineRanges :: [(Line, Column, Maybe Column)] -> [LineRange]
+makeLineRanges = mapMaybe mkLineRange'
+ where
+ mkLineRange' (line', start, end) = mkLineRange line' start end
+
+spec_mkRanges = do
+ it "sorts ranges" $ do
+ rs <- mkRanges' [((1, 1), (1, 7)), ((4, 1), (7, 2)), ((1, 8), (3, 4))]
+ map rangeToTuples (rangesToList rs) `shouldBe`
+ [((1, 1), (1, 7)), ((1, 8), (3, 4)), ((4, 1), (7, 2))]
+ it "does not accept empty ranges" $
+ mkRanges' [] `shouldThrow` anyException
+
+spec_splitRanges = do
+ it "splits one range into line ranges" $ do
+ rs <- mkRanges' [((1, 1), (1, 7))]
+ let lrs = HashMap.fromList [(1, makeLineRanges [(1, 1, Just 7)])]
+ splitRanges rs `shouldBe` lrs
+ it "splits two ranges into line ranges" $ do
+ rs <- mkRanges' [((1, 1), (1, 7)), ((1, 8), (2, 2))]
+ let lrs =
+ HashMap.fromList
+ [ (1, makeLineRanges [(1, 1, Just 7), (1, 8, Nothing)])
+ , (2, makeLineRanges [(2, 1, Just 2)])
+ ]
+ splitRanges rs `shouldBe` lrs
+ it "splits multiple ranges into line ranges" $ do
+ rs <- mkRanges' [((1, 1), (1, 7)), ((1, 8), (3, 4)), ((8, 2), (10, 2))]
+ let lrs =
+ HashMap.fromList
+ [ (1, makeLineRanges [(1, 1, Just 7), (1, 8, Nothing)])
+ , (2, makeLineRanges [(2, 1, Nothing)])
+ , (3, makeLineRanges [(3, 1, Just 4)])
+ , (8, makeLineRanges [(8, 2, Nothing)])
+ , (9, makeLineRanges [(9, 1, Nothing)])
+ , (10, makeLineRanges [(10, 1, Just 2)])
+ ]
+ splitRanges rs `shouldBe` lrs
+{-# ANN module ("HLint: ignore Use camelCase" :: String) #-}
diff --git a/test/Text/Pandoc/Filter/EmphasizeCode/Testing/Ranges.hs b/test/Text/Pandoc/Filter/EmphasizeCode/Testing/Ranges.hs
new file mode 100644
--- /dev/null
+++ b/test/Text/Pandoc/Filter/EmphasizeCode/Testing/Ranges.hs
@@ -0,0 +1,15 @@
+module Text.Pandoc.Filter.EmphasizeCode.Testing.Ranges where
+
+import Data.Maybe (mapMaybe)
+
+import Text.Pandoc.Filter.EmphasizeCode.Position
+import Text.Pandoc.Filter.EmphasizeCode.Range
+
+mkRanges' :: [((Line, Column), (Line, Column))] -> IO Ranges
+mkRanges' rs = either (fail . show) return (mkRanges (mapMaybe makeRange rs))
+ where
+ makeRange ((r1, c1), (r2, c2)) = do
+ p1 <- mkPosition r1 c1
+ p2 <- mkPosition r2 c2
+ mkRange p1 p2
+
diff --git a/test/Text/Pandoc/Filter/EmphasizeCodeTest.hs b/test/Text/Pandoc/Filter/EmphasizeCodeTest.hs
new file mode 100644
--- /dev/null
+++ b/test/Text/Pandoc/Filter/EmphasizeCodeTest.hs
@@ -0,0 +1,65 @@
+{-# LANGUAGE OverloadedStrings #-}
+{-# OPTIONS_GHC -fno-warn-missing-signatures #-}
+
+module Text.Pandoc.Filter.EmphasizeCodeTest where
+
+import Test.Tasty.Hspec
+
+import qualified Text.Pandoc.Filter.EmphasizeCode as Filter
+import Text.Pandoc.JSON
+
+(@@?=) :: (Eq a, Show a) => IO a -> a -> IO ()
+(@@?=) a b = a >>= (`shouldBe` b)
+
+emphasizeCode :: Format -> String -> IO Block
+emphasizeCode format ranges =
+ Filter.emphasizeCode
+ (Just format)
+ (CodeBlock
+ ("", ["my-lang"], [("emphasize", ranges)])
+ "hello world\nhej världen\nhallo welt\nhei verden")
+
+spec_emphasizeCode = do
+ it "emphasizes HTML and a single range" $
+ emphasizeCode "html5" "2:5-3:5" @@?=
+ RawBlock
+ "html"
+ (mconcat
+ [ "hello world\n"
+ , "hej världen\n"
+ , "hallo welt\n"
+ , "hei verden
"
+ ])
+ it "emphasizes HTML and a single range over multiple lines" $
+ emphasizeCode "html5" "2:5-4:3" @@?=
+ RawBlock
+ "html"
+ (mconcat
+ [ "hello world\n"
+ , "hej världen\n"
+ , "hallo welt\n"
+ , "hei verden
"
+ ])
+ it "emphasizes HTML and multiple ranges" $
+ emphasizeCode "html5" "1:1-1:5,2:5-3:5" @@?=
+ RawBlock
+ "html"
+ (mconcat
+ [ "hello world\n"
+ , "hej världen\n"
+ , "hallo welt\n"
+ , "hei verden
"
+ ])
+ it "emphasizes latex and multiple ranges" $
+ emphasizeCode "latex" "1:1-1:5,2:5-3:5" @@?=
+ RawBlock
+ "latex"
+ (mconcat
+ [ "\\begin{lstlisting}[escapechar=£,language=my-lang]\n"
+ , "£\\CodeEmphasis{hello}£ world\n"
+ , "hej £\\CodeEmphasis{världen}£\n"
+ , "£\\CodeEmphasis{hallo}£ welt\n"
+ , "hei verden\n"
+ , "\\end{lstlisting}\n"
+ ])
+{-# ANN module ("HLint: ignore Use camelCase" :: String) #-}