language-protobuf (empty) → 1.0
raw patch · 5 files changed
+583/−0 lines, 5 filesdep +basedep +megaparsecdep +textsetup-changed
Dependencies added: base, megaparsec, text
Files
- LICENSE +202/−0
- Setup.hs +2/−0
- language-protobuf.cabal +26/−0
- src/Language/ProtocolBuffers/Parser.hs +235/−0
- src/Language/ProtocolBuffers/Types.hs +118/−0
+ LICENSE view
@@ -0,0 +1,202 @@++ Apache License+ Version 2.0, January 2004+ http://www.apache.org/licenses/++ TERMS AND CONDITIONS FOR USE, REPRODUCTION, AND DISTRIBUTION++ 1. Definitions.++ "License" shall mean the terms and conditions for use, reproduction,+ and distribution as defined by Sections 1 through 9 of this document.++ "Licensor" shall mean the copyright owner or entity authorized by+ the copyright owner that is granting the License.++ "Legal Entity" shall mean the union of the acting entity and all+ other entities that control, are controlled by, or are under common+ control with that entity. For the purposes of this definition,+ "control" means (i) the power, direct or indirect, to cause the+ direction or management of such entity, whether by contract or+ otherwise, or (ii) ownership of fifty percent (50%) or more of the+ outstanding shares, or (iii) beneficial ownership of such entity.++ "You" (or "Your") shall mean an individual or Legal Entity+ exercising permissions granted by this License.++ "Source" form shall mean the preferred form for making modifications,+ including but not limited to software source code, documentation+ source, and configuration files.++ "Object" form shall mean any form resulting from mechanical+ transformation or translation of a Source form, including but+ not limited to compiled object code, generated documentation,+ and conversions to other media types.++ "Work" shall mean the work of authorship, whether in Source or+ Object form, made available under the License, as indicated by a+ copyright notice that is included in or attached to the work+ (an example is provided in the Appendix below).++ "Derivative Works" shall mean any work, whether in Source or Object+ form, that is based on (or derived from) the Work and for which the+ editorial revisions, annotations, elaborations, or other modifications+ represent, as a whole, an original work of authorship. For the purposes+ of this License, Derivative Works shall not include works that remain+ separable from, or merely link (or bind by name) to the interfaces of,+ the Work and Derivative Works thereof.++ "Contribution" shall mean any work of authorship, including+ the original version of the Work and any modifications or additions+ to that Work or Derivative Works thereof, that is intentionally+ submitted to Licensor for inclusion in the Work by the copyright owner+ or by an individual or Legal Entity authorized to submit on behalf of+ the copyright owner. For the purposes of this definition, "submitted"+ means any form of electronic, verbal, or written communication sent+ to the Licensor or its representatives, including but not limited to+ communication on electronic mailing lists, source code control systems,+ and issue tracking systems that are managed by, or on behalf of, the+ Licensor for the purpose of discussing and improving the Work, but+ excluding communication that is conspicuously marked or otherwise+ designated in writing by the copyright owner as "Not a Contribution."++ "Contributor" shall mean Licensor and any individual or Legal Entity+ on behalf of whom a Contribution has been received by Licensor and+ subsequently incorporated within the Work.++ 2. Grant of Copyright License. Subject to the terms and conditions of+ this License, each Contributor hereby grants to You a perpetual,+ worldwide, non-exclusive, no-charge, royalty-free, irrevocable+ copyright license to reproduce, prepare Derivative Works of,+ publicly display, publicly perform, sublicense, and distribute the+ Work and such Derivative Works in Source or Object form.++ 3. Grant of Patent License. Subject to the terms and conditions of+ this License, each Contributor hereby grants to You a perpetual,+ worldwide, non-exclusive, no-charge, royalty-free, irrevocable+ (except as stated in this section) patent license to make, have made,+ use, offer to sell, sell, import, and otherwise transfer the Work,+ where such license applies only to those patent claims licensable+ by such Contributor that are necessarily infringed by their+ Contribution(s) alone or by combination of their Contribution(s)+ with the Work to which such Contribution(s) was submitted. If You+ institute patent litigation against any entity (including a+ cross-claim or counterclaim in a lawsuit) alleging that the Work+ or a Contribution incorporated within the Work constitutes direct+ or contributory patent infringement, then any patent licenses+ granted to You under this License for that Work shall terminate+ as of the date such litigation is filed.++ 4. Redistribution. You may reproduce and distribute copies of the+ Work or Derivative Works thereof in any medium, with or without+ modifications, and in Source or Object form, provided that You+ meet the following conditions:++ (a) You must give any other recipients of the Work or+ Derivative Works a copy of this License; and++ (b) You must cause any modified files to carry prominent notices+ stating that You changed the files; and++ (c) You must retain, in the Source form of any Derivative Works+ that You distribute, all copyright, patent, trademark, and+ attribution notices from the Source form of the Work,+ excluding those notices that do not pertain to any part of+ the Derivative Works; and++ (d) If the Work includes a "NOTICE" text file as part of its+ distribution, then any Derivative Works that You distribute must+ include a readable copy of the attribution notices contained+ within such NOTICE file, excluding those notices that do not+ pertain to any part of the Derivative Works, in at least one+ of the following places: within a NOTICE text file distributed+ as part of the Derivative Works; within the Source form or+ documentation, if provided along with the Derivative Works; or,+ within a display generated by the Derivative Works, if and+ wherever such third-party notices normally appear. The contents+ of the NOTICE file are for informational purposes only and+ do not modify the License. You may add Your own attribution+ notices within Derivative Works that You distribute, alongside+ or as an addendum to the NOTICE text from the Work, provided+ that such additional attribution notices cannot be construed+ as modifying the License.++ You may add Your own copyright statement to Your modifications and+ may provide additional or different license terms and conditions+ for use, reproduction, or distribution of Your modifications, or+ for any such Derivative Works as a whole, provided Your use,+ reproduction, and distribution of the Work otherwise complies with+ the conditions stated in this License.++ 5. Submission of Contributions. Unless You explicitly state otherwise,+ any Contribution intentionally submitted for inclusion in the Work+ by You to the Licensor shall be under the terms and conditions of+ this License, without any additional terms or conditions.+ Notwithstanding the above, nothing herein shall supersede or modify+ the terms of any separate license agreement you may have executed+ with Licensor regarding such Contributions.++ 6. Trademarks. This License does not grant permission to use the trade+ names, trademarks, service marks, or product names of the Licensor,+ except as required for reasonable and customary use in describing the+ origin of the Work and reproducing the content of the NOTICE file.++ 7. Disclaimer of Warranty. Unless required by applicable law or+ agreed to in writing, Licensor provides the Work (and each+ Contributor provides its Contributions) on an "AS IS" BASIS,+ WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or+ implied, including, without limitation, any warranties or conditions+ of TITLE, NON-INFRINGEMENT, MERCHANTABILITY, or FITNESS FOR A+ PARTICULAR PURPOSE. You are solely responsible for determining the+ appropriateness of using or redistributing the Work and assume any+ risks associated with Your exercise of permissions under this License.++ 8. Limitation of Liability. In no event and under no legal theory,+ whether in tort (including negligence), contract, or otherwise,+ unless required by applicable law (such as deliberate and grossly+ negligent acts) or agreed to in writing, shall any Contributor be+ liable to You for damages, including any direct, indirect, special,+ incidental, or consequential damages of any character arising as a+ result of this License or out of the use or inability to use the+ Work (including but not limited to damages for loss of goodwill,+ work stoppage, computer failure or malfunction, or any and all+ other commercial damages or losses), even if such Contributor+ has been advised of the possibility of such damages.++ 9. Accepting Warranty or Additional Liability. While redistributing+ the Work or Derivative Works thereof, You may choose to offer,+ and charge a fee for, acceptance of support, warranty, indemnity,+ or other liability obligations and/or rights consistent with this+ License. However, in accepting such obligations, You may act only+ on Your own behalf and on Your sole responsibility, not on behalf+ of any other Contributor, and only if You agree to indemnify,+ defend, and hold each Contributor harmless for any liability+ incurred by, or claims asserted against, such Contributor by reason+ of your accepting any such warranty or additional liability.++ END OF TERMS AND CONDITIONS++ APPENDIX: How to apply the Apache License to your work.++ To apply the Apache License to your work, attach the following+ boilerplate notice, with the fields enclosed by brackets "[]"+ replaced with your own identifying information. (Don't include+ the brackets!) The text should be enclosed in the appropriate+ comment syntax for the file format. We also recommend that a+ file or class name and description of purpose be included on the+ same "printed page" as the copyright notice for easier+ identification within third-party archives.++ Copyright [yyyy] [name of copyright owner]++ Licensed under the Apache License, Version 2.0 (the "License");+ you may not use this file except in compliance with the License.+ You may obtain a copy of the License at++ http://www.apache.org/licenses/LICENSE-2.0++ Unless required by applicable law or agreed to in writing, software+ distributed under the License is distributed on an "AS IS" BASIS,+ WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.+ See the License for the specific language governing permissions and+ limitations under the License.
+ Setup.hs view
@@ -0,0 +1,2 @@+import Distribution.Simple+main = defaultMain
+ language-protobuf.cabal view
@@ -0,0 +1,26 @@+cabal-version: >=1.10+-- Initial package description 'protobuf-parser.cabal' generated by 'cabal+-- init'. For further documentation, see+-- http://haskell.org/cabal/users-guide/++name: language-protobuf+version: 1.0+synopsis: Language definition and parser for Protocol Buffers.+description: Language definition and parser for Protocol Buffers files, according to <https://developers.google.com/protocol-buffers/docs/reference/proto3-spec>.+-- bug-reports:+license: Apache-2.0+license-file: LICENSE+author: Alejandro Serrano+maintainer: alejandro.serrano@47deg.com+-- copyright:+category: Network+build-type: Simple++library+ exposed-modules: Language.ProtocolBuffers.Types,+ Language.ProtocolBuffers.Parser+ -- other-modules:+ -- other-extensions:+ build-depends: base >=4.12 && <5, megaparsec, text+ hs-source-dirs: src+ default-language: Haskell2010
+ src/Language/ProtocolBuffers/Parser.hs view
@@ -0,0 +1,235 @@+{-# language FlexibleContexts, OverloadedStrings #-}+-- | Parser for the proto3 spec,+-- as defined in <https://developers.google.com/protocol-buffers/docs/reference/proto3-spec>.+module Language.ProtocolBuffers.Parser (+ -- * Parse and sort out a whole file+ parseProtoBufFile+, parseProtoBuf+ -- * Parse declarations+, parseProtoBufDeclarations+) where++import qualified Data.Text as T+import qualified Data.Text.IO as T+import Text.Megaparsec+import Text.Megaparsec.Char+import qualified Text.Megaparsec.Char.Lexer as L++import Language.ProtocolBuffers.Types++-- | Parse a whole file into a 'ProtoBuf' structure.+-- This function sorts together the different declarations.+parseProtoBufFile :: FilePath -> IO (Either (ParseErrorBundle T.Text Char) ProtoBuf)+parseProtoBufFile p = parseProtoBuf <$> T.readFile p+-- | Parse 'T.Text' into a 'ProtoBuf' structure.+-- This function sorts together the different declarations.+parseProtoBuf :: T.Text -> Either (ParseErrorBundle T.Text Char) ProtoBuf+parseProtoBuf = parse wholeProtoBuf ""+-- | Parse all the declarations in a 'T.Text'.+parseProtoBufDeclarations :: T.Text -> Either (ParseErrorBundle T.Text Char) [Declaration]+parseProtoBufDeclarations = parse (many declaration) ""++spaceConsumer :: MonadParsec Char T.Text m => m ()+spaceConsumer = L.space space1 (L.skipLineComment "//") (L.skipBlockComment "/*" "*/")++lexeme :: MonadParsec Char T.Text m => m a -> m a+lexeme = L.lexeme spaceConsumer+symbol :: MonadParsec Char T.Text m => T.Text -> m T.Text+symbol = L.symbol spaceConsumer+reserved :: MonadParsec Char T.Text m => T.Text -> m T.Text+reserved = lexeme . chunk++number :: (MonadParsec Char T.Text m, Integral a) => m a +number = L.signed spaceConsumer (lexeme L.decimal)+ <|> lexeme L.octal+ <|> lexeme L.hexadecimal+floating :: (MonadParsec Char T.Text m, RealFloat a) => m a+floating = L.signed spaceConsumer (lexeme L.float)+stringLiteral :: MonadParsec Char T.Text m => m T.Text+stringLiteral = T.pack <$> (char '"' >> manyTill L.charLiteral (char '"'))++betweenBraces :: MonadParsec Char T.Text m => m a -> m a+betweenBraces = between (symbol "{") (symbol "}")+betweenSquares :: MonadParsec Char T.Text m => m a -> m a+betweenSquares = between (symbol "[") (symbol "]")+betweenParens :: MonadParsec Char T.Text m => m a -> m a+betweenParens = between (symbol "(") (symbol ")")++ident :: MonadParsec Char T.Text m => m T.Text+ident = (\h t -> T.pack (h:t))+ <$> letterChar+ <*> many (alphaNumChar <|> char '_')+identifier :: MonadParsec Char T.Text m => m T.Text+identifier = lexeme ident+fullIdentifier :: MonadParsec Char T.Text m => m FullIdentifier+fullIdentifier = lexeme $ sepBy1 identifier (char '.')++constant :: MonadParsec Char T.Text m => m Constant+constant + = KFloat <$> floating+ <|> KInt <$> number+ <|> KString <$> stringLiteral+ <|> KBool True <$ reserved "true"+ <|> KBool False <$ reserved "false"+ <|> KIdentifier <$> fullIdentifier++optionName :: MonadParsec Char T.Text m => m FullIdentifier+optionName = (++) <$> ((: []) <$> identifier <|> betweenParens fullIdentifier)+ <*> many (char '.' >> identifier)++topOption :: MonadParsec Char T.Text m => m Option+topOption+ = Option <$ reserved "option"+ <*> optionName+ <* symbol "="+ <*> constant+ <* symbol ";"+innerOption :: MonadParsec Char T.Text m => m Option+innerOption+ = Option <$> optionName+ <* symbol "="+ <*> constant++wholeProtoBuf :: MonadParsec Char T.Text m => m ProtoBuf+wholeProtoBuf = declsToProtoBuf <$> many declaration++declaration :: MonadParsec Char T.Text m => m Declaration+declaration+ = DSyntax <$ reserved "syntax" <* symbol "=" <*> stringLiteral <* symbol ";"+ <|> DImport <$ reserved "import"+ <*> (Weak <$ reserved "weak" <|> Public <$ reserved "public" <|> pure Normal)+ <*> stringLiteral <* symbol ";"+ <|> DPackage <$ reserved "package" <*> fullIdentifier <* symbol ";"+ <|> DOption <$> topOption+ <|> DType <$> typeDeclaration+ <|> DService <$> serviceDeclaration++typeDeclaration :: MonadParsec Char T.Text m => m TypeDeclaration+typeDeclaration+ = buildEnum <$ reserved "enum"+ <*> identifier+ <*> betweenBraces (many enumThing)+ <|> buildMessage <$ reserved "message"+ <*> identifier+ <*> betweenBraces (many msgThing)+ where+ buildEnum :: T.Text -> [EnumThing] -> TypeDeclaration+ buildEnum name things+ = DEnum name [o | EnumThingOption o <- things]+ [f | EnumThingField f <- things]+ buildMessage :: T.Text -> [MsgThing] -> TypeDeclaration+ buildMessage name things+ = DMessage name [o | MsgThingOption o <- things]+ [r | MsgThingReserved r <- things]+ [f | MsgThingField f <- things]+ [i | MsgThingInner i <- things]++data EnumThing+ = EnumThingOption Option | EnumThingField EnumField+enumThing :: MonadParsec Char T.Text m => m EnumThing+enumThing+ = EnumThingOption <$> topOption+ <|> EnumThingField <$> enumField+ where+ enumField :: MonadParsec Char T.Text m => m EnumField+ enumField = EnumField <$> identifier+ <* symbol "="+ <*> number+ <*> (betweenSquares (sepBy innerOption (symbol ",")) <|> pure [])+ <* symbol ";"++data MsgThing+ = MsgThingOption Option+ | MsgThingReserved Reserved+ | MsgThingField MessageField+ | MsgThingInner TypeDeclaration+msgThing :: MonadParsec Char T.Text m => m MsgThing+msgThing+ = MsgThingOption <$> topOption+ <|> MsgThingReserved <$> reservedOption+ <|> MsgThingInner <$> typeDeclaration+ <|> MsgThingField <$> msgField++reservedOption :: MonadParsec Char T.Text m => m Reserved+reservedOption+ = id <$ reserved "reserved"+ <*> sepBy1 reservedValue (symbol ",")+ <* symbol ";"+ where+ reservedValue :: MonadParsec Char T.Text m => m ReservedValue+ reservedValue = RRange <$> number <* reserved "to" <*> number+ <|> RInt <$> number+ <|> RName <$> stringLiteral++msgField :: MonadParsec Char T.Text m => m MessageField+msgField+ = OneOfField <$ reserved "oneof"+ <*> identifier+ <*> betweenBraces (some msgField)+ <|> MapField <$ reserved "map"+ <* symbol "<"+ <*> fieldType+ <* symbol ","+ <*> fieldType+ <* symbol ">"+ <*> identifier+ <* symbol "="+ <*> number+ <*> (betweenSquares (sepBy innerOption (symbol ",")) <|> pure [])+ <* symbol ";"+ <|> NormalField <$> (Repeated <$ reserved "repeated" <|> pure Single)+ <*> fieldType+ <*> identifier+ <* symbol "="+ <*> number+ <*> (betweenSquares (sepBy innerOption (symbol ",")) <|> pure [])+ <* symbol ";"++serviceDeclaration :: MonadParsec Char T.Text m => m ServiceDeclaration+serviceDeclaration+ = buildService <$ reserved "service"+ <*> identifier+ <*> betweenBraces (many serviceThing)+ where+ buildService :: T.Text -> [ServiceThing] -> ServiceDeclaration+ buildService name things+ = Service name [o | ServiceThingOption o <- things]+ [m | ServiceThingMethod m <- things]++data ServiceThing+ = ServiceThingOption Option | ServiceThingMethod Method+serviceThing :: MonadParsec Char T.Text m => m ServiceThing+serviceThing+ = ServiceThingOption <$> topOption+ <|> ServiceThingMethod <$> method+ where+ method = Method <$ reserved "rpc"+ <*> identifier+ <* symbol "("+ <*> (Stream <$ reserved "stream" <|> pure Single)+ <*> fieldType+ <* symbol ")"+ <* reserved "returns"+ <* symbol "("+ <*> (Stream <$ reserved "stream" <|> pure Single)+ <*> fieldType+ <* symbol ")"+ <*> (betweenBraces (many topOption) <|> [] <$ symbol ";")++fieldType :: MonadParsec Char T.Text m => m FieldType+fieldType+ = TInt32 <$ reserved "int32"+ <|> TInt64 <$ reserved "int64"+ <|> TUInt32 <$ reserved "uint32"+ <|> TUInt64 <$ reserved "uint64"+ <|> TSInt32 <$ reserved "sint32"+ <|> TSInt64 <$ reserved "sint64"+ <|> TFixed32 <$ reserved "fixed32"+ <|> TFixed64 <$ reserved "fixed64"+ <|> TSFixed32 <$ reserved "sfixed32"+ <|> TSFixed64 <$ reserved "sfixed64"+ <|> TDouble <$ reserved "double"+ <|> TBool <$ reserved "bool"+ <|> TString <$ reserved "string"+ <|> TBytes <$ reserved "bytes"+ <|> TOther <$> fullIdentifier
+ src/Language/ProtocolBuffers/Types.hs view
@@ -0,0 +1,118 @@+{-# language GADTSyntax, PatternSynonyms #-}+-- | Elements in the Protocol Buffers syntax,+-- as defined in <https://developers.google.com/protocol-buffers/docs/reference/proto3-spec>+module Language.ProtocolBuffers.Types where++import qualified Data.Text as T++type Identifier = T.Text+type FullIdentifier = [Identifier]++-- | Whole definition, in which declarations are+-- sorted out by their form.+data ProtoBuf+ = ProtoBuf { syntax :: Maybe T.Text+ , package :: Maybe FullIdentifier+ , imports :: [(ImportType, T.Text)]+ , options :: [Option]+ , types :: [TypeDeclaration]+ , services :: [ServiceDeclaration]+ }+ deriving (Eq, Show)++declsToProtoBuf :: [Declaration] -> ProtoBuf+declsToProtoBuf things+ = ProtoBuf (safeHead [s | DSyntax s <- things])+ (safeHead [s | DPackage s <- things])+ [(i,t) | DImport i t <- things]+ [o | DOption o <- things]+ [t | DType t <- things]+ [s | DService s <- things]++safeHead :: [a] -> Maybe a+safeHead [] = Nothing+safeHead (x:_) = Just x++-- | Declarations, that is, anything which may+-- appear in the top-level.+data Declaration where+ DSyntax :: T.Text -> Declaration+ DImport :: ImportType -> T.Text -> Declaration+ DPackage :: FullIdentifier -> Declaration+ DOption :: Option -> Declaration+ DType :: TypeDeclaration -> Declaration+ DService :: ServiceDeclaration -> Declaration+ deriving (Eq, Show)++data Option where+ Option :: FullIdentifier -> Constant -> Option+ deriving (Eq, Show)++data TypeDeclaration where+ DEnum :: Identifier -> [Option] -> [EnumField]+ -> TypeDeclaration+ DMessage :: Identifier -> [Option] -> [Reserved]+ -> [MessageField] -> [TypeDeclaration]+ -> TypeDeclaration+ deriving (Eq, Show)++data ServiceDeclaration where+ Service :: Identifier -> [Option] -> [Method] -> ServiceDeclaration+ deriving (Eq, Show)++data Method where+ Method :: Identifier+ -> Repetition -> FieldType+ -> Repetition -> FieldType+ -> [Option] -> Method+ deriving (Eq, Show)++data ImportType+ = Normal | Weak | Public+ deriving (Eq, Show)++data Constant where+ KIdentifier :: FullIdentifier -> Constant+ KInt :: Integer -> Constant+ KFloat :: Float -> Constant+ KString :: T.Text -> Constant+ KBool :: Bool -> Constant+ deriving (Eq, Show)++data EnumField where+ EnumField :: FieldName -> FieldNumber -> [Option] -> EnumField+ deriving (Eq, Show)++type TypeName = FullIdentifier+data FieldType+ = TInt32 | TInt64 | TUInt32 | TUInt64 | TSInt32 | TSInt64+ | TFixed32 | TFixed64 | TSFixed32 | TSFixed64+ | TDouble | TBool | TString | TBytes | TOther TypeName+ deriving (Eq, Show)++type FieldName = Identifier+type FieldNumber = Int++data MessageField where+ NormalField :: Repetition -> FieldType+ -> FieldName -> FieldNumber+ -> [Option] -> MessageField+ OneOfField :: FieldName -> [MessageField]+ -> MessageField+ MapField :: FieldType -> FieldType+ -> FieldName -> FieldNumber+ -> [Option] -> MessageField+ deriving (Eq, Show)++data Repetition+ = Single | Repeated+ deriving (Eq, Show)++pattern Stream = Repeated++type Reserved = [ReservedValue]+data ReservedValue where+ RInt :: Int -> ReservedValue+ RRange :: Int -> Int -> ReservedValue+ RName :: Identifier -> ReservedValue+ deriving (Eq, Show)