hschema (empty) → 0.0.1.0

raw patch · 8 files changed

+477/−0 lines, 8 filesdep +basedep +comonaddep +contravariantsetup-changed

Dependencies added: base, comonad, contravariant, free, hashable, invariant, lens, mtl, natural-transformation, profunctors, text, unordered-containers, vector

Files

ChangeLog.md +3/−0
LICENSE +165/−0
README.md +4/−0
Setup.hs +2/−0
hschema.cabal +53/−0
src/Control/Functor/HigherOrder.hs +69/−0
src/Data/Schema.hs +61/−0
src/Data/Schema/Internal/Types.hs +120/−0

+ ChangeLog.md view

@@ -0,0 +1,3 @@+# Changelog for hexomorph++## Unreleased changes

+ LICENSE view

@@ -0,0 +1,165 @@+                   GNU LESSER GENERAL PUBLIC LICENSE+                       Version 3, 29 June 2007++ Copyright (C) 2007 Free Software Foundation, Inc. <http://fsf.org/>+ Everyone is permitted to copy and distribute verbatim copies+ of this license document, but changing it is not allowed.+++  This version of the GNU Lesser General Public License incorporates+the terms and conditions of version 3 of the GNU General Public+License, supplemented by the additional permissions listed below.++  0. Additional Definitions.++  As used herein, "this License" refers to version 3 of the GNU Lesser+General Public License, and the "GNU GPL" refers to version 3 of the GNU+General Public License.++  "The Library" refers to a covered work governed by this License,+other than an Application or a Combined Work as defined below.++  An "Application" is any work that makes use of an interface provided+by the Library, but which is not otherwise based on the Library.+Defining a subclass of a class defined by the Library is deemed a mode+of using an interface provided by the Library.++  A "Combined Work" is a work produced by combining or linking an+Application with the Library.  The particular version of the Library+with which the Combined Work was made is also called the "Linked+Version".++  The "Minimal Corresponding Source" for a Combined Work means the+Corresponding Source for the Combined Work, excluding any source code+for portions of the Combined Work that, considered in isolation, are+based on the Application, and not on the Linked Version.++  The "Corresponding Application Code" for a Combined Work means the+object code and/or source code for the Application, including any data+and utility programs needed for reproducing the Combined Work from the+Application, but excluding the System Libraries of the Combined Work.++  1. Exception to Section 3 of the GNU GPL.++  You may convey a covered work under sections 3 and 4 of this License+without being bound by section 3 of the GNU GPL.++  2. Conveying Modified Versions.++  If you modify a copy of the Library, and, in your modifications, a+facility refers to a function or data to be supplied by an Application+that uses the facility (other than as an argument passed when the+facility is invoked), then you may convey a copy of the modified+version:++   a) under this License, provided that you make a good faith effort to+   ensure that, in the event an Application does not supply the+   function or data, the facility still operates, and performs+   whatever part of its purpose remains meaningful, or++   b) under the GNU GPL, with none of the additional permissions of+   this License applicable to that copy.++  3. Object Code Incorporating Material from Library Header Files.++  The object code form of an Application may incorporate material from+a header file that is part of the Library.  You may convey such object+code under terms of your choice, provided that, if the incorporated+material is not limited to numerical parameters, data structure+layouts and accessors, or small macros, inline functions and templates+(ten or fewer lines in length), you do both of the following:++   a) Give prominent notice with each copy of the object code that the+   Library is used in it and that the Library and its use are+   covered by this License.++   b) Accompany the object code with a copy of the GNU GPL and this license+   document.++  4. Combined Works.++  You may convey a Combined Work under terms of your choice that,+taken together, effectively do not restrict modification of the+portions of the Library contained in the Combined Work and reverse+engineering for debugging such modifications, if you also do each of+the following:++   a) Give prominent notice with each copy of the Combined Work that+   the Library is used in it and that the Library and its use are+   covered by this License.++   b) Accompany the Combined Work with a copy of the GNU GPL and this license+   document.++   c) For a Combined Work that displays copyright notices during+   execution, include the copyright notice for the Library among+   these notices, as well as a reference directing the user to the+   copies of the GNU GPL and this license document.++   d) Do one of the following:++       0) Convey the Minimal Corresponding Source under the terms of this+       License, and the Corresponding Application Code in a form+       suitable for, and under terms that permit, the user to+       recombine or relink the Application with a modified version of+       the Linked Version to produce a modified Combined Work, in the+       manner specified by section 6 of the GNU GPL for conveying+       Corresponding Source.++       1) Use a suitable shared library mechanism for linking with the+       Library.  A suitable mechanism is one that (a) uses at run time+       a copy of the Library already present on the user's computer+       system, and (b) will operate properly with a modified version+       of the Library that is interface-compatible with the Linked+       Version.++   e) Provide Installation Information, but only if you would otherwise+   be required to provide such information under section 6 of the+   GNU GPL, and only to the extent that such information is+   necessary to install and execute a modified version of the+   Combined Work produced by recombining or relinking the+   Application with a modified version of the Linked Version. (If+   you use option 4d0, the Installation Information must accompany+   the Minimal Corresponding Source and Corresponding Application+   Code. If you use option 4d1, you must provide the Installation+   Information in the manner specified by section 6 of the GNU GPL+   for conveying Corresponding Source.)++  5. Combined Libraries.++  You may place library facilities that are a work based on the+Library side by side in a single library together with other library+facilities that are not Applications and are not covered by this+License, and convey such a combined library under terms of your+choice, if you do both of the following:++   a) Accompany the combined library with a copy of the same work based+   on the Library, uncombined with any other library facilities,+   conveyed under the terms of this License.++   b) Give prominent notice with the combined library that part of it+   is a work based on the Library, and explaining where to find the+   accompanying uncombined form of the same work.++  6. Revised Versions of the GNU Lesser General Public License.++  The Free Software Foundation may publish revised and/or new versions+of the GNU Lesser General Public License from time to time. Such new+versions will be similar in spirit to the present version, but may+differ in detail to address new problems or concerns.++  Each version is given a distinguishing version number. If the+Library as you received it specifies that a certain numbered version+of the GNU Lesser General Public License "or any later version"+applies to it, you have the option of following the terms and+conditions either of that published version or of any later version+published by the Free Software Foundation. If the Library as you+received it does not specify a version number of the GNU Lesser+General Public License, you may choose any version of the GNU Lesser+General Public License ever published by the Free Software Foundation.++  If the Library as you received it specifies that a proxy can decide+whether future versions of the GNU Lesser General Public License shall+apply, that proxy's public statement of acceptance of any version is+permanent authorization for you to choose that version for the+Library.

+ README.md view

@@ -0,0 +1,4 @@+# Haskell Schema Core++This is the core module of the the Haskell Schema set of libraries and provides with the basic elements needed to define your own schemas.+To be able to use this library you will need to combine it with one or more of the additional companion packages.

+ Setup.hs view

@@ -0,0 +1,2 @@+import Distribution.Simple+main = defaultMain

+ hschema.cabal view

@@ -0,0 +1,53 @@+cabal-version: 1.12++-- This file has been generated from package.yaml by hpack version 0.31.0.+--+-- see: https://github.com/sol/hpack+--+-- hash: 61456a052d486027e62bffc9af3700c01118a4cf0b5aa48e39ff96e59fb889d5++name:           hschema+version:        0.0.1.0+synopsis:       Describe schemas for your Haskell data types.+description:    Please see the README on GitHub at <https://github.com/alonsodomin/haskell-schema#readme>+category:       Data,Schema+homepage:       https://github.com/alonsodomin/haskell-schema#readme+bug-reports:    https://github.com/alonsodomin/haskell-schema/issues+author:         Antonio Alonso Dominguez+maintainer:     alonso.domin@gmail.com+copyright:      2018 Antonio Alonso Dominguez+license:        LGPL-3+license-file:   LICENSE+build-type:     Simple+extra-source-files:+    README.md+    ChangeLog.md++source-repository head+  type: git+  location: https://github.com/alonsodomin/haskell-schema++library+  exposed-modules:+      Control.Functor.HigherOrder+      Data.Schema+      Data.Schema.Internal.Types+  other-modules:+      Paths_hschema+  hs-source-dirs:+      src+  build-depends:+      base >=4.7 && <5+    , comonad >=5.0 && <5.1+    , contravariant+    , free+    , hashable+    , invariant+    , lens+    , mtl+    , natural-transformation+    , profunctors+    , text+    , unordered-containers+    , vector+  default-language: Haskell2010

+ src/Control/Functor/HigherOrder.hs view

@@ -0,0 +1,69 @@+{-# LANGUAGE FlexibleContexts     #-}+{-# LANGUAGE FlexibleInstances    #-}+{-# LANGUAGE KindSignatures       #-}+{-# LANGUAGE Rank2Types           #-}+{-# LANGUAGE TypeOperators        #-}+{-# LANGUAGE TypeSynonymInstances #-}++module Control.Functor.HigherOrder where++import           Control.Natural++type HAlgebra   f g = f g :~> g+type HCoalgebra f g = g :~> f g++class HFunctor (f :: ((* -> *) -> * -> *)) where+  hfmap :: (m ~> n) -> f m ~> f n++class HFunctor f => HPointed f where+  hreturn :: Functor g => g a -> f g a++class HFunctor f => HCopointed f where+  hextract :: Functor g => f g a -> g a++newtype HFix f a = HFix { unfix :: f (HFix f) a }++data HEnvT+  (f :: ((* -> *) -> * -> *))+  (e :: *)+  (g :: (* -> *))+  (i :: *) = HEnvT { hask :: !e, hlocal :: f g i }++newtype HMutu+  (f :: ((* -> *) -> * -> *))+  (g :: ((* -> *) -> * -> *))+  (a :: *) = HMutu { unmutu :: f (g (HMutu f g)) a }++instance HFunctor f => HFunctor (HEnvT f a) where+  hfmap nt = \fa -> HEnvT (hask fa) ((hfmap nt) (hlocal fa))++instance Functor (f g) => Functor (HEnvT f e g) where+  fmap f env = HEnvT (hask env) (fmap f (hlocal env))++type HCofree+  (f :: ((* -> *) -> * -> *))+  (a :: *) = HFix (HEnvT f a)++hcofree :: a -> f (HCofree f a) b -> HCofree f a b+hcofree a fhc = HFix (HEnvT a fhc)++cataNT :: HFunctor f => HAlgebra f g -> HFix f ~> g+cataNT alg = (unwrapNT alg) . nt+  where nt hf = (hfmap (cataNT alg)) (unfix hf)++anaNT :: HFunctor f => HCoalgebra f g -> g ~> HFix f+anaNT coalg g = HFix $ (hfmap (anaNT coalg)) $ (unwrapNT coalg) g++--hyloNT :: HFunctor f => HAlgebra f g -> HCoalgebra g f -> HFix f ~> HFix g++hforgetAlg :: HAlgebra (HEnvT f a) (HFix f)+hforgetAlg = wrapNT $ \env -> HFix $ hlocal env++hforget :: HFunctor f => HCofree f a ~> HFix f+hforget = cataNT hforgetAlg++htagCoalg :: HFunctor f => a -> HCoalgebra (HEnvT f a) (HFix f)+htagCoalg tag = wrapNT $ \hfix -> HEnvT tag (unfix hfix)++htag :: HFunctor f => a -> HFix f ~> HCofree f a+htag tag = anaNT (htagCoalg tag)

+ src/Data/Schema.hs view

@@ -0,0 +1,61 @@+{-# LANGUAGE RankNTypes #-}++module Data.Schema+     ( Field+     , Fields+     , field+     , optional+     , alt+     , Schema+     , HasSchema (..)+     , prim+     , const+     , record+     , asList+     , toList+     , oneOf+     , alias+     ) where++import           Control.Functor.HigherOrder+import           Control.Lens+import           Data.Functor.Invariant+import           Data.Hashable               (Hashable)+import           Data.HashMap.Strict         (HashMap)+import qualified Data.List.NonEmpty          as NEL+import           Data.Schema.Internal.Types+import           Data.Text                   (Text)+import           Data.Vector                 (Vector)+import qualified Data.Vector                 as Vector+import           Prelude                     hiding (const, seq)++-- | Define an alternative+alt :: Text -> s b -> Prism' a b -> AltDef s a+alt = AltDef++-- | Define an annotated schema for primitives of type `p`+prim :: p a -> Schema p a+prim primAlg = Schema (HFix $ PrimitiveSchema primAlg)++-- | Define a schema for a type that is always constant+const :: a -> Schema p a+const a = Schema (HFix (RecordSchema $ pure a))++-- | Define the schema of record using the given fields+record :: Fields (Schema p) a -> Schema p a+record ps = Schema (HFix (RecordSchema $ hoistField unwrapSchema ps))++-- | Define the schema of a list based on the element type+asList :: Iso' (Vector a) [a]+asList = iso Vector.toList Vector.fromList++toList :: Schema p (Vector a) -> Schema p [a]+toList = invmap Vector.toList Vector.fromList++-- | Define the schema of an union (coproduct) type based on the given alternatives+oneOf :: [AltDef (Schema p) a] -> Schema p a+oneOf alts = Schema (HFix (UnionSchema $ fmap (hfmap unwrapSchema) $ NEL.fromList alts))++-- | Define an schema alias that is isomorphic to another one using the given ISO transformation+alias :: Iso' a b -> Schema p a -> Schema p b+alias i base = invmap (view i) (view . from $ i) base

+ src/Data/Schema/Internal/Types.hs view

@@ -0,0 +1,120 @@+{-# LANGUAGE ExistentialQuantification #-}+{-# LANGUAGE FlexibleContexts          #-}+{-# LANGUAGE FlexibleInstances         #-}+{-# LANGUAGE GADTs                     #-}+{-# LANGUAGE LambdaCase                #-}+{-# LANGUAGE MultiParamTypeClasses     #-}+{-# LANGUAGE RankNTypes                #-}+{-# LANGUAGE ScopedTypeVariables       #-}+{-# LANGUAGE TypeFamilies              #-}+{-# LANGUAGE TypeOperators             #-}+{-# LANGUAGE TypeSynonymInstances      #-}++module Data.Schema.Internal.Types where++import           Control.Applicative.Free+import           Control.Functor.HigherOrder+import           Control.Lens                hiding (iso)+import qualified Control.Lens                as Lens+import           Control.Natural+import           Data.Functor.Invariant+import           Data.List.NonEmpty          (NonEmpty)+import           Data.Profunctor+import           Data.Text                   (Text)+import qualified Data.Text                   as T+import           Data.Vector                 (Vector)+import           Prelude                     hiding (const, seq)++-- | Metadata for a field of type `a`, belonging to the data type `o` and based on schema `s`+data FieldDef o s a where+  RequiredField :: Text -> s a -> Getter o a -> FieldDef o s a+  OptionalField :: Text -> s a -> Getter o (Maybe a) -> FieldDef o s (Maybe a)++fieldName :: FieldDef o s a -> Text+fieldName (RequiredField name _ _) = name+fieldName (OptionalField name _ _) = name++instance HFunctor (FieldDef o) where+  hfmap nt = \case+    RequiredField name s acc -> RequiredField name (nt s) acc+    OptionalField name s acc -> OptionalField name (nt s) acc++-- | The type of a field of type `a`, belonging to the data type `o` and based on schema `s`+newtype Field s o a = Field { unwrapField :: Ap (FieldDef o s) a }++hoistField :: (m ~> n) -> Field m o a -> Field n o a+hoistField nt (Field ap) = Field $ hoistAp (hfmap nt) ap++-- | The set of fields for the data type `o` based on schema `s`+type Fields s o = Field s o o++instance Functor (Field s o) where+  fmap f (Field x) = Field $ fmap f x++instance Applicative (Field s o) where+  pure x = Field $ Pure x+  (Field x) <*> (Field y) = Field (x <*> y)++instance Profunctor (Field s) where+  lmap f (Field ap) = Field $ hoistAp (contraNT f) ap+    where contraNT :: (n -> o) -> FieldDef o s ~> FieldDef n s+          contraNT f = \case+            RequiredField n s g -> RequiredField n s ((to f) . g)+            OptionalField n s g -> OptionalField n s ((to f) . g)+  rmap = fmap++-- | Define a field+field :: Text -> s a -> Getter o a -> Field s o a+field name schema getter = Field $ liftAp (RequiredField name schema getter)++optional :: Text -> s a -> Getter o (Maybe a) -> Field s o (Maybe a)+optional name schema getter = Field $ liftAp (OptionalField name schema getter)++-- | Metadata for an alternative of type `a` based on schema `s`+data AltDef s a = forall b. AltDef+  { altName   :: Text+  , altSchema :: s b+  , altPrism  :: Prism' a b+  }++instance HFunctor AltDef where+  hfmap nt = \(AltDef name schema pr) -> AltDef name (nt schema) pr++-- | Metadata for a schema `s` based on primitives `p` and representing type `a`+data SchemaF p s a where+  PrimitiveSchema :: p a -> SchemaF p s a+  RecordSchema    :: Fields s a -> SchemaF p s a+  UnionSchema     :: NonEmpty (AltDef s a) -> SchemaF p s a+  AliasSchema     :: s a -> Iso' a b -> SchemaF p s b++instance HFunctor (SchemaF p) where+  hfmap nt = \case+    PrimitiveSchema p         -> PrimitiveSchema p+    RecordSchema (Field flds) -> RecordSchema . Field $ hoistAp (hfmap nt) flds+    UnionSchema alts          -> UnionSchema $ fmap (hfmap nt) alts+    AliasSchema base iso      -> AliasSchema (nt base) iso++-- | The Schema type itself for a set of primitives `p`+newtype Schema p a = Schema { unwrapSchema :: HFix (SchemaF p) a }++instance Invariant (Schema p) where+  invmap f g sch = case (unfix . unwrapSchema $ sch) of+    AliasSchema base iso -> Schema . HFix $ AliasSchema base (iso . (Lens.iso f g))+    otherwise            -> Schema . HFix $ AliasSchema (unwrapSchema sch) (Lens.iso f g)++-- | An Schema has a HFunctor that performs a natural transformation of the primitive algebra of the Schema+instance HFunctor Schema where+  hfmap nt (Schema fsch) = Schema $ cataNT pfmapAlg fsch+    where pfmapAlg = wrapNT $ \sch -> HFix $ pfmap nt sch++          pfmap :: (p ~> q) -> SchemaF p s ~> SchemaF q s+          pfmap nt = \case+            PrimitiveSchema p    -> PrimitiveSchema (nt p)+            RecordSchema fields  -> RecordSchema fields+            UnionSchema alts     -> UnionSchema alts+            AliasSchema base iso -> AliasSchema base iso++class HasSchema a where+  type PrimitivesOf a :: * -> *++  getSchema :: Schema (PrimitivesOf a) a