diff --git a/CHANGELOG.md b/CHANGELOG.md
new file mode 100644
--- /dev/null
+++ b/CHANGELOG.md
@@ -0,0 +1,5 @@
+# Revision history for e11y-otel
+
+## 0.1.0.0 -- 2024-01-16
+
+* Initial release
diff --git a/LICENSE b/LICENSE
new file mode 100644
--- /dev/null
+++ b/LICENSE
@@ -0,0 +1,202 @@
+
+                                 Apache License
+                           Version 2.0, January 2004
+                        http://www.apache.org/licenses/
+
+   TERMS AND CONDITIONS FOR USE, REPRODUCTION, AND DISTRIBUTION
+
+   1. Definitions.
+
+      "License" shall mean the terms and conditions for use, reproduction,
+      and distribution as defined by Sections 1 through 9 of this document.
+
+      "Licensor" shall mean the copyright owner or entity authorized by
+      the copyright owner that is granting the License.
+
+      "Legal Entity" shall mean the union of the acting entity and all
+      other entities that control, are controlled by, or are under common
+      control with that entity. For the purposes of this definition,
+      "control" means (i) the power, direct or indirect, to cause the
+      direction or management of such entity, whether by contract or
+      otherwise, or (ii) ownership of fifty percent (50%) or more of the
+      outstanding shares, or (iii) beneficial ownership of such entity.
+
+      "You" (or "Your") shall mean an individual or Legal Entity
+      exercising permissions granted by this License.
+
+      "Source" form shall mean the preferred form for making modifications,
+      including but not limited to software source code, documentation
+      source, and configuration files.
+
+      "Object" form shall mean any form resulting from mechanical
+      transformation or translation of a Source form, including but
+      not limited to compiled object code, generated documentation,
+      and conversions to other media types.
+
+      "Work" shall mean the work of authorship, whether in Source or
+      Object form, made available under the License, as indicated by a
+      copyright notice that is included in or attached to the work
+      (an example is provided in the Appendix below).
+
+      "Derivative Works" shall mean any work, whether in Source or Object
+      form, that is based on (or derived from) the Work and for which the
+      editorial revisions, annotations, elaborations, or other modifications
+      represent, as a whole, an original work of authorship. For the purposes
+      of this License, Derivative Works shall not include works that remain
+      separable from, or merely link (or bind by name) to the interfaces of,
+      the Work and Derivative Works thereof.
+
+      "Contribution" shall mean any work of authorship, including
+      the original version of the Work and any modifications or additions
+      to that Work or Derivative Works thereof, that is intentionally
+      submitted to Licensor for inclusion in the Work by the copyright owner
+      or by an individual or Legal Entity authorized to submit on behalf of
+      the copyright owner. For the purposes of this definition, "submitted"
+      means any form of electronic, verbal, or written communication sent
+      to the Licensor or its representatives, including but not limited to
+      communication on electronic mailing lists, source code control systems,
+      and issue tracking systems that are managed by, or on behalf of, the
+      Licensor for the purpose of discussing and improving the Work, but
+      excluding communication that is conspicuously marked or otherwise
+      designated in writing by the copyright owner as "Not a Contribution."
+
+      "Contributor" shall mean Licensor and any individual or Legal Entity
+      on behalf of whom a Contribution has been received by Licensor and
+      subsequently incorporated within the Work.
+
+   2. Grant of Copyright License. Subject to the terms and conditions of
+      this License, each Contributor hereby grants to You a perpetual,
+      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
+      copyright license to reproduce, prepare Derivative Works of,
+      publicly display, publicly perform, sublicense, and distribute the
+      Work and such Derivative Works in Source or Object form.
+
+   3. Grant of Patent License. Subject to the terms and conditions of
+      this License, each Contributor hereby grants to You a perpetual,
+      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
+      (except as stated in this section) patent license to make, have made,
+      use, offer to sell, sell, import, and otherwise transfer the Work,
+      where such license applies only to those patent claims licensable
+      by such Contributor that are necessarily infringed by their
+      Contribution(s) alone or by combination of their Contribution(s)
+      with the Work to which such Contribution(s) was submitted. If You
+      institute patent litigation against any entity (including a
+      cross-claim or counterclaim in a lawsuit) alleging that the Work
+      or a Contribution incorporated within the Work constitutes direct
+      or contributory patent infringement, then any patent licenses
+      granted to You under this License for that Work shall terminate
+      as of the date such litigation is filed.
+
+   4. Redistribution. You may reproduce and distribute copies of the
+      Work or Derivative Works thereof in any medium, with or without
+      modifications, and in Source or Object form, provided that You
+      meet the following conditions:
+
+      (a) You must give any other recipients of the Work or
+          Derivative Works a copy of this License; and
+
+      (b) You must cause any modified files to carry prominent notices
+          stating that You changed the files; and
+
+      (c) You must retain, in the Source form of any Derivative Works
+          that You distribute, all copyright, patent, trademark, and
+          attribution notices from the Source form of the Work,
+          excluding those notices that do not pertain to any part of
+          the Derivative Works; and
+
+      (d) If the Work includes a "NOTICE" text file as part of its
+          distribution, then any Derivative Works that You distribute must
+          include a readable copy of the attribution notices contained
+          within such NOTICE file, excluding those notices that do not
+          pertain to any part of the Derivative Works, in at least one
+          of the following places: within a NOTICE text file distributed
+          as part of the Derivative Works; within the Source form or
+          documentation, if provided along with the Derivative Works; or,
+          within a display generated by the Derivative Works, if and
+          wherever such third-party notices normally appear. The contents
+          of the NOTICE file are for informational purposes only and
+          do not modify the License. You may add Your own attribution
+          notices within Derivative Works that You distribute, alongside
+          or as an addendum to the NOTICE text from the Work, provided
+          that such additional attribution notices cannot be construed
+          as modifying the License.
+
+      You may add Your own copyright statement to Your modifications and
+      may provide additional or different license terms and conditions
+      for use, reproduction, or distribution of Your modifications, or
+      for any such Derivative Works as a whole, provided Your use,
+      reproduction, and distribution of the Work otherwise complies with
+      the conditions stated in this License.
+
+   5. Submission of Contributions. Unless You explicitly state otherwise,
+      any Contribution intentionally submitted for inclusion in the Work
+      by You to the Licensor shall be under the terms and conditions of
+      this License, without any additional terms or conditions.
+      Notwithstanding the above, nothing herein shall supersede or modify
+      the terms of any separate license agreement you may have executed
+      with Licensor regarding such Contributions.
+
+   6. Trademarks. This License does not grant permission to use the trade
+      names, trademarks, service marks, or product names of the Licensor,
+      except as required for reasonable and customary use in describing the
+      origin of the Work and reproducing the content of the NOTICE file.
+
+   7. Disclaimer of Warranty. Unless required by applicable law or
+      agreed to in writing, Licensor provides the Work (and each
+      Contributor provides its Contributions) on an "AS IS" BASIS,
+      WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or
+      implied, including, without limitation, any warranties or conditions
+      of TITLE, NON-INFRINGEMENT, MERCHANTABILITY, or FITNESS FOR A
+      PARTICULAR PURPOSE. You are solely responsible for determining the
+      appropriateness of using or redistributing the Work and assume any
+      risks associated with Your exercise of permissions under this License.
+
+   8. Limitation of Liability. In no event and under no legal theory,
+      whether in tort (including negligence), contract, or otherwise,
+      unless required by applicable law (such as deliberate and grossly
+      negligent acts) or agreed to in writing, shall any Contributor be
+      liable to You for damages, including any direct, indirect, special,
+      incidental, or consequential damages of any character arising as a
+      result of this License or out of the use or inability to use the
+      Work (including but not limited to damages for loss of goodwill,
+      work stoppage, computer failure or malfunction, or any and all
+      other commercial damages or losses), even if such Contributor
+      has been advised of the possibility of such damages.
+
+   9. Accepting Warranty or Additional Liability. While redistributing
+      the Work or Derivative Works thereof, You may choose to offer,
+      and charge a fee for, acceptance of support, warranty, indemnity,
+      or other liability obligations and/or rights consistent with this
+      License. However, in accepting such obligations, You may act only
+      on Your own behalf and on Your sole responsibility, not on behalf
+      of any other Contributor, and only if You agree to indemnify,
+      defend, and hold each Contributor harmless for any liability
+      incurred by, or claims asserted against, such Contributor by reason
+      of your accepting any such warranty or additional liability.
+
+   END OF TERMS AND CONDITIONS
+
+   APPENDIX: How to apply the Apache License to your work.
+
+      To apply the Apache License to your work, attach the following
+      boilerplate notice, with the fields enclosed by brackets "[]"
+      replaced with your own identifying information. (Don't include
+      the brackets!)  The text should be enclosed in the appropriate
+      comment syntax for the file format. We also recommend that a
+      file or class name and description of purpose be included on the
+      same "printed page" as the copyright notice for easier
+      identification within third-party archives.
+
+   Copyright 2024 Shea Levy
+
+   Licensed under the Apache License, Version 2.0 (the "License");
+   you may not use this file except in compliance with the License.
+   You may obtain a copy of the License at
+
+       http://www.apache.org/licenses/LICENSE-2.0
+
+   Unless required by applicable law or agreed to in writing, software
+   distributed under the License is distributed on an "AS IS" BASIS,
+   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+   See the License for the specific language governing permissions and
+   limitations under the License.
diff --git a/e11y-otel.cabal b/e11y-otel.cabal
new file mode 100644
--- /dev/null
+++ b/e11y-otel.cabal
@@ -0,0 +1,65 @@
+cabal-version:   3.0
+name:            e11y-otel
+version:         0.1.0.0
+synopsis:        OpenTelemetry-based rendering for e11y
+description:     Render [e11y](https://hackage.haskell.org/package/e11y) events to OpenTelemetry traces.
+bug-reports:     https://github.com/shlevy/e11y/issues
+homepage:        https://github.com/shlevy/e11y
+license:         Apache-2.0
+license-file:    LICENSE
+author:          Shea Levy
+maintainer:      shea@shealevy.com
+copyright:
+  Copyright 2024 Shea Levy
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+category:        Observability
+build-type:      Simple
+extra-doc-files: CHANGELOG.md
+tested-with:     GHC == { 9.2.8, 9.4.8, 9.6.4, 9.8.1 }
+
+source-repository head
+  type:     git
+  location: https://github.com/shlevy/e11y
+
+library
+  exposed-modules: Observe.Event.Backend.OpenTelemetry
+  build-depends:
+    , base                 ^>= { 4.16, 4.17, 4.18, 4.19 }
+    , e11y                 ^>= { 0.1 }
+    , hs-opentelemetry-api ^>= { 0.1 }
+    , parametric-functor   ^>= { 0.1 }
+    , text                 ^>= { 1.2, 2.0, 2.1 }
+    , unordered-containers ^>= { 0.2 }
+
+  hs-source-dirs:   src
+  default-language: GHC2021
+
+test-suite e11y-otel
+  type:             exitcode-stdio-1.0
+  main-is:          Test.hs
+  hs-source-dirs:   test
+  ghc-options:      -threaded -rtsopts -with-rtsopts=-N
+  build-depends:
+    , async                ^>= { 2.2 }
+    , base
+    , e11y
+    , e11y-otel
+    , general-allocate     ^>= { 0.2 }
+    , hs-opentelemetry-api
+    , hs-opentelemetry-sdk ^>= { 0.0.3 }
+    , sydtest              ^>= { 0.15 }
+    , text
+    , unordered-containers
+
+  default-language: GHC2021
diff --git a/src/Observe/Event/Backend/OpenTelemetry.hs b/src/Observe/Event/Backend/OpenTelemetry.hs
new file mode 100644
--- /dev/null
+++ b/src/Observe/Event/Backend/OpenTelemetry.hs
@@ -0,0 +1,154 @@
+-- Copyright 2024 Shea Levy
+--
+-- Licensed under the Apache License, Version 2.0 (the "License");
+-- you may not use this file except in compliance with the License.
+-- You may obtain a copy of the License at
+--
+--     http://www.apache.org/licenses/LICENSE-2.0
+--
+-- Unless required by applicable law or agreed to in writing, software
+-- distributed under the License is distributed on an "AS IS" BASIS,
+-- WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+-- See the License for the specific language governing permissions and
+-- limitations under the License.
+{-# LANGUAGE DuplicateRecordFields #-}
+{-# LANGUAGE OverloadedRecordDot #-}
+{-# LANGUAGE OverloadedStrings #-}
+{-# LANGUAGE TypeFamilies #-}
+{-# LANGUAGE UnicodeSyntax #-}
+
+{- |
+Description : 'EventBackend' rendering 'Observe.Event.Event's as OpenTelemetry traces
+Copyright   : Copyright 2024 Shea Levy.
+License     : Apache-2.0
+Maintainer  : shea@shealevy.com
+-}
+module Observe.Event.Backend.OpenTelemetry
+  ( TracerEventBackend (..)
+  , RenderOTel
+  , OTelRendered (..)
+  )
+where
+
+import Control.Monad.IO.Class
+import Data.Functor.Parametric
+import Data.HashMap.Strict as HashMap
+import Data.Maybe
+import Data.Text (Text, pack)
+import Observe.Event.Backend
+import OpenTelemetry.Context as Context
+import OpenTelemetry.Context.ThreadLocal
+import OpenTelemetry.Trace.Core
+
+{- | An 'EventBackend' built on a 'Tracer'.
+
+When no explicit parent is set, the backend will try to find a parent in the "OpenTelemetry.Context.ThreadLocal" 'Context'.
+However, it will never update that 'Context', as the primitive 'EventBackend' API has no way to determine if it's being
+consumed in a scoped context or one allowing for general interleaving.
+
+When possible, events created with 'Observe.Event.instantEvent' will use the span event API. However, this requires a parent event
+(explicitly specified or found in the thread-local 'Context'), so the backend will fallback to creating and 'finalize'ing a new
+'Span'. If a span event is created, the resulting 'Observe.Event.eventReference' will be to its parent, as span events cannot be parents/links.
+Span events do not allow for non-parent links, so any @causes@ are dropped; in the future, we may either add them as custom
+'Attribute's or fall back to a full span if any are specified.
+
+Event t'Link's are currently not given any attributes. In the future, arbitrary link metadata could be added to the core 'EventBackend'
+API, in which case we could add a renderer for the link metadata type.
+
+The underlying 'Tracer' is responsible for timestamping.
+
+Exceptions are 'recordException'ed without any custom attributes. In the future, an @Exception -> HashMap Text Attribute@
+argument could be added, or arbitrary exception metadata added to 'Observe.Event.finalizeEvent'.
+-}
+data TracerEventBackend selector = TracerEventBackend
+  { tracer ∷ !Tracer
+  -- ^ The 'Tracer' from @hs-opentelemetry-api@.
+  --
+  -- See the [hs-opentelemetry-sdk intialization docs](https://hackage.haskell.org/package/hs-opentelemetry-sdk#initialization) for
+  -- the typical way of getting a 'Tracer' in your application.
+  , render ∷ !(RenderOTel selector)
+  -- ^ The domain-specific logic for translating 'Observe.Event.Event's rooted
+  -- in a given [selector](https://hackage.haskell.org/package/e11y/docs/Observe-Event.html#g:selectorAndField).
+  }
+
+{- | The domain-specific logic for translating 'Observe.Event.Event's rooted
+in a given [selector](https://hackage.haskell.org/package/e11y/docs/Observe-Event.html#g:selectorAndField).
+-}
+type RenderOTel selector = ∀ field. Selectors selector field → OTelRendered field
+
+{- | The domain-specific logic for translating a specific 'Observe.Event.Event'
+with a given [field](https://hackage.haskell.org/package/e11y/docs/Observe-Event.html#g:selectorAndField)
+type.
+-}
+data OTelRendered field = OTelRendered
+  { eventName ∷ !Text
+  -- ^ The name of the event.
+  --
+  -- See the "span name" section of the [open-telemetry span documentation](https://opentelemetry.io/docs/reference/specification/trace/api/#span).
+  , eventKind ∷ !SpanKind
+  -- ^ The kind of span to create.
+  --
+  -- See the [SpanKind](https://opentelemetry.io/docs/reference/specification/trace/api/#spankind) specification.
+  , renderField ∷ !(field → HashMap Text Attribute)
+  -- ^ Render a field to a set of span [attributes](https://opentelemetry.io/docs/reference/specification/common/#attribute).
+  --
+  -- Note especially the [attribute naming guidelines](https://opentelemetry.io/docs/reference/specification/common/attribute-naming/).
+  }
+
+instance EventBackend (TracerEventBackend selector) where
+  type BackendEvent (TracerEventBackend selector) = TracerEventBackendEvent
+  type RootSelector (TracerEventBackend selector) = selector
+
+instance (MonadIO m, ParametricFunctor m) ⇒ EventBackendIn m (TracerEventBackend selector) where
+  newEvent be params = do
+    ctx ← fromMaybe Context.empty <$> lookupContext
+    let ctx' = maybe ctx (`insertSpan` ctx) params.parent
+        rendered = render be params.selectors
+    links ← traverse (fmap (`NewLink` HashMap.empty) . getSpanContext) params.causes
+    otelSpan ←
+      createSpanWithoutCallStack be.tracer ctx' rendered.eventName $
+        SpanArguments
+          { kind = rendered.eventKind
+          , attributes = foldMap (renderField rendered) params.initialFields
+          , links
+          , startTime = Nothing
+          }
+    pure $ TracerEventBackendEvent{otelSpan, renderField' = renderField rendered}
+
+  newInstantEvent be params = case params.parent of
+    Nothing → do
+      m_ctx ← lookupContext
+      case m_ctx >>= lookupSpan of
+        Just s → newInstantEvent be $ params{parent = Just s}
+        Nothing → do
+          ev ← newEvent be params
+          finalize ev Nothing
+          pure $ reference ev
+    Just s → do
+      let rendered = render be params.selectors
+      addEvent s $
+        NewEvent
+          { newEventName = rendered.eventName
+          , newEventAttributes = foldMap (renderField rendered) params.initialFields
+          , newEventTimestamp = Nothing
+          }
+      pure s
+
+data TracerEventBackendEvent field = TracerEventBackendEvent
+  { renderField' ∷ !(field → HashMap Text Attribute)
+  , otelSpan ∷ Span
+  }
+
+instance Observe.Event.Backend.Event TracerEventBackendEvent where
+  type EventReference TracerEventBackendEvent = Span
+  reference = (.otelSpan)
+
+instance (MonadIO m, ParametricFunctor m) ⇒ EventIn m TracerEventBackendEvent where
+  finalize ev err = do
+    case err of
+      Just e → do
+        recordException ev.otelSpan (singleton "exception.escaped" (toAttribute True)) Nothing e
+        setStatus ev.otelSpan . Error . pack $ show e
+      Nothing → setStatus ev.otelSpan Ok
+    endSpan ev.otelSpan Nothing
+  addField ev = addAttributes ev.otelSpan . renderField' ev
diff --git a/test/Test.hs b/test/Test.hs
new file mode 100644
--- /dev/null
+++ b/test/Test.hs
@@ -0,0 +1,308 @@
+-- Copyright 2024 Shea Levy
+--
+-- Licensed under the Apache License, Version 2.0 (the "License");
+-- you may not use this file except in compliance with the License.
+-- You may obtain a copy of the License at
+--
+--     http://www.apache.org/licenses/LICENSE-2.0
+--
+-- Unless required by applicable law or agreed to in writing, software
+-- distributed under the License is distributed on an "AS IS" BASIS,
+-- WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+-- See the License for the specific language governing permissions and
+-- limitations under the License.
+{-# LANGUAGE DuplicateRecordFields #-}
+{-# LANGUAGE ImplicitParams #-}
+{-# LANGUAGE OverloadedRecordDot #-}
+{-# LANGUAGE OverloadedStrings #-}
+{-# LANGUAGE TypeFamilies #-}
+{-# LANGUAGE UnicodeSyntax #-}
+
+module Main where
+
+import Control.Concurrent.Async
+import Control.Concurrent.MVar
+import Control.Exception
+import Control.Monad.With
+import Data.Foldable
+import Data.HashMap.Strict hiding (toList)
+import Data.IORef
+import Data.Kind
+import Data.Maybe
+import Data.Text qualified as T
+import Observe.Event
+import Observe.Event.Backend
+import Observe.Event.Backend.OpenTelemetry
+import OpenTelemetry.Attributes
+import OpenTelemetry.Context
+import OpenTelemetry.Context.ThreadLocal
+import OpenTelemetry.Processor
+import OpenTelemetry.Trace
+import OpenTelemetry.Trace.Core
+import OpenTelemetry.Util
+import Test.Syd
+
+data TestSelector ∷ Type → Type where
+  Test ∷ TestSelector TestField
+
+data TestField = TestField deriving (Eq, Show)
+
+type instance SubSelector TestField = SubTestSelector
+
+data SubTestSelector ∷ Type → Type where
+  SubTest ∷ SubTestSelector SubTestField
+
+data SubTestField = SubTestField deriving (Eq, Show)
+
+type instance SubSelector SubTestField = NoEventsSelector
+
+renderTestSelector ∷ RenderOTel TestSelector
+renderTestSelector = selectorRendering $ \Test →
+  SelectorRendering
+    { renderTopSelector =
+        OTelRendered
+          { eventName = "test"
+          , eventKind = Internal
+          , renderField = \TestField → singleton "test-field" (AttributeValue $ BoolAttribute True)
+          }
+    , renderSubSelector = renderSubTestSelector
+    }
+
+renderSubTestSelector ∷ RenderOTel SubTestSelector
+renderSubTestSelector = selectorRendering $ \SubTest →
+  noSubEventsSelectorRendering $
+    OTelRendered
+      { eventName = "sub-test"
+      , eventKind = Internal
+      , renderField = \SubTestField → singleton "sub-test-field" (AttributeValue $ BoolAttribute True)
+      }
+
+data TestException = TestException deriving (Show)
+
+instance Exception TestException
+
+dummyTracer ∷ MVar [ImmutableSpan] → IO Tracer
+dummyTracer var = do
+  (_, options) ← getTracerProviderInitializationOptions
+  let processor =
+        Processor
+          { processorOnStart = \_ _ → pure ()
+          , processorOnEnd = \spanRef → do
+              s ← readIORef spanRef
+              modifyMVar_ var $ \spans → pure (s : spans)
+          , processorShutdown = async $ pure ShutdownSuccess
+          , processorForceFlush = pure ()
+          }
+  provider ← createTracerProvider [processor] options
+  pure $ makeTracer provider (InstrumentationLibrary "dummy" "1.0.0") tracerOptions
+
+main ∷ IO ()
+main = sydTest $ do
+  let setupTracer = do
+        spansVar ← newMVar []
+        tracer ← dummyTracer spansVar
+        pure (spansVar, tracer)
+  before setupTracer $ describe "TracerEventBackend" $ do
+    it "creates spans" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      (withEvent Test $ pure ()) ∷ IO ()
+      spans ← readMVar spansVar
+
+      s ← case spans of
+        [s] → pure s
+        _ → expectationFailure "wrong number of spans"
+
+      shouldSatisfyNamed
+        s
+        "has the expected name"
+        (\s' → s'.spanName == "test")
+
+    it "creates parentless events when the Context is empty" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      (withEvent Test $ pure ()) ∷ IO ()
+      spans ← readMVar spansVar
+
+      s ← case spans of
+        [] → expectationFailure "no spans created"
+        [s] → pure s
+        _ → expectationFailure "too many spans created"
+
+      shouldSatisfyNamed
+        s
+        "has no parent"
+        (\s' → isNothing s'.spanParent)
+
+    it "gets the parent from the Context when events are parentless" $ \(spansVar, tracer) → do
+      let be = TracerEventBackend{tracer, render = renderTestSelector}
+      let ?e11yBackend = be
+      _ ∷ () ← withEvent Test $ do
+        adjustContext $ insertSpan eventReference
+        let ?e11yBackend = be
+        (withEvent Test $ pure ()) ∷ IO ()
+      spans ← readMVar spansVar
+
+      (parent, child) ← case spans of
+        [parent, child] → pure (parent, child)
+        _ → expectationFailure "wrong number of spans"
+
+      childParentContext ← traverse getSpanContext child.spanParent
+      case childParentContext of
+        Nothing → expectationFailure "child has no parent"
+        Just ctx → shouldSatisfyNamed ctx "parent is the right parent" (== parent.spanContext)
+
+    it "ignores the Context when an event has a parent" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      (s1 ∷ Span) ← withEvent Test $ pure eventReference
+      _ ∷ () ← withEvent Test $ do
+        adjustContext $ insertSpan s1
+        (withEvent SubTest $ pure ()) ∷ IO ()
+      spans ← readMVar spansVar
+
+      (parent, child) ← case spans of
+        [parent, child, _] → pure (parent, child)
+        _ → expectationFailure "wrong number of spans"
+
+      childParentContext ← traverse getSpanContext child.spanParent
+      case childParentContext of
+        Nothing → expectationFailure "child has no parent"
+        Just ctx → shouldSatisfyNamed ctx "parent is the right parent" (== parent.spanContext)
+
+    it "adds causes as links" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      _ ∷ () ← withEvent Test $ do
+        withRelatedEvent SubTest Nothing [eventReference] $ do pure ()
+      spans ← readMVar spansVar
+
+      (parent, child) ← case spans of
+        [parent, child] → pure (parent, child)
+        _ → expectationFailure "wrong number of spans"
+
+      childLink ← case toList $ frozenBoundedCollectionValues child.spanLinks of
+        [childLink] → pure childLink
+        _ → expectationFailure "wrong number of links"
+
+      shouldSatisfyNamed
+        childLink
+        "links to parent"
+        (\cl → cl.frozenLinkContext == parent.spanContext)
+
+    it "adds initial fields" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      let alloc =
+            allocateEventArgs $
+              EventParams
+                { selectors = Leaf Test
+                , parent = Nothing
+                , causes = []
+                , initialFields = [TestField]
+                }
+      generalWith alloc $ \_ → pure ()
+      spans ← readMVar spansVar
+
+      s ← case spans of
+        [s] → pure s
+        _ → expectationFailure "wrong number of spans"
+
+      let checkAttrs s' = (snd . getAttributes $ s'.spanAttributes) ! "test-field" == AttributeValue (BoolAttribute True)
+
+      shouldSatisfyNamed
+        s
+        "has a test attr"
+        checkAttrs
+
+    it "creates instant parentless events as spans when the Context is empty" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      !_ ← instantEvent Test []
+      spans ← readMVar spansVar
+
+      s ← case spans of
+        [] → expectationFailure "no spans created"
+        [s] → pure s
+        _ → expectationFailure "too many spans created"
+
+      shouldSatisfyNamed
+        s
+        "has no parent"
+        (\s' → isNothing s'.spanParent)
+
+    it "creates instant parentless events as span events of the Context's span when it has one" $ \(spansVar, tracer) → do
+      let be = TracerEventBackend{tracer, render = renderTestSelector}
+      let ?e11yBackend = be
+      _ ∷ () ← withEvent Test $ do
+        adjustContext $ insertSpan eventReference
+        let ?e11yBackend = be
+        !_ ← instantEvent Test []
+        pure ()
+      spans ← readMVar spansVar
+
+      parent ← case spans of
+        [parent] → pure parent
+        _ → expectationFailure "wrong number of spans"
+
+      let evs = toList . appendOnlyBoundedCollectionValues $ parent.spanEvents
+      child ← case evs of
+        [child] → pure child
+        _ → expectationFailure "wrong number of span events"
+      shouldSatisfyNamed
+        child
+        "is a test event"
+        (\c → c.eventName == "test")
+
+    it "adds fields span events generated by parented instant events" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      _ ∷ () ← withEvent Test $ do
+        _ ← instantEvent SubTest [SubTestField]
+        pure ()
+      spans ← readMVar spansVar
+
+      parent ← case spans of
+        [parent] → pure parent
+        _ → expectationFailure "wrong number of spans"
+
+      let evs = toList . appendOnlyBoundedCollectionValues $ parent.spanEvents
+      child ← case evs of
+        [child] → pure child
+        _ → expectationFailure "wrong number of span events"
+
+      let checkAttrs e = (snd . getAttributes $ e.eventAttributes) ! "sub-test-field" == AttributeValue (BoolAttribute True)
+
+      shouldSatisfyNamed
+        child
+        "has a subtest attr"
+        checkAttrs
+
+    it "sets event exceptions" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      (withEvent Test $ finalizeEvent (Just (SomeException TestException))) ∷ IO ()
+      spans ← readMVar spansVar
+
+      s ← case spans of
+        [s] → pure s
+        _ → expectationFailure "wrong number of spans"
+
+      let evs = toList . appendOnlyBoundedCollectionValues $ s.spanEvents
+          checkAttrs e = (snd . getAttributes $ e.eventAttributes) ! "exception.escaped" == AttributeValue (BoolAttribute True)
+      errorEv ← case evs of
+        [errorEv] → pure errorEv
+        _ → expectationFailure "wrong number of span events"
+
+      shouldSatisfyNamed
+        (s, errorEv)
+        "has exception information"
+        (\(s', errorEv') → s'.spanStatus == Error (T.pack $ show TestException) && checkAttrs errorEv')
+
+    it "adds fields as attributes" $ \(spansVar, tracer) → do
+      let ?e11yBackend = TracerEventBackend{tracer, render = renderTestSelector}
+      (withEvent Test $ addEventField TestField) ∷ IO ()
+      spans ← readMVar spansVar
+
+      s ← case spans of
+        [s] → pure s
+        _ → expectationFailure "wrong number of spans"
+
+      let checkAttrs s' = (snd . getAttributes $ s'.spanAttributes) ! "test-field" == AttributeValue (BoolAttribute True)
+
+      shouldSatisfyNamed
+        s
+        "has a test attr"
+        checkAttrs