diff --git a/CHANGELOG.md b/CHANGELOG.md
new file mode 100644
--- /dev/null
+++ b/CHANGELOG.md
@@ -0,0 +1,4 @@
+# 0.1.0.0
+
+Added everything that exists in this version.  See Haddock documentation for a
+complete accounting.
diff --git a/LICENSE b/LICENSE
new file mode 100644
--- /dev/null
+++ b/LICENSE
@@ -0,0 +1,202 @@
+
+                                 Apache License
+                           Version 2.0, January 2004
+                        http://www.apache.org/licenses/
+
+   TERMS AND CONDITIONS FOR USE, REPRODUCTION, AND DISTRIBUTION
+
+   1. Definitions.
+
+      "License" shall mean the terms and conditions for use, reproduction,
+      and distribution as defined by Sections 1 through 9 of this document.
+
+      "Licensor" shall mean the copyright owner or entity authorized by
+      the copyright owner that is granting the License.
+
+      "Legal Entity" shall mean the union of the acting entity and all
+      other entities that control, are controlled by, or are under common
+      control with that entity. For the purposes of this definition,
+      "control" means (i) the power, direct or indirect, to cause the
+      direction or management of such entity, whether by contract or
+      otherwise, or (ii) ownership of fifty percent (50%) or more of the
+      outstanding shares, or (iii) beneficial ownership of such entity.
+
+      "You" (or "Your") shall mean an individual or Legal Entity
+      exercising permissions granted by this License.
+
+      "Source" form shall mean the preferred form for making modifications,
+      including but not limited to software source code, documentation
+      source, and configuration files.
+
+      "Object" form shall mean any form resulting from mechanical
+      transformation or translation of a Source form, including but
+      not limited to compiled object code, generated documentation,
+      and conversions to other media types.
+
+      "Work" shall mean the work of authorship, whether in Source or
+      Object form, made available under the License, as indicated by a
+      copyright notice that is included in or attached to the work
+      (an example is provided in the Appendix below).
+
+      "Derivative Works" shall mean any work, whether in Source or Object
+      form, that is based on (or derived from) the Work and for which the
+      editorial revisions, annotations, elaborations, or other modifications
+      represent, as a whole, an original work of authorship. For the purposes
+      of this License, Derivative Works shall not include works that remain
+      separable from, or merely link (or bind by name) to the interfaces of,
+      the Work and Derivative Works thereof.
+
+      "Contribution" shall mean any work of authorship, including
+      the original version of the Work and any modifications or additions
+      to that Work or Derivative Works thereof, that is intentionally
+      submitted to Licensor for inclusion in the Work by the copyright owner
+      or by an individual or Legal Entity authorized to submit on behalf of
+      the copyright owner. For the purposes of this definition, "submitted"
+      means any form of electronic, verbal, or written communication sent
+      to the Licensor or its representatives, including but not limited to
+      communication on electronic mailing lists, source code control systems,
+      and issue tracking systems that are managed by, or on behalf of, the
+      Licensor for the purpose of discussing and improving the Work, but
+      excluding communication that is conspicuously marked or otherwise
+      designated in writing by the copyright owner as "Not a Contribution."
+
+      "Contributor" shall mean Licensor and any individual or Legal Entity
+      on behalf of whom a Contribution has been received by Licensor and
+      subsequently incorporated within the Work.
+
+   2. Grant of Copyright License. Subject to the terms and conditions of
+      this License, each Contributor hereby grants to You a perpetual,
+      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
+      copyright license to reproduce, prepare Derivative Works of,
+      publicly display, publicly perform, sublicense, and distribute the
+      Work and such Derivative Works in Source or Object form.
+
+   3. Grant of Patent License. Subject to the terms and conditions of
+      this License, each Contributor hereby grants to You a perpetual,
+      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
+      (except as stated in this section) patent license to make, have made,
+      use, offer to sell, sell, import, and otherwise transfer the Work,
+      where such license applies only to those patent claims licensable
+      by such Contributor that are necessarily infringed by their
+      Contribution(s) alone or by combination of their Contribution(s)
+      with the Work to which such Contribution(s) was submitted. If You
+      institute patent litigation against any entity (including a
+      cross-claim or counterclaim in a lawsuit) alleging that the Work
+      or a Contribution incorporated within the Work constitutes direct
+      or contributory patent infringement, then any patent licenses
+      granted to You under this License for that Work shall terminate
+      as of the date such litigation is filed.
+
+   4. Redistribution. You may reproduce and distribute copies of the
+      Work or Derivative Works thereof in any medium, with or without
+      modifications, and in Source or Object form, provided that You
+      meet the following conditions:
+
+      (a) You must give any other recipients of the Work or
+          Derivative Works a copy of this License; and
+
+      (b) You must cause any modified files to carry prominent notices
+          stating that You changed the files; and
+
+      (c) You must retain, in the Source form of any Derivative Works
+          that You distribute, all copyright, patent, trademark, and
+          attribution notices from the Source form of the Work,
+          excluding those notices that do not pertain to any part of
+          the Derivative Works; and
+
+      (d) If the Work includes a "NOTICE" text file as part of its
+          distribution, then any Derivative Works that You distribute must
+          include a readable copy of the attribution notices contained
+          within such NOTICE file, excluding those notices that do not
+          pertain to any part of the Derivative Works, in at least one
+          of the following places: within a NOTICE text file distributed
+          as part of the Derivative Works; within the Source form or
+          documentation, if provided along with the Derivative Works; or,
+          within a display generated by the Derivative Works, if and
+          wherever such third-party notices normally appear. The contents
+          of the NOTICE file are for informational purposes only and
+          do not modify the License. You may add Your own attribution
+          notices within Derivative Works that You distribute, alongside
+          or as an addendum to the NOTICE text from the Work, provided
+          that such additional attribution notices cannot be construed
+          as modifying the License.
+
+      You may add Your own copyright statement to Your modifications and
+      may provide additional or different license terms and conditions
+      for use, reproduction, or distribution of Your modifications, or
+      for any such Derivative Works as a whole, provided Your use,
+      reproduction, and distribution of the Work otherwise complies with
+      the conditions stated in this License.
+
+   5. Submission of Contributions. Unless You explicitly state otherwise,
+      any Contribution intentionally submitted for inclusion in the Work
+      by You to the Licensor shall be under the terms and conditions of
+      this License, without any additional terms or conditions.
+      Notwithstanding the above, nothing herein shall supersede or modify
+      the terms of any separate license agreement you may have executed
+      with Licensor regarding such Contributions.
+
+   6. Trademarks. This License does not grant permission to use the trade
+      names, trademarks, service marks, or product names of the Licensor,
+      except as required for reasonable and customary use in describing the
+      origin of the Work and reproducing the content of the NOTICE file.
+
+   7. Disclaimer of Warranty. Unless required by applicable law or
+      agreed to in writing, Licensor provides the Work (and each
+      Contributor provides its Contributions) on an "AS IS" BASIS,
+      WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or
+      implied, including, without limitation, any warranties or conditions
+      of TITLE, NON-INFRINGEMENT, MERCHANTABILITY, or FITNESS FOR A
+      PARTICULAR PURPOSE. You are solely responsible for determining the
+      appropriateness of using or redistributing the Work and assume any
+      risks associated with Your exercise of permissions under this License.
+
+   8. Limitation of Liability. In no event and under no legal theory,
+      whether in tort (including negligence), contract, or otherwise,
+      unless required by applicable law (such as deliberate and grossly
+      negligent acts) or agreed to in writing, shall any Contributor be
+      liable to You for damages, including any direct, indirect, special,
+      incidental, or consequential damages of any character arising as a
+      result of this License or out of the use or inability to use the
+      Work (including but not limited to damages for loss of goodwill,
+      work stoppage, computer failure or malfunction, or any and all
+      other commercial damages or losses), even if such Contributor
+      has been advised of the possibility of such damages.
+
+   9. Accepting Warranty or Additional Liability. While redistributing
+      the Work or Derivative Works thereof, You may choose to offer,
+      and charge a fee for, acceptance of support, warranty, indemnity,
+      or other liability obligations and/or rights consistent with this
+      License. However, in accepting such obligations, You may act only
+      on Your own behalf and on Your sole responsibility, not on behalf
+      of any other Contributor, and only if You agree to indemnify,
+      defend, and hold each Contributor harmless for any liability
+      incurred by, or claims asserted against, such Contributor by reason
+      of your accepting any such warranty or additional liability.
+
+   END OF TERMS AND CONDITIONS
+
+   APPENDIX: How to apply the Apache License to your work.
+
+      To apply the Apache License to your work, attach the following
+      boilerplate notice, with the fields enclosed by brackets "[]"
+      replaced with your own identifying information. (Don't include
+      the brackets!)  The text should be enclosed in the appropriate
+      comment syntax for the file format. We also recommend that a
+      file or class name and description of purpose be included on the
+      same "printed page" as the copyright notice for easier
+      identification within third-party archives.
+
+   Copyright [yyyy] [name of copyright owner]
+
+   Licensed under the Apache License, Version 2.0 (the "License");
+   you may not use this file except in compliance with the License.
+   You may obtain a copy of the License at
+
+       http://www.apache.org/licenses/LICENSE-2.0
+
+   Unless required by applicable law or agreed to in writing, software
+   distributed under the License is distributed on an "AS IS" BASIS,
+   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+   See the License for the specific language governing permissions and
+   limitations under the License.
diff --git a/attenuation.cabal b/attenuation.cabal
new file mode 100644
--- /dev/null
+++ b/attenuation.cabal
@@ -0,0 +1,42 @@
+cabal-version: 1.12
+
+-- This file has been generated from package.yaml by hpack version 0.33.0.
+--
+-- see: https://github.com/sol/hpack
+--
+-- hash: 92d47a2950ec019ac542be7970e219dab7309ba103c1c46acae9beb21fef6f06
+
+name:           attenuation
+version:        0.1.0.0
+synopsis:       Representational subtyping relations and variance roles.
+description:    This lets you coerce containers (among other things) from stronger types to
+                weaker types with zero runtime cost when it's safe to do so, e.g.
+                @[Fin n] -> [Int]@.  This primarily comes into play when using newtypes to
+                impose additional invariants on existing types.
+category:       Constraints
+homepage:       https://github.com/google/hs-attenuation#readme
+bug-reports:    https://github.com/google/hs-attenuation/issues
+author:         Andrew Pritchard <awpr@google.com>
+maintainer:     Andrew Pritchard <awpr@google.com>
+copyright:      2020-2021 Google LLC
+license:        Apache-2.0
+license-file:   LICENSE
+build-type:     Simple
+extra-source-files:
+    CHANGELOG.md
+
+source-repository head
+  type: git
+  location: https://github.com/google/hs-attenuation
+
+library
+  exposed-modules:
+      Data.Type.Attenuation
+  other-modules:
+      Paths_attenuation
+  hs-source-dirs:
+      src
+  build-depends:
+      base >=4.7 && <4.16
+    , profunctors >=0.1 && <5.7
+  default-language: Haskell2010
diff --git a/src/Data/Type/Attenuation.hs b/src/Data/Type/Attenuation.hs
new file mode 100644
--- /dev/null
+++ b/src/Data/Type/Attenuation.hs
@@ -0,0 +1,250 @@
+-- Copyright 2020-2021 Google LLC
+--
+-- Licensed under the Apache License, Version 2.0 (the "License");
+-- you may not use this file except in compliance with the License.
+-- You may obtain a copy of the License at
+--
+--      http://www.apache.org/licenses/LICENSE-2.0
+--
+-- Unless required by applicable law or agreed to in writing, software
+-- distributed under the License is distributed on an "AS IS" BASIS,
+-- WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+-- See the License for the specific language governing permissions and
+-- limitations under the License.
+
+-- | Representational subtyping relations and variance roles.
+
+{-# LANGUAGE ConstraintKinds #-}
+{-# LANGUAGE CPP #-}
+{-# LANGUAGE DataKinds #-}
+{-# LANGUAGE GADTs #-}
+{-# LANGUAGE QuantifiedConstraints #-}
+{-# LANGUAGE RankNTypes #-}
+{-# LANGUAGE ScopedTypeVariables #-}
+{-# LANGUAGE TypeFamilies #-}
+{-# LANGUAGE TypeOperators #-}
+
+module Data.Type.Attenuation
+         ( -- * Attenuation
+           Attenuation, attenuate, coercible
+         , trans, repr, coer
+           -- ** Representationality
+         , Representational, Representational0, Representational1, Variance
+           -- ** Functor and Contravariant
+         , co, contra
+           -- ** Bifunctor
+         , fstco, sndco
+           -- ** Profunctor
+         , lcontra, rco
+           -- ** Initial and Final Objects
+         , attVoid, attAny
+         ) where
+
+import Control.Category (Category(..))
+import Data.Bifunctor (Bifunctor)
+import Data.Coerce (Coercible, coerce)
+import Data.Functor.Contravariant (Contravariant)
+import Data.Kind (Constraint)
+import Data.Profunctor (Profunctor)
+import Data.Type.Coercion (Coercion(..), sym)
+import qualified Data.Type.Coercion as Coercion
+import Data.Type.Equality ((:~:)(..))
+import Data.Void (Void)
+import GHC.Exts (Any)
+
+#if MIN_VERSION_base(4,15,0)
+import Unsafe.Coerce (unsafeEqualityProof, UnsafeEquality(..))
+#else
+import Unsafe.Coerce (unsafeCoerce)
+#endif
+
+-- | @Attenuation a b@ is a unidirectional 'Coercion' from @a@ to @b@.
+--
+-- "Attenuate: reduce the force, effect, or value of."  An @Attenuation@ takes
+-- a stronger, stricter type to a weaker, more lax type.  It's meant to sound a
+-- bit like 'Coercion', while conveying that it weakens the type of its
+-- argument.
+--
+-- This arises from newtypes that impose additional invariants on their
+-- representations: if we define @Fin :: Nat -> Type@ as a newtype over 'Int',
+-- such as in <https://hackage.haskell.org/package/fin-int fin-int>, then it's
+-- safe to 'coerce' @Fin@s to 'Int's, and @Fin@s to other @Fin@s with larger
+-- @Nat@ parameters, but not vice versa.
+--
+-- Within the module defining this @Fin@ type, we can obtain 'Coercible'
+-- between any two @Fin@ types regardless of their roles, because their newtype
+-- constructors are in scope, but if we've taken appropriate precautions
+-- (namely not exporting the constructor), we can't obtain it outside the
+-- module.  We can relax this and make the coercion "opt-in" by exporting it in
+-- the form of a 'Coercion' with a scary name like @unsafeCoFin@, but this is
+-- still error-prone.
+--
+-- Instead, we introduce a newtype wrapper around 'Coercion' which restricts it
+-- to be used only in the forward direction, and carefully design its API so
+-- that it can only be obtained under the appropriate circumstances.
+--
+-- @Attenuation a b@ can be seen as a witness that @a@ is, semantically and
+-- representationally, a subtype of @b@: that is, any runtime object that
+-- inhabits @a@ also inhabits @b@ without any conversion.  Note, however, that
+-- we can't have a useful typeclass of this subtyping relation because all of
+-- its instances would have to be specified individually: whereas 'Coercible'
+-- is willing to invert or compose coercions implicitly because of GHC magic, a
+-- subtyping class would not have that affordance.
+newtype Attenuation a b = Attenuation (Coercion a b)
+  deriving (Eq, Ord, Show)
+
+instance Category Attenuation where
+  id = coercible
+  (.) = flip trans
+
+-- | Coerce along an 'Attenuation'.
+--
+-- This is really, truly a coercion when it reaches Core.
+attenuate :: Attenuation a b -> a -> b
+attenuate (Attenuation Coercion) = coerce
+
+-- | Any coercible types have an 'Attenuation'.
+coercible :: Coercible a b => Attenuation a b
+coercible = Attenuation Coercion
+
+-- | Transitivity of 'Attenuation's.  See also the 'Category' instance.
+trans :: Attenuation a b -> Attenuation b c -> Attenuation a c
+trans (Attenuation coAB) (Attenuation coBC) =
+  Attenuation (Coercion.trans coAB coBC)
+
+-- | Any type is unidirectionally coercible to itself.
+repr :: (a :~: b) -> Attenuation a b
+repr Refl = Attenuation Coercion
+
+-- | Bidirectional coercions can be weakened to unidirectional coercions.
+coer :: Coercion a b -> Attenuation a b
+coer = Attenuation
+
+-- | A witness that @a@ occurs representationally in @s@ and that, when
+-- substituting it for @b@, you get @t@.
+--
+-- These compose like Lenses from the "lens" package, so you can e.g. lift
+-- 'Attenuation's through several @Functor@s by @'co'.co.co $ x@.
+type Variance s t a b = Attenuation a b -> Attenuation s t
+
+-- | A constraint that behaves like @type role f representational@.
+--
+-- This means that if we have this constraint in context and GHC can solve
+-- 'Coercible' for some types @a@ and @b@, it will also lift the coercion to @f
+-- a@ and @f b@.
+type Representational f =
+  (forall a b. Coercible a b => Coercible (f a) (f b) :: Constraint)
+
+-- | Lift a 'Coercion' over a type constructor.
+rep :: Representational f => Coercion a b -> Coercion (f a) (f b)
+rep Coercion = Coercion
+
+-- | A constraint that behaves like @type role f _ representational@.
+--
+-- See also 'Representational'.
+type Representational1 f =
+  (forall a b x. Coercible a b => Coercible (f x a) (f x b) :: Constraint)
+
+-- | A constraint that behaves like @type role f representational _@.
+--
+-- See also 'Representational'.
+type Representational0 f =
+  (forall a b x. Coercible a b => Coercible (f a x) (f b x) :: Constraint)
+
+-- | Lift a 'Coercion' over the last-but-one parameter of a type constructor.
+rep0 :: Representational0 f => Coercion a b -> Coercion (f a x) (f b x)
+rep0 Coercion = Coercion
+
+-- | Lift an 'Attenuation' covariantly over a type constructor @f@.
+--
+-- Although we don't /use/ the 'Functor' constraint, it serves an important
+-- purpose: to guarantee that the type parameter @a@ doesn't appear
+-- contravariantly in @f a@; otherwise it'd be impossible to write a 'Functor'
+-- instance.  This is used as a standin for more-detailed "covariant" and
+-- "contravariant" type roles, which GHC doesn't have because there's no
+-- built-in notion of subtyping to use them with.  'Representational1' provides
+-- the actual lifting of coercions, and 'Functor' guarantees we've got the
+-- variance right.
+co :: (Functor f, Representational f) => Variance (f a) (f b) a b
+co (Attenuation c) = Attenuation (rep c)
+
+-- | Lift an 'Attenuation' contravariantly over a type constructor @f@.
+--
+-- Regarding the 'Contravariant' constraint, see 'co', and interchange mentions
+-- of covariance and contravariance.
+contra :: (Contravariant f, Representational f) => Variance (f b) (f a) a b
+contra (Attenuation c) = Attenuation (sym $ rep c)
+
+-- | Lift an 'Attenuation' covariantly over the left of a 'Bifunctor'.
+--
+-- Like with 'co' and 'contra', we require a not-actually-used constraint as
+-- proof that the type has the appropriate variance.  Since there's not a
+-- commonly-used class for functors over the last-but-one parameter, we use
+-- 'Bifunctor'.  Sadly, this rules out types which are covariant in parameter
+-- -1 and contravariant in parameter -0.
+fstco :: (Bifunctor f, Representational0 f) => Variance (f a x) (f b x) a b
+fstco (Attenuation c) = Attenuation (rep0 c)
+
+-- | Lift an 'Attenuation' covariantly over the last-but-one type parameter.
+--
+-- Like with 'co' and 'contra', we require a not-actually-used constraint as
+-- proof that the type has the appropriate variance.  Since there's not a
+-- commonly-used class for functors over the last-but-one parameter, we use
+-- 'Bifunctor'.  Sadly, this rules out types which are covariant in parameter
+-- -1 and contravariant in parameter -0.
+--
+-- Note that any particular type with a @Bifunctor f@ instance should also have
+-- @Functor (f x)@, so 'co' should work on any type that 'sndco' works on, but
+-- in polymorphic contexts, the 'Functor' instance may not be available.
+sndco :: (Bifunctor f, Representational1 f) => Variance (f x a) (f x b) a b
+sndco (Attenuation c) = Attenuation (rep c)
+
+-- | Lift an 'Attenuation' covariantly over the left of a 'Profunctor'.
+--
+-- Similarly to the use of 'Functor' in 'co', we use 'Profunctor' to guarantee
+-- contravariance in the appropriate parameter.
+lcontra :: (Profunctor p, Representational0 p) => Variance (p b x) (p a x) a b
+lcontra (Attenuation c) = Attenuation (sym $ rep0 c)
+
+-- | Lift an 'Attenuation' covariantly over the right of a 'Profunctor'.
+--
+-- Similarly to the use of 'Functor' in 'co', we use 'Profunctor' to guarantee
+-- contravariance in the appropriate parameter.
+--
+-- As with 'sndco', this functions the same as 'co', but the needed 'Functor'
+-- instance might not be available in polymorphic contexts.
+rco :: (Profunctor p, Representational1 p) => Variance (p x a) (p x b) a b
+rco (Attenuation c) = Attenuation (rep c)
+
+-- | 'Attenuation' of 'Void' to any type.
+--
+-- If you have 'Void' appearing covariantly in a type, you can replace it with
+-- any other lifted type with a coercion, because the value can't contain any
+-- non-bottom 'Void' values (there are none), and any value that /is/ bottom
+-- can "work" (i.e. throw or fail to terminate) just as well at any other
+-- lifted type.
+--
+-- For example, if you have a @[Doc Void]@ (from
+-- <https://hackage.haskell.org/package/pretty pretty>), you know it doesn't
+-- have any annotations (or they're errors), so you can use it as @[Doc a]@
+-- without actually traversing the list and @Doc@ structure to apply
+-- 'Data.Void.absurd' to all of the 'Void's.
+attVoid :: forall a. Attenuation Void a
+attVoid = Attenuation $
+#if MIN_VERSION_base(4,15,0)
+  case unsafeEqualityProof :: UnsafeEquality a Void of UnsafeRefl -> Coercion
+#else
+  (unsafeCoerce (Coercion :: Coercion a a) :: Coercion Void a)
+#endif
+
+-- | 'Attenuation' of any type to 'Any'.
+--
+-- Similarly to 'attVoid', you can weaken any type to 'Any' for free, since any
+-- value is a valid value of type 'Any'.
+attAny :: forall a. Attenuation a Any
+attAny = Attenuation $
+#if MIN_VERSION_base(4,15,0)
+  case unsafeEqualityProof :: UnsafeEquality a Any of UnsafeRefl -> Coercion
+#else
+  (unsafeCoerce (Coercion :: Coercion a a) :: Coercion a Any)
+#endif